*DECK C$MCS5
          IDENT  C$MCS5 
          TITLE  C$MCS5 - INPUT CD POST MORTEM
          MACHINE ANY,I 
          COMMENT INPUT CD POST MORTEM
          SST 
          B1=1
          SPACE  5
* 
**        C.MCS5 - INPUT CD POST MORTEM 
* 
*         INPUT 
*                NONE 
* 
*         OUTPUT
*                B2  1      NO ERROR (ES=0 AND C=1) 
*                    OTHER  ERROR OF SOME SORT
* 
*         DOES
*                EXAMINES ERROR AND STATUS BITS 
*                UPDATES STATUS KEY IF NECESSARY
* 
*         USES
*                A  - 1 - - - - 6 - 
*                X  0 1 - - - - 6 - 
*                B  0 1 2 - - - - - 
          EJECT 
          USE    /C.MCSPB/
 MCSPB    BSS    64 
 CDADDR   BSS    1
          USE    *
          ENTRY  C.MCS5 
 C.MCS5   DATA   0
*                POST MORTEM ANALYSIS 
*                THE FOLLOWING CONDITIONS CAUSE STATUS KEY 90 
*                1) C = 0 COMPLETE BIT NOT SET (NEVER)
*                2) ES BIT 2 = 1 MCS BUSY (NEVER) 
*                3) ES BITS 6-11 NE 0 SYSTEM ERROR (NEVER)
*                THE FOLLOWING CONDITIONS CAUSE STATUS KEY 91 
*                1) ES BIT 1 = 1 MCS NOT INITIATED
*                2) ES BIT 3 = 1 MCS NOT DEFINED
          SA1    MCSPB       X1 = FIRST WORD MCSPB
          MX0    48 
          BX1    -X0*X1      X1 = ES C
          SB2    X1 
          EQ     B2,B1,C.MCS5 JUMP IF ES = 0 AND C = 1
          SX6    1R0         ASSUME STATUS KEY 90 
          LX1    -1 
          PL     X1,L90      JUMP IF COMPLETE BIT NOT SET 
          LX1    -1 
          NG     X1,L91      JUMP IF MCS NOT INITIATED (ES BIT 1) 
          LX1    -1 
          NG     X1,L90      JUMP IF MCS BUSY (ES BIT 2)
          LX1    -1 
          PL     X1,L90      JUMP FOR SYSTEM ERROR
 L91      SX6    1R1         FALL THRU FOR MCS DOES NOT EXIST 
 L90      LX6    54 
          SA1    CDADDR 
          SA1    X1+8        X1 = CD WORD 8 
          MX0    6
          BX1    -X0*X1      CLEAR STATUS KEY CHARACTER 
          BX6    X6+X1       INSERT NEW STATUS KEY CHARACTER
          SA6    A1          REPLACE CD WORD 8
          SA1    A1-B1       X1 = CD WORD 7 
          MX0    54 
          BX1    X0*X1       CLEAR STATUS KEY CHARACTER 
          SX6    1R9
          BX6    X1+X6       INSERT NEW STATUS KEY CHARACTER
          SA6    A1          REPLACE CD WORD 7
          EQ     C.MCS5 
          END 
