*DECK C$DLODL 
          IDENT  C$DLODL
          COMMENT TWO REGISTER LOAD JUST LEFT 
          TITLE  C$DLODL - DOUBLE REGISTER LEFT JUSTIFIED LOAD
 C$DLODL  SPACE  4
*         C$DLODL - DOUBLE REGISTER LEFT JUSTIFIED LOAD 
* 
*         INPUT 
*                X3 - OFFSET OF FIELD TO LOAD 
*                B3 - ADDRESS OF FIELD TO LOAD
*                B4 - LENGTH OF FIELD TO LOAD (11 TO 20 CHARACTERS) 
*         OUTPUT
*                X1 - FIRST WORD OF LOADED ITEM, JUSTIFIED LEFT 
*                X2 - SECOND WORD OF LOADED ITEM (BLANK FILLED) 
* 
*         USES - A - - 1 2 3 4 - - -
*                X - - 1 2 3 4 5 - -
*                B - 0 1 2 3 4 5 - -
* 
          ENTRY  C.DLODL
 C.DLODL  DATA   0
          SB2    10 
          LE     B4,B2,DLODL3      POSSIBLE IF REFERENCE MODIFICATION 
          SX1    314632B
          IX2    X1*X3
          AX2    20 
          SB3    X2+B3       ADJUSTED ADDRESS 
          IX1    X2+X2
          LX2    3
          IX1    X1+X2
          IX3    X3-X1       OFFSET MOD 10
          NZ     X3,DLODL1   NOT LEFT JUSTIFIED 
          SA1    B3 
          SA2    =XC.MASK+B4-10 
          SA3   A1+B1 
          BX2    X2*X3
         SA3    =XC.BFILL+B4-10 
          BX2    X2+X3
          EQ     C.DLODL
          SPACE  3
 DLODL1   BSS    0           BCP NOT ZERO 
          SB2    X3+B4       ECP
          SB5    20 
          GT     B2,B5,DLODL2          ITEM SPANS THREE WORDS 
          SB5    X3 
          SX4    B5+B5
          SB5    X4+B5
          SB5    B5+B5       6*BCP
          SA1    B3 
          SA2    A1+B1
          LX1    B5,X1       LEFT JUSTIFY 
          LX2    B5,X2
          SX4    10 
          IX3    X4-X3       10-BCP 
          SA4    =XC.MASK+X3
          BX1    X1*X4
          BX4    -X4*X2 
          BX1    X1+X4
          SA4    =XC.MASK+B4-10 
          BX2    X2*X4       ZERO FILL
          SA4    =XC.BFILL+B4-10
          BX2    X2+X4
          EQ     C.DLODL
          SPACE  3
 DLODL2   BSS    0           ITEM SPANS THREE WORDS 
          SA1    B3 
          SB2    X3 
          SB2    B2+B2
          SB2    X3+B2
          SB2    B2+B2       6*BCP
          SA2    A1+B1
          LX1    B2,X1
          LX2    B2,X2       LEFT JUSTIFY 
          SX4    10 
          IX3    X4-X3       10-BCP 
          SA4    =XC.MASK+X3
          BX1    X1*X4
          BX5    -X4*X2 
          BX1    X1+X5
          SA3    A2+B1
          LX3    B2,X3
          BX2    X2*X4
          BX3    -X4*X3 
          BX2    X2+X3
          SA4    =XC.MASK+B4-10 
          BX2    X4*X2       ZERO FILL
          SA4    =XC.BFILL+B4-10
          BX2    X2+X4
          EQ     C.DLODL
          SPACE  3
 DLODL3   RJ     =XC.SLODL
          SA2    =XC.SPACE
          EQ     C.DLODL
          END 
