*DECK  C$DSTOR
          IDENT  C$DSTOR
          COMMENT TWO REGISTER STORE JUST RIGHT 
          TITLE  C$DSTOR - SUBSCRIPTED STORE TWO REGISTERS
 C$DSTOR  SPACE  4
**        C$DSTOR - SUBSCRIPTED STORE TWO REGISTERS 
* 
*         INPUT 
*                X1 - FIRST WORD TO STORE 
*                X2 - SECOND WORD TO STORE, RIGHT JUSTIFIED 
*                B3 - DESTINATION ADDRESS 
*                X3 - DESTINATION OFFSET
*                B4 - DESTINATION LENGTH
* 
*         DOES -  STORES CONTENTS OF X1, X2  IN SPECIFIED DESTINATION 
* 
*         USES   A  - - - - 4 5 6 - 
*                X  - 1 2 3 4 5 6 - 
*                B  0 1 2 3 4 5 6 7 
* 
* 
          ENTRY  C.DSTOR
 C.DSTOR  DATA   0
          SX4    314632B
          IX5    X4*X3
          AX5    20 
          SB3    X5+B3       ADJUSTED ADDRESS 
          IX4    X5+X5
          LX5    3
          IX4    X4+X5
          IX3    X3-X4       OFFSET MOD 10
          SB2    20 
          SB5    B2-B4       SOURCE BCP 
          SB7    X3          DESTINATION BCP
          NE     B7,B5,STOR2 UNEQUAL BCP
          NZ     B7,STOR1 
          BX6    X1 
          SA6    B3 
          BX6    X2 
          SA6    A6+B1
          EQ     C.DSTOR
          SPACE  3
 STOR1    BSS    0           EQUAL BCP, NONZERO 
          SA4    =XC.MASK+B5
          BX3    -X4*X1 
          SA5    B3 
          BX6    X4*X5
          BX6    X3+X6
          SA6    A5 
          BX6    X2 
          SA6    A6+B1
          EQ     C.DSTOR
          SPACE  3
 STOR2    BSS    0           UNEQUAL BCP
          GE     B7,B5,STOR5 RIGHT SHIFT
          SB6    B5-B7
          SB2    10 
          SB2    B2-B6
          SA4    =XC.MASK+B2
          SX3    B6+B6
          SB6    B6+X3
          SB6    B6+B6
          LX1    B6,X1       ALIGN BCPS 
          LX2    B6,X2
          BX6    X1*X4
          BX5    -X4*X2 
          BX6    X5+X6
          NZ     B7,STOR3 
          SA6    B3 
          EQ     STOR4
 STOR3    BSS    0
          SA4    =XC.MASK+B7
          SA5    B3 
          BX3    X4*X5
          BX5    -X4*X6 
          BX6    X3+X5
          SA6    A5 
 STOR4    BSS    0
          SB2    10 
          SB7    B2-B7
          SB4    B4-B7       CHARACTERS IN SECOND WORD
          SA4    =XC.MASK+B4
          SA5    B3+B1
          BX6    X4*X2
          BX4    -X4*X5 
          BX6    X4+X6
          SA6    A5 
          EQ     C.DSTOR
          SPACE  3
 STOR5    BSS    0           UNEQUAL BCP, SHIFT RIGHT 
          SB6    B7-B5
          SB2    10 
          SB6    B2-B6
          SX4    B6+B6
          SB2    B6+X4
          SB2    B2+B2
          LX1    B2,X1       ALIGN SOURCE 
          LX2    B2,X2
          SA4    =XC.MASK+B7
          SA5    B3 
          BX6    X4*X5
          BX5    -X4*X1 
          BX6    X5+X6
          SA6    A5 
          SB6    B7-B5
          SA4    =XC.MASK+B6
          BX1    X4*X1
          BX6    -X4*X2 
          BX6    X1+X6
          SA6    A6+B1
          SA5    A6+B1
          BX6    X4*X2
          BX5    -X4*X5 
          BX6    X5+X6
          SA6    A6+B1
          EQ     C.DSTOR
          END 
