*DECK GETIPS
          IDENT GETIPS
          SST 
          TITLE  GETIPS - GET INSTALLATION PARAMETERS 
* 
**        GETIPS - GET INSTALLATION PARAMETERS
* 
*         DOES  -  PICKS UP INSTALLATION PARAMETERS - SEE ROUTINES
* 
  
*         GETCSET IS ENTERED FROM SYMPL AS A FUNCTION TO
*         RETURN THE CHARACTER SET SELECTED BY IPARAMS. 
* 
*         1 = CDC63 
*         2 = CDC64 
*         3 = ASCII63 
*         4 = ACSII64 
*         5 = DISPLAY CODE
* 
*         THIS ROUTINE IS CALLED FROM INITCCT ONLY
* 
          ENTRY  GETCSET
 GETCSET  DATA   0
          IFEQ   OP.COLSQ,OP.C64,1
          SX6    2           CDC 64 
          IFEQ   OP.COLSQ,OP.ASCII,1
          SX6    4           ASCII 64 
*         ASCII 63 AND DISPLAY CODE DO NOT EXIST
          EQ     GETCSET
 GETCMU   SPACE  4
* 
**        GETCMU - RETURNS 1 IF CMU (IP.CMU) CODE WANTED
*                0 OTHERWISE
* 
*         CALLED AS FUNCTION FROM SYMPL 
* 
          ENTRY  GETCMU 
 GETCMU   DATA   0
          IFEQ   OP.BDP,OP.YES,1
          SX6    1
          IFEQ   OP.BDP,OP.NO,1 
          MX6    0
          EQ     GETCMU 
 GETNOST  SPACE  3
* 
**        GETNOST - RETURNS 1 IF NOS JOB AND OUTPUT FILE IS CONNECTED 
*                   0 OTHERWISE 
* 
 JOBR     EQU    66B         WORD HOLDING JOB ORIGIN
 TXOT     EQU    3           TIMESHARING ORIGIN 
  
          ENTRY  GETNOST
 GETNOST  DATA   0
          IFC    EQ,*"OSNAME"*KRONOS* 
          SA1    X1          FILE NAME
          BX6    X1 
          SA6    =SLISTF
          SX5    050000B     LEN FIELD
          BX6    X6+X5
          SA6    FINBLK 
          FILINFO  FINBLK    GET INFO ABOUT FILE
          SA2    FINBLK+1    RETURN WORD ABOUT FILE 
          BX4    X2 
          LX2    59-16
          NG     X2,GETTRUE  JP IF CONNECTED FILE 
          AX4    48          DT FIELD 
          NZ     X4,GETFALSE ASSIGNED, SO NOT CONNECTED 
          SA2    JOBR        JOB ORIGIN 
          MX0    48 
          LX2    36 
          BX2    -X0*X2 
          SX2    X2-TXOT
          NZ     X2,GETFALSE NOT TELEX JOB
          SA1    LISTF
          SA2    =0LOUTPUT
          IX3    X1-X2
          ZR     X3,GETTRUE  OUTPUT WILL BE CONNECTED 
 GETFALSE MX6    0
          EQ     GETNOST
          SPACE  3
 GETTRUE  SX6    1
          EQ     GETNOST
          ELSE
          MX6    0
          EQ     GETNOST
          ENDIF 
  
          IFC    EQ,*"OSNAME"*KRONOS*,1 
 FINBLK   BSS    5
 GETOS    SPACE  3
* 
**        GETOS - RETURNS 1 IF OS IS NOS, 0 IF OS IS NOS/BE 
* 
*         CALLED AS FUNCTION FROM SYMPL - INITCCT 
* 
          ENTRY  GETOS
 GETOS    DATA   0
 OSIF     IFC    EQ,*"OSNAME"*KRONOS* 
          SX6    1
 OSIF     ELSE
          MX6    0
 OSIF     ENDIF 
          EQ     GETOS
  
  
  
* 
**        GETDBUG - RETURN 1 IF DEBUG,ON., 0 IF NOT 
* 
*         CALLED AS FUNC FROM COBINIT TO SET CCTIDBUG 
* 
          ENTRY GETDBUG 
 GETDBUG  DATA   0
          GETLC  LDRCTWD     OBTAIN LOADER CONTROL WORD 
          SA1    LDRCTWD
          MX2    59 
          AX1    34 
          BX6    -X2*X1      RETURN WITH BIT 34 OF LOADER CONTROL WORD
          EQ     GETDBUG
 LDRCTWD  DATA   0
 BLDLOF   SPACE  5
* 
**        BLDLOF - BUILD LIST OF FILES AND CALL SYSTEM TO PROVIDE IT
*                ALSO SETS FLUSH FLAG IN OUTPUT FET 
* 
          USE    /FET/
          BSS    1           INPUT FET PTR
 OUTFET   BSS    1           OUTPUT FET PTR 
          USE    *
  
          ENTRY  BLDLOF 
 BLDLOF   DATA   0
          SB1    1
          SX6    10 
          SA6    2           LIST OF FILES STARTS IN RA+2 AND IS 10 
*                            WORDS LONG 
          SETLOF LOFPAR,RCL  CALL SYSTEM TO SET IT UP 
          SA1    OUTFET      GET ADDRESS OF OUTPUT FET
          SA2    X1          GET LFN FROM FET 
          MX3    42 
          BX6    X3*X2       GET THE NAME 
          BX6    X1+X6       COMBINE NAME AND ADDR
          SA6    3           PUT AS FIRST ENTRY IN LIST OF FILES
*                            ON NOS THIS IS NECESSARY SOMETIMES 
          MX7    0
          SB2    9
 BLDL1    BSS    0           ZERO OUT REMAINDER OF LIST 
          SA7    B2+4 
          SB2    B2-B1
          NZ     B2,BLDL1 
          STORE  X1,FF=YES   SET FLUSH FLAG 
          EQ     BLDLOF      RETURN 
 LOFPAR   VFD    12/0,18/2,30/0 
  
  
          SPACE  3
          END 
