*DECK C$TERM
          IDENT  C$TERM 
          TITLE  C$TERM - PUT OUT TERMINATION MESSAGES
  
          MACHINE  ANY,I
          COMMENT  PUT OUT TERMINATION MESSAGES 
          B1=1
  
          LDSET  OMIT=CMM.AUS/CMM.ICM/C.ZEROS/MSG=/SYS= 
* 
*         KEEP THIS OMIT LIST UP TO DATE WITH CHANGES IN THE CAPSULE
*                OR IT WON-T LOAD RIGHT 
* 
          ENTRY  C.TERM 
 C.TERM   SPACE  5
 C.TERM   BSS    0           NOT ENTERED WITH AN RJ.... 
          SA3    =YC.JTFLG   JOB TERMINATION FLAG CTIME 
          ZR     X3,DOCORE         DON-T WANT TIME
          TIME   ENDTIM 
          SA2    ENDTIM 
          MX0    24 
          BX3    -X0*X3      STRIP OFF TIME 
          BX2    -X0*X2      LIMIT
          SX5    1000 
          MX0    48 
          BX1    -X0*X2      CURR MS
          BX2    X0*X2       CURR SEC 
          BX4    -X0*X3      ORIG MS
          AX2    12          MAKE CURR SEC INTEGER
          BX3    X0*X3       ORIG SEC 
          AX3    12          MAKE ORIG SEC INTEGER
          IX2    X2*X5       CSEC*1000
          IX3    X3*X5       OSEC*1000
          IX2    X2+X1
          IX3    X3+X4
          IX1    X2-X3       THE DIFFERENCE, IN M.S.
          RJ     =XC.R1S09   CONVERT DIFF (IN MS) TO DECIMAL
          MX0    12 
          BX6    -X0*X1      KEEP ONLY BOTTOM 8 DIGITS
          MX0    42 
          BX1    X6*X0       TOP
          SX5    1R.
          BX6    -X0*X6      BOTTOM 
          LX1    6
          LX5    18 
          BX6    X6+X5
          SX4    1R 
          BX6    X6+X1
          LX6    6
          BX6    X6+X4
          SA6    MESS1
          MESSAGE  MESS1,LOCAL,R
 DOCORE   SPACE  5
 DOCORE   BSS    0
          SA3    =YC.JTFLG+1 JOB TERMINATION FLAG COREF 
          ZR     X3,DOEND    NO CORE USED MSG WANTED
          RJ     =XCMM.GSS
          SX0    7
          SA2    X1+1        WORD W/ MAXFL
          MX6    0
          LX2    42          TO TOP OF WORD 
          SB7    6           COUNT
  
 CORELP   LX6    6
          LX2    3
          BX4    X0*X2       NEXT DIGIT 
          SB7    B7-B1
          SX4    X4+1R0 
          BX6    X6+X4
          NZ     B7,CORELP
          SX4    1RB
          LX6    6
          BX6    X6+X4
          SA2    MESS2
          MX0    18 
          BX2    X0*X2
          BX6    X2+X6
          SA6    A2 
          MESSAGE  MESS2,LOCAL,R
  
 DOEND    BSS    0
          SB4    =YC.DBEND
          NG     B4,OLDABS   JP IF OLD ABSOLUTE (C.DBEND NOT THERE) 
          JP     B4          GO TO C.DBEND TO WRAP IT UP
 OLDABS   ENDRUN             STOP IT FOR OLD ABSOLUTES
  
 ENDTIM   DATA   0
 MESS1    DATA   C*XXXXX.XXX CPU SECONDS EXECUTION TIME*
 MESS2    DATA   C*   000000B SCM MAXIMUM USED* 
  
          END 
