*DECK C$RWMSG 
          IDENT  C$RWMSG
          SST 
          TITLE  C.RWMSG - OUTPUT REPORT WRITER RUN TIME MESSAGES 
* 
          COMMENT  OUTPUT REPORT WRITER RUN TIME MESSAGES 
**        C.RWMSG - OUTPUT REPORT WRITER RUN TIME MESSAGES
* 
*         CALLED BY ENTER STATEMENT 
*                PARAMETER 1 IS THE LINE NUMBER 
*                PARAMETER 2 IS THE ERROR NUMBER
* 
*         CALLS C.MSG TO PRINT THE MESSAGE IN THE DAYFILE 
* 
          ENTRY  C.RWMSG
 C.RWMSG  DATA   0
          SA2    A1+B1       GET ERROR NUMBER PARAMETER 
          SB5    X1          ADDRESS OF LINE NUMBER 
          AX1    30 
          BX6    X2 
          SA6    =SSAVEP2    SAVE ERROR NUMBER PARAMETER
          MX5    60-6 
          BX4    -X5*X1      ISOLATE BCP
          SB6    X4          BCP
          AX1    6
          MX5    60-18
          BX4    -X5*X1 
          SB7    X4          SIZE 
          SB3    =XC.MSINS   FWA OF RECEIVER
          SB4    B0          BCP OF RECEIVER
          MX2    0           NO FILL
          RJ     =XC.MOVE    MOVE LINE NUMBER TO PARAM
          SB5    ZERWD       WORD OF BINARY ZEROS 
          SB6    B0          BCP = 0
          SB7    B1          MOVE 1 CHARACTER (1 ZERO BYTE) 
          RJ     =XC.MOVE    MOVE ZERO BYTE FOR D00 INSERT
          SX1    #CBMSG1     LINE NUMBER MESSAGE
          SX2    B1          X2 NON ZERO - INSERTS
          MX3    1           X3 NEGATIVE - NO SOURCE LINE (THIS IS) 
          MX6    0           RETURN 
          RJ     =XC.MSG     WRITE MESSAGE TO DAYFILE 
          SA2    SAVEP2      GET MSG NBR PARAMETER WORD 
          MX4    60-6 
          SB3    X2          ADDRESS OF NBR 
          AX2    30 
          BX1    -X4*X2      BCP
          MX0    1           MAKE PARAMETER WORD
          LX0    10 
          AX2    6
          MX3    60-4 
          BX2    -X3*X2 
          IX0    X0+X2       SIZE + PARAM 
          LX0    8
          IX0    X0+X2       SIZE IN BOTH DEST AND SOURCE 
          RJ     =XC.ND2RN   CONVERT TO REG NUMERIC 
          MX0    60-48       CONVERT 8 CHARS
          BX1    X2 
          RJ     =XC.U08R1   CONVERT TO BINARY
          SB3    X1          MESSAGE NBR
          SA1    B3+MSGNBR   GET CB5TEXT MESSAGE NBR
          MX0    0           NO INSERTS 
          MX3    1           NO SOURCE LINE MESSAGE (ALREADY DONE)
          MX6    0           RETURN AFTER MESSAGE 
          RJ     =XC.MSG     OUTPUT MESSAGE 
          EQ     C.RWMSG     RETURN 
 MSGNBR   BSS    0           MESSAGE NUMBERS - RELATED TO MSG IN CB5TEXT
 ZERWD    DATA   0           NO MESSAGE ZERO
          VFD    60/#RWMS1
          VFD    60/#RWMS2
          VFD    60/#RWMS3
          VFD    60/#RWMS4
          VFD    60/#RWMS5
          VFD    60/#RWMS6
          VFD    60/#RWMS7
          VFD    60/#RWMS8
          END 
