*DECK C$MCS12 
          IDENT  C$MCS12
          TITLE  C$MCS12 - ACCEPT MESSAGE COUNT AND INITIAL INPUT 
          MACHINE ANY,I 
          COMMENT MCS INTERFACE FOR ACCEPT MESSAGE COUNT
          SST 
          B1=1
          SPACE  5
* 
**        C.MCS12 - MCS REQUEST FOR ACCEPT MESSAGE COUNT
*                 - MCS REQUEST FOR INITIAL INPUT 
* 
*         INPUT 
*                A0  CD ADDRESS 
*                X4  1 INITIAL
*                    2 ACCEPT MESSAGE COUNT 
* 
*         OUTPUT
*                NONE 
* 
*         DOES
*                SETS UP MCS REQUEST PARAMETER BLOCK FOR
*                ACCEPT MESSAGE COUNT OR INITIAL INPUT
*                CALLS MCS
*                CHECKS FOR ERROR CONDITIONS AFTER CALLING MCS
* 
*         USES
*                A  0 1 2 - - - 6 7 
*                X  - 1 2 - - - 6 7 
*                B  0 1 2 3 - - - - 
          EJECT 
          EXT    C.MCS3 
          EXT    C.MCS5 
          EXT    DEBUG
          USE    /C.MCSPB/
 MCSPB    BSS    64 
 CDADDR   BSS    1
          USE    *
          ENTRY  C.MCS12
 C.MCS12  DATA   0
          SA1    C.MCS12
          RJ     =XC.MCS3    PROGRAM-ID CBLNO *APPLE UTILITY
          MX6    0
          SA6    MCSPB+2     FLAGS=0,EI=0,FDC=0,FDWA=0,DL=0 
          SX1    9           CDL
          LX4    54 
          BX1    X1+X4
          SX7    A0 
          SA7    CDADDR 
          LX7    18 
          BX6    X1+X7       INSERT CDA 
          SA6    A6-B1       REQ=2,ADVNCE=0,CDA=A0,CDL=9
          SA1    =00000000000015020000B 
          BX6    X1 
          SA6    A6-B1       WC=13,RT=2,ES=0,C=0
*                COPY INPUT CD TO MCSPB+5 
          SB2    B0          INITIALIZE LOOP INDEX
          SX1    MCSPB+5
          SB3    9
 L1       SA2    A0+B2       READ FROM CD 
          BX6    X2 
          SA6    X1+B2       WRITE INTO MCSPB 
          SB2    B2+B1       INCREMENT LOOP INDEX 
          LT     B2,B3,L1    STOP WHEN B2 = 9 
          IFC    EQ,/"OSNAME"/SCOPE / 
          CALLSS OP.MCS1,MCSPB,R
          ELSE
          CALLSS OP.MCS2,MCSPB,R
          ENDIF 
          RJ     =XC.MCS5    INPUT CD POST MORTEM 
          EQ     C.MCS12
          END 
