*DECK C$SLODL 
          IDENT  C$SLODL
          COMMENT  ONE REGISTER LOAD JUST LEFT
          TITLE  C$SLODL - SINGLE REGISTER LEFT JUSTIFIED LOAD
 C$SLODL  SPACE  4
*         C$SLODL - SINGLE REGISTER LEFT JUSTIFIED LOAD 
* 
*         INPUT 
*                X3 - OFFSET OF FIELD TO LOAD 
*                B3 - ADDRESS OF FIELD TO LOAD
*                B4 - LENGTH OF FIELD TO LOAD (MAXIMUM 10 CHARACTERS) 
*         OUTPUT
*                X1 - LOADED ITEM (BLANK FILLED)
* 
* 
*         USES - A - 1 2 3 - - - -
*                X - 1 2 3 - - - -
*                B 0 1 2 3 4 5 - -
* 
          ENTRY  C.SLODL
 C.SLODL  DATA   0
          SX1    314632B
          IX2    X1*X3
          AX2    20 
          SB3    X2+B3       NEW ADDRESS
          IX1    X2+X2
          LX2    3
          IX1    X1+X2
          IX3    X3-X1       OFFSET MOD 10
          SB5    B4+X3       ECP
          SB2    10 
          GT     B5,B2,SLODL2          ITEM CROSSES WORD BOUNDARY 
          SA1    B3          LOAD ITEM
          ZR     X3,SLODL1   LEFT JUSTIFIED 
          SB2    X3 
          SX3    B2+B2
          SB2    X3+B2
          SB2    B2+B2       6*BCP
          LX1    B2,X1
 SLODL1   BSS    0
          SA2    =XC.MASK+B4
          BX1    X1*X2
          SA2    =XC.BFILL+B4 
          BX1    X1+X2
          EQ     C.SLODL
          SPACE  3
 SLODL2   BSS    0           ITEM CROSSES WORD BOUNDARY 
          SB5    X3 
          SX1    B5+B5
          SB5    X1+B5
          SB5    B5+B5       6*BCP
          SA1    B3 
          SA2    B3+B1
          LX1    B5,X1       LEFT JUSTIFY 
          LX2    B5,X2
          BX3    -X3
          SB5    B2+X3       10-BCP 
          SA3    =XC.MASK+B5
          BX1    X3*X1
          BX2    -X3*X2 
          BX1    X1+X2
          SA2    =XC.MASK+B4 LENGTH MASK
          BX1    X1*X2
          SA2    =XC.BFILL+B4 
          BX1    X1+X2
          EQ     C.SLODL
          END 
