*DECK C$DMPVC 
          IDENT  C$DMPVC
          SST 
          COMMENT  ISSUE CDCS 2 PRIVACY (ACCESS-CONTROL) CALL 
          B1=1
          ENTRY  C.DMPVC
* 
*                ISSUE THE CDCS 2 PRIVACY (ACCESS-CONTROL) CALL 
*                 (SEPARATELY FOR EACH REALM SPECIFIED) 
*                CALLED BY THE EQUIVALENT OF AN -ENTER "C.DMPVC" USING
*                 DATA-NAME (CONTAINING PRIVACY KEY),1,0/1/2,REALM-1,..-
* 
*                ON ENTRY A1=ADDRESS OF PARAMETER LIST
*                PARAMETER LIST 
*                     WORD 1 - ADDRESS OF DATA-NAME CONTAINING PRIVACY
*                              KEY
*                     WORD 2 - ADDRESS OF TYPE OF SS ELEMENTS INVOLVED
*                              IN PRIVACY CALL - CURRENTLY ONLY -REALM- 
*                              IMPLEMENTED, THEREFORE -1- 
*                     WORD 3 - ADDRESS OF PRIVACY CALL OPTIONS, NAMELY, 
*                              0 IF -INPUT-, 1 IF -I-O-, 2 IF BOTH
*                     WORD 4 THRU N - ADDRESS(ES) OF REALM(S) FIT(S)
* 
 C.DMPVC  DATA   0
 CDCS2    IFEQ   OP.DCS,OP.DCS2 
          SX6    X1          ADDRESS OF -DB-PRIVACY-KEY-
          SA6    =XC.DMPAR   INTO -DB$PVC- PARAMETER LIST 
*                CURRENTLY, THE PRIVACY CALL IS ONLY IMPLEMENTED FOR
*                AREAS.  SUBSEQUENT VERSIONS MAY REQUIRE IMPLEMENTATION 
*                FOR RECORDS AND ITEMS, TOO.
          SA1    A1+B1       X1=ADDRESS OF ELEMENT TYPE IN DISPLAY
          SX6    C.PVCET     ADDRESS TO CONTAIN PRIV ELEM TYPE IN BINARY
          MX0    54          CONVERT LITERAL FROM DISPLAY TO BINARY 
          SA2    X1 
          BX2    -X0*X2 
          SX7    X2-33B 
          SA7    X6 
          SA6    A6+B1
          SX6    C.IORD      ADDRESS OF ITEM ORDINAL - DOES NOT PERTAIN 
          SA6    A6+2         CURRENTLY 
          SA1    A1+B1
          SA2    X1          X2=PRIVACY OPTIONS 
          SX6    C.PVCOPT    ADDRESS TO CONTAIN REFORMATTED PRIVACY OPTS
          BX2    -X0*X2 
          SB7    X2-33B      CONVERT LITERAL FROM DISPLAY TO BINARY 
          SX7    20B         I-O
          EQ     B7,B1,C.DMPVC1  JUMP IF I-O
          SX7    60B         I-O INPUT
          NE     B7,B0,C.DMPVC1  JUMP IF BOTH -INPUT- AND -I-O- 
          SX7    40B         INPUT
 C.DMPVC1 SA7    X6          REFORMATTED TO CDCS 2 SPECS
          SA6    A6+B1
          SA1    A1+B1
 C.DMPVC2 SA0    X1          REALM FIT ADDRESS
          RJ     =XC.DMDFO   REALM ORDINAL TO -F.R.ORD-, AND X7=F.R.ORD 
          SA7    =XC.DMPAR+2
          SX6    A1 
          SA6    =XC.BUFF    SAVE A1 ACROSS PRIVACY CALL (TO CDCS2) 
          SA1    =XC.DMPAR
          RJ     =XDB$PVC    CDCS2 PRIVACY CALL 
          SB1    1
          SA1    =XC.BUFF 
          SA1    X1+B1       (POSSIBLE) FIT ADDRESS OF NEXT RELAM TO X1 
          NZ     X1,C.DMPVC2  JUMP IF ANOTHER REALM 
          EQ     C.DMPVC
          EJECT 
 C.IORD   DATA   0           CONTAINS ITEM ORDINAL IF PRIVACY ELEMENT IS
*                             -RECORD-
 C.PVCET  BSS    1           CONTAINS PRIVACY ELEMENT TYPE (0-ALL 
*                             ELEMENTS, 1-AREA, 2-RECORD, 3-ITEM) 
 C.PVCOPT BSS    1           CONTAINS PRIVACY OPTION
 CDCS2    ENDIF 
          END 
