*DECK C$STOP2 
          IDENT  C$STOP2
          TITLE  C$STOP2 - MCS REQUEST FOR STOP RUN AND CHECK POINT 
          MACHINE ANY,I 
          COMMENT MCS INTERFACE FOR STOP RUN
          SST 
          B1=1
          SPACE  5
* 
**        C.STOP2 - MCS REQUEST FOR STOP RUN AND CHECK POINT
* 
*         INPUT 
*                X1  10B CHECK POINT REQUEST
*                    11B STOP RUN REQUEST 
*                    CALLED FROM CBINIT AND CBRERCT 
* 
*         OUTPUT
*                NONE 
* 
*         DOES
*                SETS UP MCS REQUEST FOR STOP RUN 
*                CALLS MCS
* 
*         USES
*                A  - 1 - - - - 6 - 
*                X  - 1 - - - - 6 - 
*                B  0 1 - - - - - - 
          EJECT 
          EXT    C.MCS3 
          EXT    DEBUG
          USE    /C.MCSPB/
 MCSPB    BSS    64 
 CDADDR   BSS    1
          USE    *
          ENTRY  C.STOP2
 C.STOP2  DATA   0
          BX6    X1          X1 CONTAINS REQUEST CODE 
          LX6    54 
          SA6    MCSPB+1     STORE MCSPB WORD 1 
          SA1    =00000000000004020000B 
          BX6    X1 
          SA6    A6-B1       WORD 0 
          MX6    0
          SA6    MCSPB+2     WORD 2 ALL ZEROES
          SA1    C.STOP2
          RJ     =XC.MCS3    PROGRAM-ID CBLNO *APPLE UTILITY
          IFC    EQ,/"OSNAME"/SCOPE / 
          CALLSS OP.MCS1,MCSPB,R
          ELSE
          CALLSS OP.MCS2,MCSPB,R
          ENDIF 
          EQ     C.STOP2
          END 
