*DECK C$DMOPN 
          IDENT  C$DMOPN
          SST 
          COMMENT  ISSUE CDCS -OPEN- CALL 
          B1=1
          ENTRY  C.DMOPN
 CDCS2    IFEQ   OP.DCS,OP.DCS1 
          ENTRY  C.DMOP2
 CDCS2    ENDIF 
*                ISSUE THE CDCS -OPEN- CALL 
*                ON ENTRY A0=FIT ADDRESS
*CALL,IOMICROS
 C.DMOPN  BSS    1
 CDCS     IFNE   OP.DCS,OP.NO 
          SA2    =XC.BINRY   GET THE BINARY LEVEL 
          SX2    X2-5 
          PL     X2,L5BINS   JUMP IF AT LEAST BINARY LEVEL 5
          FETCH  A0,L4DBRO,X2  MOVE DBRO AND DBKO FROM THEIR PRE- 
          STORE  A0,DBRO=X2    BINARY LEVEL 5 LOCATIONS TO THEIR
          FETCH  A0,L4DBKO,X2  BINARY LEVEL 5 LOCATIONS 
          STORE  A0,DBKO=X2 
 L5BINS   BSS    0
          FETCH  A0,RECA,X2 
          STORE  A0,WSA=X2   REQUIRED BY CDCS 
          SX7    A0          FIT ADDRESS
          SA7    =XC.DMPAR
          RJ     =XC.DMDFO   GET FILE ORDINAL 
          SA7    A7+B1       ADDRESS OF FILE ORDINAL
          SA1    A7-B1
 CDCS2    IFEQ   OP.DCS,OP.DCS1 
          FETCH  A0,ON,X5 
          PL     X5,DM.OPN1  JUMP IF NOT -NEW- FILE 
          FETCH  A0,MINF,X5 
          PL     X5,DM.OPN1  JUMP IF NOT MIP FILE 
 C.DMOP2  RJ     0           FILLED IN WITH -RJ =XDM$OP2- AT INVOKE TIME
*                             IF AN -OPEN OUTPUT- CALL FOR MIP FILE 
          EQ     DM.OPN2
 DM.OPN1  RJ     =XDM$OPN    CDCS -OPEN- CALL (EXCEPT AS NOTED ABOVE) 
 CDCS2    ELSE
          RJ     =XDB$OPN    CDCS 2 -OPEN- CALL 
 CDCS2    ENDIF 
 DM.OPN2  RJ     =XC.A0B1    RESTORE A0 (FIT ADDRESS) AND B1(=1)
          EQ     C.DMOPN
 CDCS     ENDIF 
          END 
