*DECK C$EDOUT 
          IDENT  C$EDOUT
          TITLE  C$EDOUT - MCS INTERFACE FOR ENABLE/DISABLE OUTPUT
          MACHINE ANY,I 
          COMMENT MCS INTERFACE FOR ENABLE/DISABLE OUTPUT 
          SST 
          B1=1
          SPACE  5
* 
**        C.EDOUT - MCS REQUEST FOR ENABLE/DISABLE OUTPUT 
* 
*         INPUT 
*                A0  CD ADDRESS 
*                X4  0 DISABLE
*                    1 ENABLE 
*                B4  MAXIMUM CD LENGTH
*                X0  THE PASSWORD 
*                B7  LENGTH PASSWORD
* 
*         OUTPUT
*                NONE 
* 
*         DOES
*                SETS UP MCS REQUEST PARAMETER BLOCK
*                CALLS MCS
*                ERROR ANALYSIS BEFORE AND AFTER CALLING MCS
* 
*         USES
*                A  0 1 - - - - 6 7 
*                X  0 1 2 - 4 - 6 7 
*                B  0 1 2 3 4 5 6 7 
          EJECT 
          EXT    C.MCS1 
          EXT    C.MCS3 
          EXT    C.MCS4 
          EXT    C.MOVN 
          USE    /C.MCSPB/
 MCSPB    BSS    64 
 CDADDR   BSS    1
          USE    *
 PWTEMP   BSS    1
 REQUEST  BSS    1
          ENTRY  C.EDOUT
 C.EDOUT  DATA   0
          BX6    X0          PASSWORD 
          SA6    PWTEMP      SAVE PASSWORD UNTIL AFTER MOVING CD
          BX6    X4 
          SA6    REQUEST     PRESERVE REQUEST CODE
          SA1    C.EDOUT     X1 = INPUT FOR C.MCS3
          RJ     =XC.MCS3    PROGRAM-ID CBLNO *APPLE UTILITY
          SX6    B7 
          SA6    MCSPB+2     FLAGS=0,EI=0,FDC=0,FDWA=0,DL=B7
          SX4    58          FREE = 58 (SAVE WORD FOR PASSWORD) 
          RJ     =XC.MCS1    CALCULATE CDL IN X2 AND CDLP IN B2 
          SA4    REQUEST     RESTORE REQUEST CODE 
          SX6    X4+3        REQ = 3 OR 4 
          LX6    54          X6 = REQ 
          SX7    A0 
          SA7    CDADDR      SAVE CD ADDRESS FOR POST MORTEM
          LX7    18 
          BX6    X6+X7       X6 = REQ 0 CDA 
          BX6    X6+X2       X6 = REQ 0 CDA CDL 
          SA6    MCSPB+1     STORE MCSPB WORD 1 
          SX6    B2+5        WC = CDLP + 4 + 1
          LX6    18 
          MX1    1
          LX1    14 
          BX6    X6+X1       X6 = 0 WC 0 RT 0 ES C
          SA6    A6-B1       STORE MCSPB WORD 0 
          SA1    PWTEMP      RETRIEVE PASSWORD
          BX6    X1 
          SA6    B2+MCSPB+5 
          IFC    EQ,/"OSNAME"/SCOPE / 
          CALLSS OP.MCS1,MCSPB,R
          ELSE
          CALLSS OP.MCS2,MCSPB,R
          ENDIF 
          RJ     =XC.MCS4    OUTPUT CD POST MORTEM
          EQ     C.EDOUT
          END 
