*DECK C$SSTOR 
          IDENT  C$SSTOR
          COMMENT ONE REGISTER STORE JUST RIGHT 
          TITLE  C$SSTOR - SUBSCRIPTED STORE SINGLE REGISTER
 C$SSTOR  SPACE  4
**        C$SSTOR - SUBSCRIPTED STORE SINGLE REGISTER 
* 
*         INPUT 
*                X1 - WORD TO STORE, RIGHT JUSTIFIED
*                B3 - DESTINATION ADDRESS 
*                X3 - DESTINATION OFFSET
*                B4 - DESTINATION LENGTH, CHARACTERS
* 
*         DOES - STORE CONTENTS OF X1 IN SPECIFIED DESTINATION
* 
*         USES   A  - - - - 4 5 6 - 
*                X  - 1 - 3 4 5 6 - 
*                B  0 1 2 3 4 5 6 7 
* 
          ENTRY  C.SSTOR
 C.SSTOR  DATA   0
          SX4    314632B
          IX5    X4*X3
          AX5    20 
          SB3    X5+B3       ADJUSTED ADDRESS 
          IX4    X5+X5
          LX5    3
          IX4    X4+X5
          IX3    X3-X4       OFFSET MOD 10
          SB2    10 
          SB5    B2-B4       SOURCE BCP 
          SB7    X3          DESTINATION BCP
          SX3    B5+B7
          ZR     X3,STOR3    BCP = 0, SIZE = 10 
          SB6    B5-B7
          GE     B6,B0,STOR1
          SB6    B2+B6
 STOR1    BSS    0
          SX3    B6+B6
          SB6    X3+B6
          SB6    B6+B6
          LX1    B6,X1       ALIGN BCPS 
          SB6    B2-B7       10 - BCP 
          SB5    B6 
          LT     B6,B4,STOR2
          SB6    B4 
 STOR2    BSS    0
          SB4    B4-B6       CHARACTERS IN SECOND WORD
          SA4    =XC.MASK+B6 MASK  6 * MIN(SIZE,10-BCP) 
          SX3    B5+B5
          SB5    X3+B5
          SB5    B5+B5
          LX4    X4,B5       ALIGN MASK 
          BX6    X4*X1
          SA5    B3          LOAD FIRST WORD
          BX3    -X4*X5 
          BX6    X6+X3
          SA6    A5 
          ZR     B4,C.SSTOR  DESTINATION CONTAINED IN ONE WORD
          SA5    A5+B1
          BX6   X6+X3 
          SA4    =XC.MASK+B4
          BX3    X4*X1
          BX6    -X4*X5 
          BX6    X6+X3
          SA6    A5 
          EQ     C.SSTOR
          SPACE  3
 STOR3    BX6    X1 
          SA6    B3 
          EQ     C.SSTOR
          END 
