*DECK C$OBOP
          IDENT  C$OBOP 
          SST 
          TITLE  C$OBOP - OLD BINARY OPEN 
          COMMENT  OLD BINARY OPEN (PRE CRM15)
* 
**        CBOBOP - OLD BINARY OPEN
* 
*         DOES - INTERCEPTS OPEN REQUESTS FROM PRE COBOL 5.2 CRM 1.5
*                BINARY DECKS AND MAPS THEM INTO THE NEW FORM AS WELL AS
*                MAPS THE OLD FIT INTO THE NEW FIT. 
*                WILL ONLY ACCEPT DECKS CREATED AT AND AFTER LEVEL 446. 
* 
 CDCS1    IFNE   OP.DCS,OP.NO 
          LDSET  LIB=DMSLIB 
 CDCS1    ENDIF 
*CALL IODEFSC 
*CALL IOMICROS
 #ALFN#   MICRO  1,,/0,0,60,0,0,1/
 #APM#    MICRO  1,,/0,1,1,35,0,1/
 #AFO#    MICRO  1,,/0,1,3,32,0,1/
 #ABT#    MICRO  1,,/0,1,3,28,0,1/
 #ABCK#   MICRO  1,,/0,1,1,27,0,1/
 #ART#    MICRO  1,,/0,1,4,22,0,1/
 #ALT#    MICRO  1,,/0,2,2,28,0,1/
 #AULP#   MICRO  1,,/0,2,3,25,0,1/
 #AMNR#   MICRO  1,,/0,3,24,36,0,1/ 
 #ABFS#   MICRO  1,,/0,3,18,18,0,1/ 
 #ATL#    MICRO  1,,/0,4,24,36,0,1/ 
 #AERL#   MICRO  1,,/0,5,9,36,0,1/
 #ASPR#   MICRO  1,,/0,5,1,33,0,1/
 #AEXD#   MICRO  1,,/0,5,1,32,0,1/
 #ASDS#   MICRO  1,,/0,5,1,31,0,1/
 #AFWI#   MICRO  1,,/0,5,1,28,0,1/
 #AHB#    MICRO  1,,/0,5,1,24,0,1/
 #AMRL#   MICRO  1,,/0,6,24,36,0,1/ 
 #ACM#    MICRO  1,,/0,6,1,25,0,1/
 #AEO#    MICRO  1,,/0,6,3,22,0,1/
 #AIP#    MICRO  1,,/0,7,7,29,0,1/
 #ADP#    MICRO  1,,/0,7,7,22,0,1/
 #AMFN#   MICRO  1,,/0,7,36,24,0,1/ 
 #APNO#   MICRO  1,,/0,7,24,0,0,1/
 #AMNB#   MICRO  1,,/0,8,24,36,0,1/ 
 #ARMK#   MICRO  1,,/0,8,8,28,0,1/
 #APC#    MICRO  1,,/0,8,6,22,0,1/
 #ACP#    MICRO  1,,/0,9,24,36,0,1/ 
 #ALP#    MICRO  1,,/0,9,24,36,0,1/ 
 #ARB#    MICRO  1,,/0,9,14,22,0,1/ 
 #ASBF#   MICRO  1,,/0,10,1,58,0,1/ 
 #AC1#    MICRO  1,,/0,10,1,42,0,1/ 
 #ACL#    MICRO  1,,/0,10,6,36,0,1/ 
 #ALL#    MICRO  1,,/0,10,6,36,0,1/ 
 #ATRC#   MICRO  1,,/0,11,06,18,0,1/
 #AMUL#   MICRO  1,,/0,11,6,30,0,1/ 
 #AMBL#   MICRO  1,,/0,12,24,36,0,1/
 #ANL#    MICRO  1,,/0,12,6,30,0,1/ 
 #AOVF#   MICRO  1,,/0,12,2,28,0,1/ 
 #AFLM#   MICRO  1,,/0,12,28,0,0,1/ 
 #AIBL#   MICRO  1,,/0,13,24,36,0,1/
 #AXN#    MICRO  1,,/0,16,42,18,0,1/
*      ITEMS IN COBOL FIT EXTENSIONS
 #ALABT#  MICRO  1,,/0,29,02,48,0,1/
 #AKEYT#  MICRO  1,,/0,33,18,00,0,1/
          EJECT 
          TITLE  C.LABLS - LABEL PROCESSING ROUTINE 
          ENTRY  C.LABLS
 C.LABLS  DATA   0           LABEL PROCESSING ROUTINE 
          SB4    B1          SET LENGTH OF EXTRA WORDS (1 FOR SQ) 
          RJ     MAPIT       MAP OLD FIT INTO NEW FIT (IF NEEDED) 
          RJ     =XC.LABLI   GO TO REGULAR LABEL PROCESS ROUTINE
          EQ     C.LABLS     EXIT 
          EJECT 
          TITLE  C.OPXXX - OPEN ROUTINES
          ENTRY  C.OPIAK
          ENTRY  C.OPMAK
          ENTRY  C.OPOAK
          ENTRY  C.OPIDA
          ENTRY  C.OPMDA
          ENTRY  C.OPODA
          ENTRY  C.OPIIS
          ENTRY  C.OPMIS
          ENTRY  C.OPOIS
          ENTRY  C.OPIRL
          ENTRY  C.OPMRL
          ENTRY  C.OPORL
          ENTRY  C.OPISQ
          ENTRY  C.OPESQ
          ENTRY  C.OPMSQ
          ENTRY  C.OPOSQ
          ENTRY  C.OPIWA
          ENTRY  C.OPMWA
          ENTRY  C.OPOWA
  
 C.OPIAK  BSS    0           OPEN INPUT ACUTAL KEY
          SB7    =XC.OPAK 
          SB5    =XC.OPIN 
          SX4    =XC.CLOAK   ADDRESS OF CLOSE ROUTINE 
          EQ     MAPPER1
 C.OPMAK  BSS    0           OPEN IO ACTUAL KEY 
          SB7    =XC.OPAK 
          SB5    =XC.OPIO 
          SX4    =XC.CLOAK
          EQ     MAPPER1
 C.OPOAK  BSS    0           OPEN OUTPUT ACUTAL KEY 
          SB7    =XC.OPAK 
          SB5    =XC.OPOUT
          SX4    =XC.CLOAK
          EQ     MAPPER1
  
  
 C.OPIDA  BSS    0           OPEN INPUT DIRECT
          SB7    =XC.OPDA 
          SB5    =XC.OPIN 
          SX4    =XC.CLODA
          EQ     MAPPER1
 C.OPMDA  BSS    0           OPEN IO DIRECT 
          SB7    =XC.OPDA 
          SB5    =XC.OPIO 
          SX4    =XC.CLODA
          EQ     MAPPER1
 C.OPODA  BSS    0           OPEN OUTPUT DIRECT 
          SB7    =XC.OPNDA
          SB5    =XC.OPOUT
          SX4    =XC.CLODA
          EQ     MAPPER1
  
  
 C.OPIIS  BSS    0           OPEN INPUT INDEXED 
          SB7    =XC.OPIS 
          SB5    =XC.OPIN 
          SX4    =XC.CLOIS
          EQ     MAPPER1
 C.OPMIS  BSS    0           OPEN IO INDEXED
          SB7    =XC.OPIS 
          SB5    =XC.OPIO 
          SX4    =XC.CLOIS
          EQ     MAPPER1
 C.OPOIS  BSS    0           OPEN OUTPUT INDEXED
          SB7    =XC.OPIS 
          SB5    =XC.OPOUT
          SX4    =XC.CLOIS
          EQ     MAPPER1
  
  
 C.OPIRL  BSS    0           OPEN INPUT RELATIVE
          SB7    =XC.OPRL 
          SB5    =XC.OPIN 
          SX4    =XC.CLORL
          EQ     MAPPER4
 C.OPMRL  BSS    0           OPEN IO RELATIVE 
          SB7    =XC.OPRL 
          SB5    =XC.OPIO 
          SX4    =XC.CLORL
          EQ     MAPPER4
 C.OPORL  BSS    0           OPEN OUTPUT RELATIVE 
          SB7    =XC.OPRL 
          SB5    =XC.OPOUT
          SX4    =XC.CLORL
          EQ     MAPPER4
  
  
 C.OPISQ  BSS    0           OPEN INPUT SEQUENTIAL
          SB7    =XC.OPSQ 
          SB5    =XC.OPIN 
          SX4    =XC.CLOSQ
          EQ     MAPPER1
 C.OPESQ  BSS    0           OPEN EXTEND SEQUENTIAL 
          SB7    =XC.OPSQ 
          SB5    =XC.OPEXT
          SX4    =XC.CLOSQ
          EQ     MAPPER1
 C.OPMSQ  BSS    0           OPEN IO SEQUENTIAL 
          SB7    =XC.OPSQ 
          SB5    =XC.OPIO 
          SX4    =XC.CLOSQ
          EQ     MAPPER1
 C.OPOSQ  BSS    0           OPEN OUTPUT SEQUENTIAL 
          SB7    =XC.OPSQ 
          SB5    =XC.OPOUT
          SX4    =XC.CLOSQ
          EQ     MAPPER1
  
  
 C.OPIWA  BSS    0           OPEN INPUT WORD-ADDRESS
          SB7    =XC.OPWA 
          SB5    =XC.OPIN 
          SX4    =XC.CLOWA
          EQ     MAPPER1
 C.OPMWA  BSS    0           OPEN IO WORD-ADDRESS 
          SB7    =XC.OPWA 
          SB5    =XC.OPIO 
          SX4    =XC.CLOWA
          EQ     MAPPER1
 C.OPOWA  BSS    0           OPEN OUTPUT WORD-ADDRESS 
          SB7    =XC.OPWA 
          SB5    =XC.OPOUT
          SX4    =XC.CLOWA
          EQ     MAPPER1
  
  
 MAPPER1  BSS    0           EXTRA WORDS OF 1 
          SB4    1
          EQ     MAPPER 
 MAPPER4  BSS    0           EXTRA WORDS OF 4 
          SB4    4
          EQ     MAPPER 
  
 MAPPER   BSS    0
          BX7    X1 
          SA7    =SSAVEX1    SAVE X1
          SX6    B3 
          SA6    =SSAVEB3    SAVE B3
          BX6    X4 
          SA6    =SCLOSEAD   SAVE ADDRESS OF CLOSE ROUTINE
          RJ     MAPIT       DO MAPPING 
          SA1    CLOSEAD     GET SAVED CLOSE ADDRESS
          STORE  A0,CLOA=X1  SET CLOSE ROUTINE ADDRESS
          SA5    SAVEB3 
          SA1    SAVEX1      RESTORE X1 
          SB3    X5          REWTORE B3 
          JP     B7          GO TO PROPER OPEN ROUTINE
          EJECT 
          TITLE  MAPIT - MAPPING ROUTINE
 MAPIT    DATA   0
          SX1    A0+35       LENGTH OF NEW FIT/FET
          SA1    X1+B4       LEN + EXTRA WORDS GIVES FLAG WORD
          SA2    =O52525252525252525252 
          IX1    X1-X2
          ZR     X1,OKFIT    JP IF 446 OR LATER FIT 
          SA1    A0          GET WORD 1 
          MX2    42 
          BX2    -X2*X1      GET LOWER 18 BITS
          NZ     X2,LEAVE    EXIT IF NEW FIT - ALREADY TRANSLATED 
          SX1    #OBNC
          RJ     =XC.FIOER   ERROR - BAD FIT - CANNOT BE CONVERTED
 OKFIT    BSS    0
*         MAP OLD FIT INTO NEW FIT
*         FIRST STEP - ZERO OUT FIT AREA
* 
          SX7    B0 
          SA7    FITAREA
          SB2    35-1        FIT/FET LENGTH - 1 
 INITZRO  SB2    B2-B1       DECREMENT COUNT
          SA7    A7+B1
          NE     B2,INITZRO  LOOP UNTIL DONE
* 
*         STEP2 -- MOVE COBOL EXTENSION 
* 
          SA1    A0+29       FETCH OLD FIRST WORD OF EXTENSION
          SB2    B4+6        EXTRA WORDS + EXTENSION LENGTH 
 MOVFTZ   SB2    B2-B1       DECREMENT COUNT
          BX7    X1 
          SA7    A7+B1
          SA1    A1+B1
          NE     B2,MOVFTZ   LOOP UNTIL DONE
* 
*         STEP 2A -- FIX UP EXTENSIONS
* 
          SX3    FITAREA
          FETCH  A0,ALABT,X2 GET LABEL TYPE 
          FETCH  A0,AKEYT,X1 GET KEY TABLE ADDRESS
          STORE  X3,LABT=X2 
          STORE  X3,KEYT=X1 
* 
*      STEP 2B -- PUT IN NEW FIELDS 
* 
          STORE  X3,LNG=#CBL#      SET TO COBOL FIT 
* 
*         STEP 3 -- MOVE FIT FIELDS 
* 
* 
* WORD 0
          FETCH  A0,ALFN,X2  LOGICAL FILE NAME
          STORE  X3,LFN=X2
* 
* WORD 1
          FETCH  A0,AMNB,X2  MIN. BLOCK LENGTH IN CHARS. (FROM WORD 8)
          STORE  X3,MNB=X2
          FETCH  A0,AFO,X1   FILE ORGANIZATION
          STORE  X3,FO=X1 
          SX2    X1-#SQ#     IS FO=SQ 
          ZR     X2,WD1A     JUMP IF YES
          STORE  X3,MNB=B0   CLEAR FOR OVERLAP
          FETCH  A0,APM,X2   PROCESSING MODE
          RJ     MOV1BIT     ALLIGN 1-BIT FIELDS FOR STORE
          STORE  X3,PM=X2 
 WD1A     BSS    0
          FETCH  A0,ABT,X2   BLOCK TYPE 
          STORE  X3,BT=X2 
          FETCH  A0,ABCK,X2  BLOCK CHECKSUMS
          RJ     MOV1BIT     ALLIGN 1-BIT FIELDS FOR STORE
          STORE  X3,BCK=X2
          FETCH  A0,ART,X4   RECORD TYPE
          STORE  X3,RT=X4 
* 
* WORD 2
          FETCH  A0,ALT,X2   LABEL TYPE 
          STORE  X3,LT=X2 
          FETCH  A0,AULP,X2  USER LABEL PROCESSING
          STORE  X3,ULP=X2
* 
* WORD 3
          FETCH  A0,AMNR,X2  MAXIMUM RECORD LENGTH
          STORE  X3,MNR=X2
          FETCH  A0,ABFS,X2  BUFFER SIZE
          SX5    X1-#RELF#
          ZR     X5,WD3A1    JP IF RELATIVE 
          SX5    X1-#WA#
          NZ     X5,WD3A     JP IF NOT WORD ADDRESS 
 WD3A1    BSS    0
          NZ     X2,WD3A     JP IF BFS GIVEN
          SX2    202B        USE 2 PRUS 
 WD3A     BSS    0
          STORE  X3,BFS=X2
* 
* WORD 4
          FETCH  A0,ATL,X2   LENGTH OF TRAILER PORTION OF T TYPE RECORDS
          STORE  X3,TL=X2 
* 
* WORD 5
          FETCH  A0,AERL,X2  TRIVIAL ERROR LIMIT
          STORE  X3,ERL=X2
          FETCH  A0,ASPR,X2  SUPPRESS READ AHEAD
          RJ     MOV1BIT     ALLIGN 1-BIT FIELDS FOR STORE
          STORE  X3,SPR=X2
          FETCH  A0,AEXD,X2  EXTENDED DIAGNOSTIC FLAG 
          RJ     MOV1BIT     ALLIGN 1-BIT FIELDS FOR STORE
          STORE  X3,EXD=X2
          FETCH  A0,ASDS,X2  SYSTEM MESSAGE DISPOSITION 
          RJ     MOV1BIT     ALLIGN 1-BIT FIELDS FOR STORE
          STORE  X3,SDS=X2
          FETCH  A0,AFWI,X2  FORCED WRITE OF IS,AK,DA FILE BLOCKS 
          RJ     MOV1BIT     ALLIGN 1-BIT FIELDS FOR STORE
          STORE  X3,FWI=X2
          FETCH  A0,AHB,X2   USER HEADER OPTION AK FILES
          RJ     MOV1BIT     ALLIGN 1-BIT FIELDS FOR STORE
          STORE  X3,HB=X2 
* 
* WORD 6
          FETCH  A0,AMRL,X2  MAXIMUM RECORD LENGTH IN CHARACTERS
          STORE  X3,MRL=X2
          FETCH  A0,ACM,X2   CONVERSION MODE
          RJ     MOV1BIT     ALLIGN 1-BIT FIELDS FOR STORE
          STORE  X3,CM=X2 
          FETCH  A0,AEO,X2   ERROR OPTION 
          STORE  X3,EO=X2 
* 
* WORD 7
          SX2    X1-#SQ#     SEE IF FILE ORGANIZATION IS SEQUENTIAL 
          ZR     X2,WD7D     JUMP IF SEQUENTIAL 
          SX2    X1-#AK#     IS FO=AK 
          ZR     X2,WD7A     JUMP IF YES
          SX2    X1-#IS#     IS FO=IS 
          NZ     X2,WD7E     JUMP IF NOT
          FETCH  A0,AIP,X2   INDEX BLOCK PADDING (IS FILES) 
          STORE  X3,IP=X2 
 WD7A     FETCH  A0,ADP,X2   DATA BLOCK PADDING (IS AND AK) 
          STORE  X3,DP=X2 
          EQ     WD7E 
 WD7D     FETCH  A0,AMFN,X2  MULTI-FILE NAME
          STORE  X3,MFN=X2
          FETCH  A0,PNO,X2   MULTI-FILE POSITION NUMBER 
          STORE  X3,PNO=X2
 WD7E     BSS    0
* 
* WORD 8
          FETCH  A0,ARMK,X2  RECORD MARK CHARACTER
          STORE  X3,RMK=X2
          SX2    X1-#IS#     SEE IF FILE ORGANIZATION IS INDEXED SEQUEN.
          ZR     X2,WD8A     JUMP IF INDEXED SEQUENTIAL 
          FETCH  A0,APC,X2   PADDING CHARACTER FOR SEQUENTIAL FILE BLOCK
          STORE  X3,PC=X2 
 WD8A     BSS    0
* 
* WORD 9
          SX2    X4-#D#      SEE IF RECORD TYPE=D 
          ZR     X2,WD9A     JUMP IF RT=D 
          FETCH  A0,ACP,X2   BEG. CHAR. POSITION OF TRAILER COUNT FIELD 
          STORE  X3,CP=X2 
          EQ     WD9B 
 WD9A     FETCH  A0,ALP,X2   BEG. CHAR. POSITION OF LENGTH FIELD (RT=D) 
          STORE  X3,LP=X2 
 WD9B     BSS    0
          FETCH  A0,ARB,X2   NUM. RECORDS PER K TYPE BLOCK IN SQ FILES
          STORE  X3,RB=X2 
* 
* WORD 10 
          FETCH  A0,ASBF,X2  SUPPRESSED BUFFER I/O FLAG 
          RJ     MOV1BIT     ALLIGN 1-BIT FIELDS FOR STORE
          STORE  X3,SBF=X2
          FETCH  A0,AC1,X2   CL/LL FIELD FOR T/D RECORDS-BINARY FORMAT
          RJ     MOV1BIT     ALLIGN 1-BIT FIELDS FOR STORE
          STORE  X3,C1=X2 
          FETCH  A0,ART,X2
          SX2    X2-#D#      SEE IF RECORD TYPE=D 
          ZR     X2,WD10A    JUMP IF RT=D 
          FETCH  A0,ACL,X2   LENGTH OF TRAILER COUNT FIELD (RT=T) 
          STORE  X3,CL=X2 
          EQ     WD10B
 WD10A    FETCH  A0,ALL,X2   LENGTH OF D REC
          STORE  X3,LL=X2 
 WD10B    BSS    0
* 
* WORD 11 
          FETCH  A0,AMUL,X2  MULTIPLE OF CHARACTER PER K/E TYPE BLOCK 
          STORE  X3,MUL=X2
* 
* WORD 12 
          FETCH  A0,AMBL,X2  MAXIMUM BLOCK LENGTH 
          STORE  X3,MBL=X2
          FETCH  A0,ANL,X2   NUM. LEVELS OF INDEX BLOCKS IN AN IS FILE
          STORE  X3,NL=X2 
          FETCH  A0,AOVF,X2  DA FILE OVERFLOW 
          STORE  X3,OVF=X2
          FETCH  A0,AFLM,X2  FILE LIMIT, RECORDS/FILE (IS,AK,DA)
          STORE  X3,FLM=X2
* 
* WORD 13 
          FETCH  A0,AIBL,X2  INDEX BLOCK LENGTH (IN CHARACTERS) 
          STORE  X3,IBL=X2
* 
* WORD 14 
* 
* WORD 15 
* 
* WORD 16 
          FETCH  A0,AXN,X2   INDEX FILE NAME ASSOC. WITH MULTI-INDEX FIL
          STORE  X3,XN=X2 
* 
*         STEP 4 -- MOVE FITAREA INTO FIT 
* 
          SA4    FITAREA
          SB2    B4+35+6-1   EXT WDS + FIT/FET LEN + EXTWDS -1
          BX7    X4 
          SA7    A0 
 MOVNXT   SA4    A4+B1
          SB2    B2-B1
          BX7    X4 
          SA7    A7+B1
          NE     B2,MOVNXT   LOOP UNTIL DONE
          FETCH  A0,KEYT,X5  GET KEY TABLE ADDRESS
          ZR     X5,LEAVE    EXIT IF NONE 
* 
* REFORM KEY TABLE AND MOVE IT
* 
          SB2    B0 
          SB3    X5 
 COUNTKY  BSS    0
          SA1    B3          LOOK FOR END OF TABLE
          SB2    B2+B1       TALLY ENTRY
          SB3    B3+B1
          NZ     X1,COUNTKY  COUNT ANOTHER IF ANOTHER ENTRY 
          SX2    B2+B2       LENGTH OF KEY TABLE * 2
          MX3    0
          SB2    B7          SAVE B7 OVER CMM CALL
          SX0    B6          SAVE B6 AROUND CALL
          SX6    B5 
          LX6    18 
          IX0    X6+X0       SAVE B5 AND B6 
          RJ     =XCMM.ALF   GET SPACE FOR NEW KEY TABLE
          SB7    B2          RESTORE B7 
          SB6    X0          RESTORE B6, B5 
          AX0    18 
          SB5    X0 
          FETCH  A0,KEYT,X5  GET KEY TABLE ADDRESS (OLD ONE)
          SA2    X5          FETCH OLD KEY TABLE ENTRY
          STORE  A0,KEYT=X1  SET WITH NEW ADDRESS 
          MX7    0
          SB3    X1          ADDR OF NEW TABLE
 MKLOOP   BSS    0           MOVE KEY TABLE AND ADD NEW SECOND WORD 
          ZR     X2,ENDKEYS  LEAVE IF DONE
          BX6    X2 
          SA6    B3 
          SA7    B3+B1
          SB3    B3+2        BUMP TO NEXT ENTRY 
          SA2    A2+B1       GET NEXT ONE 
          EQ     MKLOOP 
 ENDKEYS  BSS    0
          MX6    0
          SA6    B3          SET TERMINATION WORD 
          SX7    10 
          SA7    B3+B1       SET MIN REC FOR Z RECS 
          SA2    X1          GET PRIMARY KEY INFO 
          LX2    15 
          MX6    60-15
          BX4    -X6*X2      GET KWNS (WORD NUMBER) 
          FETCH  A0,RECA,X5 
          IX4    X4+X5       ADDRESS OF KEY 
          STORE  A0,RKKA=X4  SAVE IT
          STORE  A0,PKA=X4   SAVE PRIMARY KEY ADDRESS 
          STORE  A0,RKIR=YES  SET PRIME KEY IN REC
          STORE  A0,EMK=YES  SET EMBEDDED KEY 
* 
* WRAP UP AND LEAVE 
* 
 LEAVE    BSS    0
          SA1    A0 
          SX2    B1 
          IX6    X1+X2
          SA6    A0          SET COMPLETE BIT TO FLAG CONVERTED 
          EQ     MAPIT       EXIT 
 MOV1BIT  DATA   0           ALLIGN 1-BIT FIT FIELDS FOR STORE
          MX0    1
          BX2    X2*X0
          LX2    1
          EQ     MOV1BIT
 FITAREA  BSS    35+6+4 
* 
*      THE FOLLOWING ENTRY POINTS ARE TO PREVENT LOADING OR UNSATISFIED 
*      ENTRY POINTS OF CRM 1.4 ROUTINES (COMI 
*      ENTRY POINTS OF CRM 1.4 ROUTINES (COPILER GENERATES REFS TO THEM)
* 
          ENTRY  GET.F
          ENTRY  GET.Z
          ENTRY  GET.T
          ENTRY  GET.D
          ENTRY  GET.R
          ENTRY  GET.W
          ENTRY  GET.U
          ENTRY  GET.S
          ENTRY  IS00OV 
 GET.F    BSS    0
 GET.Z    BSS    0
 GET.T    BSS    0
 GET.D    BSS    0
 GET.R    BSS    0
 GET.W    BSS    0
 GET.U    BSS    0
 GET.S    BSS    0
 IS00OV   BSS    0
          END 
