*DECK C$R1S02 
          IDENT  C$R1S02
          TITLE  C.R1S02 -  COMP-1 TO 2 DIGIT SIGNED NUMERIC DISPLAY
  
          MACHINE  ANY,I
          COMMENT  COMP-1 TO 2-DIGIT SIGNED NUMERIC DISPLAY 
          SPACE  4
**        C.R1S02 -  COMP-1 TO 2 DIGIT SIGNED NUMERIC DISPLAY 
* 
*         X1 = SIGNED COMP-1 VALUE
*                0 @ ABSOLUTE VALUE OF X1 < 10'2
*         RJ     C.R1S02
* 
*         SETS X1 = 10 DIGIT NUMERIC DISPLAY VALUE. 
*           (NINES COMPLEMENT IF NEGATIVE.) 
*           (MOST SIGNIFICANT 8 DIGITS ARE ZERO OR NINE.) 
* 
*         USES-  X  0 1 2 3 - - - - 
*                A  - - - 3 - - - - 
*                B    - - - - - - - 
  
  
          ENTRY  C.R1S02
 C.R1S02  DATA   0
          BX0    X1          COPY REGISTER WITH SIGN
          AX0    59          000...000B IF +,  777...777B IF -
          SX2    1S20/10+1
          BX1    X1-X0       ABSOLUTE VALUE OF INPUT
          IX2    X1*X2       M.N * 2'20 
          AX2    20          M
          IX3    X2+X2       2*M
          LX2    3           8*M
          IX3    X2+X3       10*M 
          IX1    X1-X3       (10*M+N) - 10*M = N
          SA3    =XC.ZEROS   10H0000000000
          LX2    3
          BX1    X1+X2
          IX1    X1+X3       BIAS BY DISPLAY ZEROS
          BX1    X1-X0       APPLY THE SIGN 
          EQ     C.R1S02     EXIT 
  
  
          END 
