*DECK C$GETEP 
          IDENT  C$GETEP
 C.GETEP  TITLE  CBGETEP - FETCH USER CONTROL CARD PARAMETERS 
  
          MACHINE  ANY,I
          COMMENT  FETCH USER CONTROL CARD PARAMETERS 
          B1=1
          SST 
  
          ENTRY  C.GETEP
          EXT    C.USERP
          EXT    C.MSG
 C.GETEP    SPACE  5
 C.GETEP  DATA   0
          SB3    X1                ADDRESS OF DATA-NAME.
          MX0    57 
          LX1    39 
          BX2    -X0*X1            CHECK CLASS OF DATA-NAME.
          SX3    X2-3 
          ZR     X3,GETEP1   ALPHANUMERIC 
          SX3    X2-7 
          NZ     X3,ERR      NOT GROUP
 GETEP1   BSS    0
          LX1    45 
          SX2    X1                SIZE OF DATA-NAME. 
          ZR     X2,ERR            JUMP IF SIZE IS ZERO.
          MX0    54                MASK FOR 1 CHARACTER 
          LX1    6
          BX3    -X0*X1 
          SB4    X3                GET BCP OF DATA-NAME AND PUT IN B4 
          SB7    81                SET MAX LENGTH+1 
          SA3    77B               SET HIGHEST ADDRESS
 NEXCHAR  BX4    -X0*X3            MASK OUT CHARACTER 
          NG     X0,SAMEWRD        IF MASK POSITIVE 
          SA3    A3-B1             - DECREASE ADDRESS 
 SAMEWRD  LX0    6                 SHIFT MASK 
          SB7    B7-B1             DECREASE LENGTH
          ZR     B7,DOMOVE         JUMP IF NO CONTROL CARD - MOVE SPACES
          ZR     X4,NEXCHAR        LOOP IF CHARACTER BINARY ZERO
          SB2    X2                SAVE LENGTH OF DATA ITEM 
          SX2    B7-B2             GET LENGTH OF BLANF FILL (NEGATIVE)
          GT     B2,B7,DOMOVE      JUMP IF BLANK FILL NEEDED
          SB7    B2                MOVE LENGTH=DATA-ITEM LENGTH 
          SX2    B0                NO BLANK FILL
 DOMOVE   BSS    0
          SB6    B0                OFFSET OF CONTROL CARD IMAGE, WHICH I
          SB5    70B                IS IN RA+70B THRU RA+77B. 
          RJ     =XC.MOVE          MOVE IMAGE INTO DATA-NAME. 
          EQ     C.GETEP
 ERR      SPACE  5
 ERR      SX1    #GETEP1     ERROR MSG NR 
          SA3    C.GETEP
          MX2    0           NO INSERTIONS
          LX3    30 
          SX3    X3-1        CALLING ADDR 
          SX6    X3          REQUEST ABORT
          RJ     =XC.MSG
          EQ     *+400000B   GO DIE IF WE RETURN
          END 
