*DECK C$EDITZ 
          IDENT  C$EDITZ
          TITLE  C.EDITZ -  MOVE AN ITEM TO PIC ZZZ 
  
          MACHINE  ANY,I
          COMMENT  MOVE AN ITEM TO PIC ZZZ
          SPACE  4
**        C.EDITZ -  MOVE AN ITEM TO PIC ZZZ
* 
*         X0 = NEGATIVE MASK INDICATING RELEVANT DIGITS 
*                (CREATED WITH  MX0 N;  N\12) 
*         X1 = SOURCE DIGITS,  RIGHT-JUSTIFIED,  GARBAGE-FILLED 
*         B7 = RETURN ADDRESS 
* 
*         EQ     C.EDITZ
* 
*         SETS X6 = RESULT WORD,  RIGHT-JUSTIFIED,  BLANK-FILLED
* 
*         USES-  X  0 1 2 - - - 6 - 
*                A  - 1 2 - - - - - 
*                B    - - - - - 6 - 
* 
*         CODING PRIORITIES-
*                1)  BE FAST. 
*                2)  USE FEW X-REGISTERS. 
*                3)  BE SMALL IN SIZE.
  
  
          ENTRY  C.EDITZ
 C.EDITZ  SA2    =X_C.ZEROS  10H0000000000
          IX6    X1-X2       EACH CHARACTER = BINARY ZERO IFF DIGIT = 0 
          BX6    -X0*X6      STRIP GARBAGE
          PX0    X6 
          NX6    X0,B6       NUMBER OF LEADING ZERO BITS
          SA2    =X_C.STRP+B6 
          UX0    X2,B6       NUMBER OF LEADING ZERO CHARACTERS
          SA2    =X_C.MASK+B6  <B6>77-S, <10-B6>00-S
          BX6    -X2*X1      SOURCE DIGITS
          SA1    =X_C.BLANK  10H
          BX2    X2*X1       LEADING BLANKS 
          IX6    X6+X2       FINAL RESULT 
          JP     B7          EXIT 
          SPACE  4
          END 
