*DECK C$RERCT 
          IDENT  C$RERCT
          TITLE  C.RERCT - BUMP RERUN COUNT AND TAKE RERUN DUMP WHEN DUE
          COMMENT RERUN COUNT AND RERUN DUMP PROGRAM
          SST 
          B1=1
*         THIS PROGRMM COUNTS RECORDS FOR RERUN 
*         WHEN THE COUNT IS AATISFIED, D.RERUN IS INVOKED 
*          AND A CHECKPOINT DUMP IS TAKEN 
* 
  
*CALL IOMICROS
*CALL IODEFSC 
          ENTRY  C.RERCT
 C.RERCT  DATA   0
          FETCH  A0,RERP,X2  GET RERUN PERIOD 
          ZR     X2,C.RERCT  EXIT IF NO COUNT EXPECTED
          FETCH  A0,RERC,X5  GET COUNT UP TO NOW
          LX2    30 
          NG     X2,CKRLSWP  CK FOR REEL SWAP IF RERUN ON EOR 
          AX2    30          EXTEND SIGN
          IX2    X5-X2
          SX0    B1          X0 IS USED IN INCREMENTING.
          IX2    X2+X0
          NG     X2,BMPCT    JUMP IF COUNT NOT MET
 DORRN    BSS    0
          RJ     C.RERUN     DO CHECKPOINT
          SX2    B0 
          EQ     STCT        GO CLEAR COUNT 
 BMPCT    IX2    X5+X0       BUMP COUNT.
 STCT     STORE  A0,RERC=X2 
          EQ     C.RERCT
 CKRLSWP  BSS    0
          ZR     X5,C.RERCT  EXIT IF NO EOR 
          EQ     DORRN       GO DO RERUN DUMP 
          ENTRY  C.RERUN
 C.RERUN  DATA   0           TAKE RERUN DUMP
          SX6    B0 
          SA6    RBUKET 
          SA2    COBCODE
          MX4    42 
          SX3    50B
          BX2    X4*X2
          IX6    X2+X3       PUT IN REWIND CODE 
          SA6    A2 
          SYSTEM CIO,RCL,COBCODE   REWIND THE OVERLAY FILE, IF ANY
          CHECKPT  RBUKET    DO CHECKPOINT
          SB2    =YC.STOP2
          NG     B2,NOMCS 
          SX1    10B         CHECK POINT REQUEST FOR MCS
          RJ     =YC.STOP2
 NOMCS    BSS    0
 CDCS1    IFEQ   OP.DCS,OP.DCS1 
          SA5    =XC.CDCS 
          ZR     X5,C.RERUN  JUMP IF RUN DOES NOT USE CDCS
          SX6    A0 
          SA6    =XC.BUFF    SAVE A0 ACROSS CDCS CALL 
          SA1    RBUKET 
          MX5    48          CHECKPOINT NUMBER TO BITS 12-0 OF -RBUKET- 
          LX1    12 
          BX6    -X5*X1 
          SA6    A1 
          SA1    CKPN 
          RJ     =XDM$CKP    CDCS  CHECKPOINT 
          SB1    1           RESTORE B1 
          SA5    =XC.BUFF    RESTORE A0 
          SA0    X5 
          EQ     C.RERUN
 CKPN     VFD    42/0,18/RBUKET 
 CDCS1    ENDIF 
          EQ     C.RERUN
 RBUKET   DATA   0
 COBCODE  DATA   7LCOBCODE         DUMMY FET
          VFD    42/0,18/C.RERUN
          VFD    42/0,18/C.RERUN
          VFD    42/0,18/C.RERUN
          VFD    42/0,18/C.RERUN+64 
          END 
