*DECK C$DMRSR 
          IDENT  C$DMRSR
          SST 
          TITLE  C$DMRSR - ISSUE CDCS2 START RELATION CALL
          COMMENT  ISSUE CDCS2 START RELATION CALL
          B1=1
*         C$DMRSR - ISSUE CDCS2 START RELATION CALL 
*         CALLING SEQ 
*         SA0    RELATION ORDINAL 
*         SX3    KEY LENGTH 
*         SB3    KEY NUMBER 
*         SB4    RELATION (START RELATION - NOT CDCS ONE) 
*         MX4    1 IF INV KEY, 0 IF NOT 
*         SX7    KEY ORDINAL
*         SB6    RETURN 
*         EQ     C.DMRSR
*CALL IOMICROS
  
          ENTRY  C.DMRSR
 C.DMRSR  BSS    0
 CDCS1    IFEQ   OP.DCS,OP.DCS2 
          SX6    A0          RELATION ORDINAL 
          SA6    =XF.R.ORD   SAVE RELATION ORDINAL
          SA6    =XC.DMPAR+1 TO PARAM LIST
          SA7    A6+B1       KEY ORDINAL TO PARAM LIST
          SX1    X3          SAVE KEY LENGTH OFER DMRAG CALL
          RJ     =XC.DMRAG   GET LIST OF FILES IN RELATION
          SX3    X1          RESTORE KEY LENGTH 
          SX6    A2+B1
          SA2    A2+B1
          SA6    =XC.BUFF    LOCN OF LIST TO PARAMS 
          SA0    X2          A0 NOW HAS ADDR OF FIT OF PRIMARY FILE 
          RJ     =XC.SVRTN   SAVE A0 ET AL
          FETCH  A0,RECA,X2  ADDR OF RECORD AREA
          STORE  A0,WSA=X2
          STORE  A0,EX==XC.ISEX  SET ERROR EXIT - IS ONE IS OK
          STORE  A0,MKL=X1   SAVE KEY LENGTH
          STORE  A0,REL=B4   SAVE START RELATION
          RJ     =XC.SETKY   SET KEY FIELDS 
          FETCH  A0,KL,X5 
          IX5    X5-X3       REG KEY LEN VS ONE SPECIFIED 
          NZ     X5,MKOK     JP IF IT IS A MAJOR KEY ACCESS 
          STORE  A0,MKL=X5   CLEAR MAJ KEY
 MKOK     BSS    0
          SX6    =XC.DMPAR+1
          SA6    =XC.BUFF+1  SET UP REGULAR PARAMETER LIST
          SX7    X6+B1
          SA7    A6+B1
          MX6    0
          SA6    A7+B1       TERMINATE LIST 
          SA1    =XC.BUFF 
          RJ     =XDB$RSR    GO DO START RELATION 
          RJ     =XC.A0B1    RESTORE A0 AND B1
          EQ     =XC.NORRT   RETURN 
 CDCS1    ENDIF 
          END 
