*DECK C$DMRD2 
          IDENT  C$DMRD2
          SST 
          COMMENT  ISSUE CDCS RANDOM -READ- CALL
          B1=1
          ENTRY  C.DMRD2
*                ISSUE THE CDCS RANDOM -READ- CALL
*                ON ENTRY A0=FIT ADDRESS
*                         (=XC.KRORD)=RECORD ORDINAL/KEY ORDINAL
 C.DMRD2  BSS    1
 CDCS     IFNE   OP.DCS,OP.NO 
          SX7    A0          FIT ADDRESS
          SA7    =XC.DMPAR
          RJ     =XC.DMDFO   GET FILE ORDINAL 
 CDCS2    IFEQ   OP.DCS,OP.DCS2 
          SA1    X7          FETCH FILE ORDINAL INTO X1 
 CDCS2    ENDIF 
          SA7    A7+B1       ADDRESS OF FILE ORDINAL
          SX7    =XC.KRORD   CELL IS SET IN -CBSETKY- 
          SA7    A7+B1       ADDRESS OF RECORD ORDINAL/KEY ORDINAL
          SX7    B0          NO ADDRESS FOR CDCS
          SA7    A7+B1        TO RETURN -RECORD CODE- 
 CDCS2    IFEQ   OP.DCS,OP.DCS2 
          MX2    1
          BX7    X2+X1       SET TOPMOST BIT TO REQUEST THAT CDCS 
          SA7    A1          RETURN THE RECORD LENGTH 
 CDCS2    ENDIF 
          SA1    =XC.DMPAR   CDCS 
 CDCS2    IFEQ   OP.DCS,OP.DCS1 
          RJ     =XDM$RD2     RANDOM -READ- CALL
 CDCS2    ELSE
          RJ     =XDB$RD2    CDCS2 RANDOM -READ- CALL 
 CDCS2    ENDIF 
          RJ     =XC.A0B1    RESTORE A0 (FIT ADDRESS) AND B1(=1)
          EQ     C.DMRD2
 CDCS     ENDIF 
          END 
