*DECK C$DTOR
          IDENT  C$DTOR 
          TITLE  CBDTOR - DOUBLE ** REAL
  
          MACHINE  ANY,I
          COMMENT  DOUBLE ** REAL 
 CBDTOR   SPACE  4
**        C.DTOR - DOUBLE ** REAL 
* 
*         INPUT 
*                X1   BASE (LOWER HALF) 
*                X2   BASE (UPPER HALF) 
*                X3   EXPONENT
* 
*         OUTPUT
*                X5    RESULT (UPPER HALF)
*                X0    RESULT (LOWER HALF)
*                B3   ERROR FLAG
* 
*         SAVES 
*                B1 
* 
*         CALLS-
*                FORTRAN OBJECT LIBRARY ROUTINE *DTOX.* 
  
          ENTRY  C.DTOR 
 C.DTOR   DATA   0
          SB3    B0          ZERO ERROR FLAG
          ZR     X1,C.DTOR2 
          ZR     X3,C.DTOR1 
          NG     X1,C.DTOR3 
          RJ     =XDTOX.
          BX5    X6 
          BX0    X7 
          SB3    B0 
          SB1    1
          EQ     C.DTOR 
  
 C.DTOR1  SA5    =XC.FP1     X**0 = 1 
          MX0    0
          EQ     C.DTOR 
  
 C.DTOR2  NG     X3,C.DTOR3  0**(-X) UNDEFINED
          ZR     X3,C.DTOR3  0**0    UNDEFINED
          MX5    0           0**X = 0 
          MX0    0
          EQ     C.DTOR 
  
 C.DTOR3  SB3    B1 
          TITLE  DTOX. - FORTRAN 5 DOUBLE ** REAL 
**        DTOX. - FORTRAN 5 DOUBLE ** REAL
* 
*         DTOX. WILL RAISE A DOUBLE BASE TO A REAL POWER.  NO ARGUMENT
*         VALIDATION IS PERFORMED.
*         D = D1**X 
* 
*         ENTRY  (X1) - UPPER PART OF D1
*                (X2) - LOWER PART OF D1
*                (X3) - VALUE OF X
*         EXIT   (X6) - UPPER PART OF D1**X 
*                (X7) - LOWER PART OF D1**X 
*         CALLS  C$DLOG, C$DEXP 
  
  
*         COPYRIGHT CONTROL DATA CORP 1978,1979,1980,1981,1982
* 
*         CONTROL DATA PROPRIETARY PRODUCT
  
 DTOX.    DATA   0           ENTRY/EXIT WORD
          BX6    X3 
          SA6    EXPON       SAVE THE EXPONENT
          RJ     =XC$DLOG 
  
          SA1    EXPON
          FX4    X7*X1
          DX5    X6*X1
          FX7    X6*X1
          FX5    X4+X5
          FX1    X5+X7
          DX2    X5+X7
          RJ     =XC$DEXP 
          EQ     DTOX.
  
 EXPON    DATA   0
          EQ     C.DTOR 
          END 
