*DECK C$MCS4
          IDENT  C$MCS4 
          TITLE  C$MCS4 - OUTPUT CD POST MORTEM 
          MACHINE ANY,I 
          COMMENT OUTPUT CD POST MORTEM 
          SST 
          B1=1
          SPACE  5
* 
**        C.MCS4 - OUTPUT CD POST MORTEM
* 
*         INPUT 
*                NONE 
* 
*         OUTPUT
*                NONE 
* 
*         DOES
*                EXAMINES ERROR AND STATUS BITS 
*                UPDATES STATUS KEY IF NECESSARY
* 
*         USES
*                A  - - 2 - - - 6 - 
*                X  0 1 2 - - - 6 - 
*                B  - 1 2 - - - - - 
          EJECT 
          USE    /C.MCSPB/
 MCSPB    BSS    64 
 CDADDR   BSS    1
          USE    *
          ENTRY  C.MCS4 
 C.MCS4   DATA   0
*                POST MORTEM ANALYSIS 
*                THE FOLLOWING CONDITIONS CAUSE STATUS KEY 90 
*                1) C = 0 COMPLETE BIT NOT SET (NEVER)
*                2) ES BIT 2 = 1 MCS BUSY (NEVER) 
*                3) ES BITS 6-11 NE 0 SYSTEM ERROR (NEVER)
*                THE FOLLOWING CONDITIONS CAUSE STATUS KEY 91 
*                1) ES BIT 1 = 1 MCS NOT INITIATED
*                2) ES BIT 3 = 1 MCS NOT DEFINED
          SA2    MCSPB       X2 = FIRST WORD MCSPB
          MX0    48 
          BX2    -X0*X2      X2 = ES C
          SB2    X2 
          EQ     B2,B1,C.MCS4 JUMP IF ES = 0 AND C = 1
          SX6    2R90        ASSUME STATUS KEY 90 
          LX2    -1 
          PL     X2,L90      JUMP IF COMPLETE BIT NOT SET 
          LX2    -1 
          NG     X2,L91      JUMP IF MCS NOT INITIATED (ES BIT 1) 
          LX2    -1 
          NG     X2,L90      JUMP IF MCS BUSY (ES BIT 2)
          LX2    -1 
          PL     X2,L90      JUMP FOR SYSTEM ERROR
 L91      SX6    2R91        FALL THRU FOR MCS DOES NOT EXIST 
 L90      SA1    CDADDR 
          SA2    X1          X2 = WORD CONTAINING STATUS KEY
          BX1    X0*X2       CLEAR STATUS KEY 
          BX6    X1+X6       INSERT NEW STATUS KEY
          SA6    A2          REPLACE WORD CONTAINING STATUS KEY 
          EQ     C.MCS4 
          END 
