*DECK C$PURGE 
          IDENT  C$PURGE
          TITLE  C$PURGE - MCS INTERFACE FOR PURGE
          MACHINE ANY,I 
          COMMENT MCS INTERFACE FOR PURGE VERB
          SST 
          B1=1
          SPACE  5
* 
**        C.PURGE - MCS REQUEST FOR PURGE VERB
* 
*         INPUT 
*                A0  CD ADDRESS 
*                B4  MAXIMUM LENGTH OF CD 
* 
*         OUTPUT
*                NONE 
* 
*         DOES
*                SETS UP MCS REQUEST FOR PURGE
*                CALLS MCS
*                ERROR ANALYSIS BEFORE AND AFTER CALLING MCS
* 
*         USES
*                A  0 1 - - - - 6 7 
*                X  0 1 2 3 - - - - 
*                B  - 1 2 - 4 - - - 
          EJECT 
          EXT    DEBUG
          EXT    C.MCS1      UTILITY TO CALC CDL AND CDLP 
          EXT    C.MCS3      PROGRAM-ID AND LINE NUMBER UTILITY 
          EXT    C.MCS4      OUTPUT CD POST MORTEM
          USE    /C.MCSPB/
 MCSPB    BSS    64 
 CDADDR   BSS    1
          USE    *
          ENTRY  C.PURGE
 C.PURGE  DATA   0
          SA1    C.PURGE
          RJ     =XC.MCS3    PROGRAM-ID CBLNO *APPLE UTILITY
          MX6    0
          SA6    MCSPB+2     FLAGS=0,EI=0,FDC=0,FDWA=0,DL=0 
          SX4    59          FREE = 59
          RJ     =XC.MCS1    CALCULATE CDL IN X2 AND CDLP IN B2 
          SX1    05B
          LX1    54          X1 = REQ 
          SX7    A0          X3 = CDA 
          SA7    CDADDR      SAVE CD ADDRESS FOR POST MORTEM
          LX7    18 
          BX1    X1+X7       X1 = REQ 0 CDA 
          BX6    X1+X2       X1 = REQ 0 CDA CDL 
          SA6    MCSPB+1     STORE WORD 1 
          SX3    B2+4        X3 = WC = CDLP + 4 
          LX3    18 
          MX1    1
          LX1    14 
          BX6    X3+X1       X6 = 0 SW 0 RT ES C
          SA6    A6-B1       STORE MCSPB WORD 0 
          IFC    EQ,/"OSNAME"/SCOPE / 
          CALLSS OP.MCS1,MCSPB,R
          ELSE
          CALLSS OP.MCS2,MCSPB,R
          ENDIF 
          RJ     =XC.MCS4    OUTPUT CD POST MORTEM
          EQ     C.PURGE
          END 
