*DECK C$SETSW 
          IDENT  C$SETSW
          TITLE  CBSETSW - SET SWITCH ON OR OFF 
          MACHINE  ANY,I
          COMMENT  SET SWITCH ON OR OFF 
          SST 
* 
**        NAME - CBSETSW
* 
*         DOES - SETS SENSE SWITCH 1 TO 6 ON OR OFF 
* 
*         CALLING SEQUENCE
* 
*         SB3    SWITCH NUMBER
*         SB4    0 IF OFF, 1 IF ON
*         RJ     =XC.SETSW
* 
*         CHANGES 
*                A1,A6,B2,X1,X2,X6
* 
          ENTRY  C.SETSW
 C.SETSW  DATA   0
          SB2    54 
          SB2    B2-B3       SET SHIFT COUNT FOR PROPER SWITCH
          SA1    B0          GET RA+0 
          LX1    B2          POSITION SWITCH BIT AT TOP 
          ZR     B4,SETOFF0  JP IF SETTING OFF
          NG     X1,C.SETSW  EXIT IF ALREADY ON AND SETTING ON
          EQ     SETXX
 SETOFF0  BSS    0
          PL     X1,C.SETSW  EXIT IF ALREADY OFF AND SETTING OFF
 SETXX    BSS    0
 IF1      IFC    EQ,/"OSNAME"/SCOPE / 
          MX6    0
          SA6    JCIWD       CLEAR REPLY WORD 
          GETJCI  JCIWD      GET CURRENT SWITCH SETTINGS
          SB3    B3+6        BIAS TO POINT TO SWITCH AREA (BITS 6-11) 
          SA2    JCIWD       GET CURRENT SETTINGS 
          MX1    1
          LX1    B3 
          ZR     B4,SETOFF1  JP IF SETTING OFF
          BX6    X1+X2       SET SWITCH BIT 
          EQ     SETJCI 
 SETOFF1  BSS    0
          BX6    -X1*X2      CLEAR SWITCH BIT 
 SETJCI   BSS    0
          MX7    59 
          BX6    X7*X6       CLEAR REPLY BIT
          SA6    A2 
          SA3    B0          GET RA+0 
          MX5    60-6 
          LX5    6
          BX3    X5*X3       CLEAR ALL SWITCH BITS
          BX6    -X5*X6      PICK UP NEW ONES 
          BX6    X6+X3
          SA6    B0          SET NEW SWITCH SETTING IN RA+0 
          SETJCI JCIWD
          EQ     C.SETSW
 JCIWD    BSS    2
 IF1      ELSE
          MX1    1
          LX1    B3          POSITION FOR PROPER SWITCH SETTING 
          ZR     B4,SETOFF1  JP IF SETTING OFF
          ONSW   X1          SET SWITCH ON
          EQ     C.SETSW
 SETOFF1  BSS    0
          OFFSW  X1          SET SWITCH OFF 
          EQ     C.SETSW
 IF1      ENDIF 
          END 
