*DECK C$RN2ND 
          IDENT  C$RN2ND
          TITLE  C.RN2ND/C.RN1ND -  STORE SUBSCRIPTED 
  
          MACHINE  ANY,I
          COMMENT  C.RN2ND/C.RN1ND -  STORE SUBSCRIPTED 
          SPACE  4
**        C.RN2ND -  2-REGISTER NUMERIC TO SUBSCRIPTED NUMERIC DISPLAY
* 
*         B3 = DESTINATION ADDRESS
* 
*         X0 = 40/ UNUSED (EXCEPT FOR NOTE BELOW) 
*              4/ INDICATOR FOR SHIFT AFTER BOTH FIELDS ARE 
*                   ALIGNED ON LEAST SIGNIFICANT DIGITS:  
*                            0000  (SEE NOTE BELOW) 
*                            0001  RESULT RIGHT-SHIFTED 7 DIGITS
*                            0010  RESULT RIGHT-SHIFTED 6 DIGITS
*                            ...
*                            0111  RESULT RIGHT-SHIFTED 1 DIGIT 
*                            1000  NO SHIFTING
*                            1001  RESULT PADDED WITH 1 ZERO ON RIGHT 
*                            1010  RESULT PADDED WITH 2 ZEROS ON RIGHT
*                            ...
*                            1111  RESULT PADDED WITH 7 ZEROS ON RIGHT
*              1/ =1 IFF SOURCE IS SIGNED,
*              5/ NUMERIC LENGTH OF SOURCE, 
*              1/ =1 IFF DESTINATION HAS SEPARATE SIGN, 
*              1/ =1 IFF DESTINATION HAS LEADING SIGN,
*              1/ =1 IFF DESTINATION IS SIGNED, 
*              5/ NUMERIC LENGTH OF DESTINATION 
* 
*         X1 = MOST SIGNIFICANT DIGITS OF SOURCE
* 
*         X2 = LEAST SIGNIFICANT DIGITS OF SOURCE 
* 
*         X3 = CHARACTER OFFSET FROM DESTINATION ADDRESS
*                (0 @ OFFSET < 2'18)
* 
*         NOTE-  THE SPECIFICATIONS OF COBOL REQUIRE THE CAPABILITY 
*         OF SHIFTING UP TO 17 DIGITS TO THE RIGHT OR LEFT. 
*         WITH REGISTER X0 BEING SET WITH A SINGLE *SET X-REGISTER* 
*         INSTRUCTION, ONLY 7 DIGITS MAY BE EASILY SPECIFIED. 
*         WHEN THE 4-BIT SHIFT INDICATOR = 0000 THE UPPER 42 BITS 
*         OF REGISTER X0 INDICATE THE SHIFT COUNT (THUS REQUIRING 
*         SEVERAL INSTRUCTIONS TO SET UP X0). 
*         THE UPPER 12 BITS OF X0 ARE THE BIASED SHIFT INDICATOR, 
*         SUITABLE FOR EXTRACTION WITH AN *UNPACK* INSTRUCTION: 
*                            -17   RESULT RIGHT-SHIFTED 17 DIGITS 
*                            ...
*                            -8    RESULT RIGHT-SHIFTED 8 DIGITS
*                            8     RESULT PADDED WITH 8 ZEROS ON RIGHT
*                            ...
*                            17    RESULT PADDED WITH 17 ZEROS ON RIGHT 
* 
*         B7 = RETURN ADDRESS 
* 
*         EQ     C.RN2ND
* 
* 
*         STORES THE GIVEN SOURCE REGISTERS INTO THE SPECIFIED FIELD. 
* 
*         USES-  X  0 1 2 3 4 5 6 7 
*                A  - - - - 4 5 6 - 
*                B    * - 3 4 5 6 7    *B1=1
* 
*         THIS ROUTINE ENDS A SEQUENCE SO X-REGISTERS MAY BE FREELY USED
          SPACE  4
**        C.RN1ND -  1-REGISTER NUMERIC TO SUBSCRIPTED NUMERIC DISPLAY
* 
*         B3, X0, X3, B7 = SAME AS IN C.RN2ND 
* 
*         X2 = SOURCE VALUE.
* 
*         EQ     C.RN1ND
* 
* 
*         THIS ROUTINE BEHAVES EXACTLY AS C.RN2ND EXCEPT THAT 
*         THE SOURCE VALUE IS CONTAINED IN ONE REGISTER INSTEAD OF TWO. 
* 
*         USES-  X  0 1 2 3 4 5 6 7 
*                A  - 1 - - 4 5 6 - 
*                B    * - 3 4 5 6 7    *B1=1
* 
*         THIS ROUTINE ENDS A SEQUENCE SO X-REGISTERS MAY BE FREELY USED
          SPACE  4
          ENTRY  C.RN1ND
 C.RN1ND  SA1    =X_C.ZEROS  NOW MOST SIGNIFICANT DIGITS OF SOURCE
          BX4    X0 
          LX4    -14
          MX7    0
          PL     X4,C.RN2ND1           UNSIGNED SOURCE
          BX7    X2          SET SIGN OF SOURCE 
          AX7    59          0 IF +,  777...777B IF - 
          BX2    X2-X7       ABSOLUTE VALUE OF SOURCE 
          EQ     C.RN2ND1    GO TO COMMON PROCESSING
          SPACE  4
          ENTRY  C.RN2ND
 C.RN2ND  BX7    X1          SET SIGN OF SOURCE 
          AX7    59          0 IF +,  777...777B IF - 
          BX1    X1-X7       ABSOLUTE VALUE OF MOST SIGNIFICANT DIGITS
          BX2    X2-X7       ABSOLUTE VALUE OF LEAST SIGNIFICANT DIGITS 
  
*      PERFORM SHIFTING/PADDING ACCORDING TO SHIFT INDICATOR
  
 C.RN2ND1 BSS    0           (MERGE TO HERE FROM ENTRIES) 
          LX0    -14
          MX4    -4 
          BX4    -X4*X0      SHIFT INDICATOR
          LX0    14          RESET X0 
          ZR     X4,PATHO    IF EXTENDED SHIFTING/PADDING 
          SB4    X4-10B      REMOVE BIAS
          NZ     B4,SCALE    IF SIMPLE SHIFTING/PADDING 
 C.RN2ND2 BSS    0           (RETURN FROM SHIFTING/PADDING) 
  
*      COMPUTE ADDRESS, ENDING CHARACTER POSITION, DESTINATION LENGTH 
  
          MX4    -5 
          BX4    -X4*X0      NUMERIC LENGTH OF DESTINATION
          SX6    X4-1        NUMERIC LENGTH OF DESTINATION - 1
          SX5    1S20/10+1
          IX3    X3+X6       CHARACTER OFFSET OF RIGHT-MOST DIGIT 
          IX5    X5*X3       (OFFSET/10) * 2'20 
          AX5    20          WORD OFFSET
          SB3    B3+X5       ADDRESS OF RIGHT-MOST WORD 
          IX4    X5+X5       WORD OFFSET * 2
          LX5    3           WORD OFFSET * 8
          IX4    X5+X4       WORD OFFSET * 10 
          IX3    X3-X4       CHARACTER OFFSET FROM NEW ADDRESS  (0 _ 9) 
          IX6    X6-X3       (LENGTH-1) - (OFFSET(=0_9))
          SB6    X6 
  
*      IF DESTINATION NEEDS SIGN, GO APPLY SOURCE SIGN
  
          LX0    -6          BIT 59 = 1 IFF DESTINATION IS SIGNED 
          NG     X0,SIGN     IF DESTINATION NEEDS SIGN
          LX0    6           RESET X0 
 C.RN2ND3 BSS    0           (RETURN FROM SIGN APPLICATION) 
  
*         X0 = DESCRIPTOR 
*         X1 = MOST SIGNIFICANT DIGITS OF SOURCE  (ALREADY SCALED)
*         X2 = LEAST SIGNIFICANT DIGITS OF SOURCE  (ALREADY SCALED) 
*         X3 = ENDING CHARACTER OFFSET FROM NEW ADDRESS  (0 _ 9)
*         X7 = SIGN OF SOURCE:  777...777B IF -, 0 IF + 
*         B1 = 1
*         B3 = ADDRESS OF RIGHT-MOST WORD 
*         B6 = (LENGTH-1) - (OFFSET(=X3)) 
*         B7 = RETURN ADDRESS 
  
*      SHIFT SOURCE REGISTERS TO BE ALIGNED WITH DESTINATION FIELD
  
          BX4    -X3
          SB4    9+X4 
          SB5    B4+B4       2* 
          SB4    B5+B5       4* 
          SB4    B4+B5       6* 
          LX1    X1,B4       ALIGN MOST SIGNIFICANT DIGITS
          LX2    X2,B4       ALIGN LEAST SIGNIFICANT DIGITS 
  
*      STORE INTO RIGHT-MOST WORD OF DESTINATION FIELD
  
          SA4    B3          LOAD DESTINATION WORD
          SA5    =X_C.MASK+X3+1    MASK TO CLEAR A HOLE 
          BX4    -X5*X4      CLEAR A HOLE 
          BX6    X5*X2       EXTRACT RIGHT-MOST DIGITS
          BX6    X6+X4       MERGE WITH DESTINATION WORD
          LE     B6,B0,C.RN2ND4    IF END OF FIELD REACHED
          SA6    B3          STORE DESTINATION WORD 
  
*      STORE INTO NEXT WORD OF DESTINATION FIELD
  
          SB3    B3-B1       ADDRESS OF THIS WORD 
          BX2    -X5*X2      REMAINDER OF LEAST SIGNIFICANT REGISTER
          BX6    X5*X1       LEAST PART OF MOST SIGNIFICANT REGISTER
          BX6    X6+X2       MERGE THEM 
          SB6    B6-10       DECREMENT DESTINATION LENGTH 
          LE     B6,B0,C.RN2ND4    IF END OF FIELD REACHED
          SA6    B3          STORE DESTINATION WORD 
  
*      SET UP LAST WORD OF DESTINATION FIELD
  
          SB3    B3-B1       ADDRESS OF THIS WORD 
          BX6    -X5*X1      REMAINDER OF MOST SIGNIFICANT DIGITS 
          SB6    B6-10       SET CONSISTENT LENGTH FOR COMMON PROCESSING
  
*      FILL OUT LEFT-MOST WORD AND STORE
  
 C.RN2ND4 SA4    B3          PICK UP LEFT-MOST WORD 
          SB6    -B6
          SA5    =X_C.MASK+B6  MASK TO STRIP EXCESS DIGITS
          BX6    -X5*X6      STRIP EXCESS SOURCE DIGITS 
          BX4    X5*X4       KEEP SURROUNDING NON-DESTINATION CHARACTERS
          BX6    X4+X6       MERGE BOTH PARTS 
          SA6    B3          STORE LEFT-MOST DESTINATION WORD 
          JP     B7          EXIT 
          TITLE  SCALE
**        SCALE -  SCALE THE RESULT WITHIN A SINGLE REGISTER
* 
*         X0 = DESCRIPTOR 
*         X1 = MOST SIGNIFICANT DIGITS OF RESULT
*         X2 = LEAST SIGNIFICANT DIGITS OF RESULT 
*         B4 = SCALE
*         X7 = SIGN OF SOURCE:  777...777B IF -, 0 IF + 
* 
*         EQ     SCALE
*      OR EQ     SCALE1      (FOR RIGHT-SHIFTING) 
* 
*         SCALE IS CALLED FROM NORMAL PROCESSING FOR
*           -7 @ B4 @ 1,  OR  1 @ B4 @ 7. 
*         SCALE IS CALLED FROM PATHO FOR
*           -9 @ B4 @ -8,  OR  8 @ B4 @ 9.
* 
*         SHIFTS/PADS X1 AND X2 ACCORDING TO B4.
*         RESUMES NORMAL PROCESSING AT C.RN2ND2.
*         SCRATCH REGISTERS = B4, B5, X4, X5, A4, A5. 
  
  
 SCALE    NG     B4,SCALE1   IF SHIFTING RIGHT
          SA4    =X_C.MASK+B4 
          SB4    B4+B4       LEFT-SHIFT COUNT * 2 
          BX1    -X4*X1      RIGHT PART OF MOST SIGNIFICANT DIGITS
          SB5    B4+B4       LEFT-SHIFT COUNT * 4 
          BX5    X4*X2       LEFT PART OF LEAST SIGNIFICANT DIGITS
          SB4    B5+B4       LEFT-SHIFT COUNT * 6 
          BX1    X1+X5       NEW MOST SIG. DIGITS, UNSHIFTED
          SA5    =X_C.ZEROS  10H0000000000
          BX2    -X4*X2      RIGHT PART OF LEAST SIGNIFICANT DIGITS 
          LX1    X1,B4       NEW MOST SIGNIFICANT DIGITS
          BX5    X4*X5       LEFT PART OF LEAST SIG. DIGITS = ZEROS 
          IX2    X2+X5       NEW LEAST SIGNIFICANT DIGITS, UNSHIFTED
          LX2    X2,B4       NEW LEAST SIGNIFICANT DIGITS 
          EQ     C.RN2ND2    RESUME NORMAL PROCESSING 
  
  
*      SHIFTING RIGHT 
  
 SCALE1   SB5    -B4         SET INDEX TO MASK TABLE
          SA4    =X_C.MASK+B5 
          SB4    B4+10       -9_1, -8_2, ..., -1_9
          SB4    B4+B4       RIGHT-SHIFT COUNT * 2
          SB5    B4+B4       RIGHT-SHIFT COUNT * 4
          SB4    B5+B4       RIGHT-SHIFT COUNT * 6
          LX2    X2,B4       SHIFT LEAST SIGNIFICANT DIGITS 
          BX2    -X4*X2      RIGHT PART OF ELAST SIGNIFICANT DIGITS 
          LX1    X1,B4       SHIFT MOST SIGNIFICANT DIGITS
          BX5    X4*X1       LEFT PART OF MOST SIGNIFICANT DIGITS 
          BX2    X2+X5       COMPLETE LEAST SIGNIFICANT DIGITS
          SA5    =X_C.ZEROS  10H0000000000
          BX1    -X4*X1      RIGHT PART OF MOST SIGNIFICANT DIGITS
          BX5    X4*X5       LEFT PART = ZEROS
          IX1    X1+X5       COMPLETE MOST SIGNIFICANT DIGITS 
          EQ     C.RN2ND2    RESUME NORMAL PROCESSING 
          TITLE  SIGN 
**        SIGN -  APPLY SOURCE SIGN TO ALL BUT TRAILING SEPARATE SIGN 
* 
*         X0 = DESCRIPTOR  (SHIFT LEFT 54 BITS) 
*         X1 = MOST SIGNIFICANT DIGITS OF SOURCE  (ABSOLUTE VALUE)
*         X2 = LEAST SIGNIFICANT DIGITS OF SOURCE  (ABSOLUTE VALUE) 
*         X3 = ENDING CHARACTER OFFSET FROM NEW ADDRESS 
*         X7 = SIGN OF SOURCE:  777...777B IF -, 0 IF + 
*         B6 = (NUMERIC LENGTH OF DESTINATION) - 1 - OFFSET(=X3)
* 
*         EQ     SIGN 
* 
*         RESETS X0.
*         MODIFIES X1 OR X2 TO REPLECT SIGN.
*         ADJUSTS B6
*         RESUMES NORMAL PROCESSING AT C.RN2ND3.
  
  
 SIGN     LX0    6           RESET X0 
          BX6    X0          COPY DESCRIPTOR
          LX6    -7          BIT 59 = 1 IFF DESTINATION SIGN IS LEADING 
          MX5    -6          77777777777777777700B
          NG     X6,SIGN1    IF DESTINATION NEEDS LEADING SIGN
          LX6    -1          BIT 59 = 1 IFF DESTINATION SIGN IS SEPARATE
          NG     X6,SIGN5    IF TRAILING SEPARATE SIGN,  GO PROCESS 
  
*      DESTINATION NEEDS TRAILING OVERPUNCH SIGN
  
          PL     X7,C.RN2ND3 IF SOURCE IS POSITIVE
          BX4    -X5*X2      EXTRACT SIGN DIGIT 
          SA4    =X_C.ZN+X4-1R0  54/0, 6/(UNSIGNED DIGIT)&(SIGNED DIGIT)
          BX2    X2-X4       SET BITS 5-0 = SIGNED DIGIT
          EQ     C.RN2ND3    RESUME NORMAL PROCESSING 
  
  
*      DESTINATION HAS LEADING SIGN 
  
 SIGN1    LX6    -1          BIT 59 = 1 IFF DESTINATION SIGN SEPARATE 
          NG     X6,SIGN1A
          PL     X7,C.RN2ND3 EXIT IF SOURCE POSITIVE
 SIGN1A   MX4    -5 
          BX4    -X4*X0      NUMERIC LENGTH OF DESTINATION
          SB5    60          CONSTANT 60
          BX4    -X4         START TO COMPUTE LEFT-SHIFT COUNT TO 
          SB4    X4+B1         RIGHT-JUSTIFY MOST SIGNIFICANT DIGIT 
          PL     X6,SIGN1B   SIGN NOT SEPARATE
          SB4    B4-B1
 SIGN1B   BSS    0
          SB4    B4+B4       2* 
          SX4    B4+B4       4* 
          SB4    X4+B4       6* 
          SB4    B4+B5
          GT     B4,B0,SIGN3 IF SIGN SHOULD BE IN X2
          SB4    B4+B5       MAKE LEFT-SHIFT COUNT POSITIVE 
          LX1    X1,B4       BITS 5-0 = MOST SIGNIFICANT DIGIT
          SB4    B5-B4       LEFT-SHIFT COUNT TO RESET X1 
          PL     X6,SIGN2    IF DESTINATION NEEDS LEADING OVERPUNCH SIGN
  
*      DESTINATION NEEDS LEADING SEPARATE SIGN IN X1
  
          SX4    B1 
          BX1    X5*X1       BITS 5-0 = BINARY ZERO 
          BX4    X7*X4       1 IFF -
          SX4    X4+1R+ 
          ERRNZ  1+1R+-1R-   1+1R+ MUST EQUAL 1R- 
          BX1    X1+X4       INSERT SIGN CHARACTER
          LX1    X1,B4       RESET X1 
          SX3    X3+B1       INCREMENT CHAR. POS. OF RIGHT-MOST DIGIT 
          SB4    X3-10
          NZ     B4,C.RN2ND3 IF STILL IN SAME WORD,  DONE WITH SIGN 
          SX3    B0          CHARACTER POSITION OF RIGHT-MOST DIGIT = 0 
          SB3    B3+B1       INCREMENT ADDRESS OF RIGHT-MOST WORD 
          SB6    B6+10       NOTE EXTRA WORD TO STORE INTO
          EQ     C.RN2ND3    RESUME NORMAL PROCESSING 
  
  
*      DESTINATION NEEDS LEADING OVERPUNCH SIGN IN X1 
  
 SIGN2    PL     X7,SIGN2A   IF SOURCE IS POSITIVE
          BX4    -X5*X1      EXTRACT SIGN DIGIT 
          SA4    =X_C.ZN+X4-1R0  54/0, 6/(UNSIGNED DIGIT)&(SIGNED DIGIT)
          BX1    X1-X4       SET BITS 5-0 = SIGNED DIGIT
 SIGN2A   BSS    0
          LX1    X1,B4       RESET X1 
          EQ     C.RN2ND3    RESUME NORMAL PROCESSING 
  
  
*      SIGN SHOULD BE IN X2 
  
 SIGN3    LX2    X2,B4       BITS 5-0 = MOST SIGNIFICANT DIGIT
          SB4    B5-B4       LEFT-SHIFT COUNT TO RESET X2 
          NG     X6,SIGN4    IF DESTINATION NEEDS LEADING SEPARATE SIGN 
  
*      DESTINATION NEEDS LEADING OVERPUNCH SIGN IN X2 
  
          PL     X7,SIGN3A   IF SOURCE IS POSITIVE
          BX4    -X5*X2      EXTRACT SIGN DIGIT 
          SA4    =X_C.ZN+X4-1R0  54/0, 6/(UNSIGNED DIGIT)&(SIGNED DIGIT)
          BX2    X2-X4       BITS 5-0 = SIGNED DIGIT
 SIGN3A   BSS    0
          LX2    X2,B4       RESET X2 
          EQ     C.RN2ND3    RESUME NORMAL PROCESSING 
  
  
*      DESTINATION NEEDS LEADING SEPARATE SIGN IN X2
  
 SIGN4    SX4    B1 
          BX2    X5*X2       BITS 5-0 = BINARY ZERO 
          BX4    X7*X4       1 IFF -
          SX4    X4+1R+ 
          ERRNZ  1+1R+-1R-   1+1R+ MUST EQUAL 1R- 
          BX2    X2+X4       INSERT SIGN CHARACTER
          LX2    X2,B4       RESET X2 
          SX3    X3+B1       NOTE NEW ECP 
          SB4    X3-10
          NZ     B4,C.RN2ND3 IF LAST WORD IS STILL REALLY LAST
          BX3    X0-X0       NEW ECP = 0
          SB3    B3+B1       INCREMENT ADDRESS OF LAST WORD 
          SB6    B6+10
          EQ     C.RN2ND3    RESUME NORMAL PROCESSING 
  
  
*      DESTINATION NEEDS TRAILING SEPARATE SIGN 
  
 SIGN5    LX1    6           SHIFT SOURCE LEFT BY 1 CHARACTER 
          BX1    X5*X1
          LX2    6
          BX4    -X5*X2 
          SX3    X3+B1       MAKE ROOM ON RIGHT FOR SIGN CHARACTER
          BX1    X1+X4       COMPLETE X1
          SB4    X3-10       PREPARE CHECK FOR OFFSET OVERFLOWING WORD
          BX2    X5*X2       BITS 5-0 OF X2 = BINARY ZERO 
          SX4    B1 
          BX7    X7*X4       1 IFF -
          SX4    X7+1R+      SIGN CHARACTER 
          ERRNZ  1+1R+-1R-   1+(+) MUST EQUAL (-) 
          BX2    X2+X4       COMPLETE X2
          NZ     B4,C.RN2ND3 IF SIGN WILL NOT OVERFLOW DESTINATION WORD 
          SX3    B0          RESET OFFSET TO BEGINNING OF NEXT WORD 
          SB3    B3+B1       ADVANCE TO NEXT DESTINATION WORD 
          SB6    B6+10       NOTE EXTRA WORD TO STORE INTO
          EQ     C.RN2ND3    RESUME NORMAL PROCESSING 
          TITLE  PATHO
**        PATHO -  PATHOLOGICAL SHIFTING/PADDING
* 
*         X0 = DESCRIPTOR 
*         X1 = MOST SIGNIFICANT DIGITS OF RESULT
*         X2 = LEAST SIGNIFICANT DIGITS OF RESULT 
*         X7 = SIGN OF SOURCE.
* 
*         EQ     PATHO
* 
*         SHIFTS/PADS X1 AND X2 ACCORDING TO DESCRIPTOR.
*         MAY CALL *SCALE* TO DO THE WORK  (IF SHORT CASE). 
*         RESUMES NORMAL PROCESSING AT C.RN2ND2.
*         SCRATCH REGISTERS = B4, B5, X4, X5, A4, A5. 
  
  
 PATHO    UX4    B4,X0       EXTRACT EXTENDED SHIFT INDICATOR 
          NG     B4,PATHO2   IF SHIFTING RIGHT
          SB5    10 
          LT     B4,B5,SCALE IF SHIFTING WITHIN A SINGLE REGISTER 
          EQ     B4,B5,PATHO1  IF NOT REALLY SHIFTING 
          SB4    B4-B5
  
*      LEFT-SHIFT X2 BY B4 CHARACTERS INTO X1.
*      THEN SET X2 = ZEROS. 
  
          SA4    =X_C.MASK+B4 
          SB4    B4+B4       LEFT-SHIFT COUNT * 2 
          BX1    -X4*X2      RIGHT PART OF X2 
          SA2    =X_C.ZEROS  10H0000000000
          SB5    B4+B4       LEFT-SHIFT COUNT * 4 
          BX2    X4*X2       LEFT PART = ZEROS
          SB4    B5+B4       LEFT-SHIFT COUNT * 6 
          IX1    X2+X1       COMPLETE MOST SIGNIFICANT DIGITS 
          LX1    X1,B4       SHIFT
          EQ     C.RN2ND2    RESUME NORMAL PROCESSING 
  
  
*      LEFT-SHIFT EXACTLY 10 DIGITS 
  
 PATHO1   BX1    X2          SET MOST SIGNIFICANT DIGITS = LEAST SIG. 
          NO
          SA2    =X_C.ZEROS  SET LEAST SIGNIFICANT DIGITS = ZEROS 
          EQ     C.RN2ND2    RESUME NORMAL PROCESSING 
  
  
*      RIGHT-SHIFT
  
 PATHO2   SB5    -10
          GT     B4,B5,SCALE1  IF SHIFTING WITHIN SINGLE REGISTER 
          EQ     B4,B5,PATHO3  IF NOT REALLY SHIFTING 
  
*      RIGHT-SHIFT X1 INTO X2 ACCORDING TO B4.
*      THEN SET X1 = ZEROS. 
  
          SB4    B4+20       -17_3, -16_4, ..., -11_9 
          SB4    B4+B4       LEFT-SHIFT COUNT * 2 
          SB5    B4+B4       LEFT-SHIFT COUNT * 4 
          SB4    B5+B4       LEFT-SHIFT COUNT * 6 
          LX2    X1,B4       SHIFT
          SA1    =X_C.ZEROS  SET MOST SIGNIFICANT DIGITS = ZEROS
          EQ     C.RN2ND2    RESUME NORMAL PROCESSING 
  
  
*      RIGHT-SHIFT EXACTLY 10 DIGITS
  
 PATHO3   BX2    X1          SET LEAST SIGNIFICANT DIGITS = MOST SIG. 
          NO
          SA1    =X_C.ZEROS  SET MOST SIGNIFICANT DIGITS = ZEROS
          EQ     C.RN2ND2    RESUME NORMAL PROCESSING 
          SPACE  4
          END 
