*DECK C$CAMOP 
          IDENT  C$CAMOP
          TITLE  C$CAMOP - COMMON AAM OPEN PROCESSING 
          COMMENT  COMMON AAM OPEN PROCESSING 
          SST 
**        C$CAMOP - COMMON AAM OPEN PROCESSING
* 
          ENTRY  C.CAMOP
 C.CAMOP  BSS    0
          SX6    B5          ADDR OF OPEN ROUTINE 
          MX7    1
          LX7    27          FORM AN EQ INSTRUCTION 
          BX7    X7+X6
          LX7    30 
          SA7    OPNJMP      SET AS JUMP TO OPN 
          SB2    =XC.OPOUT
          SX2    #OLD#
          NE     B2,B5,SFEQ  JP IF NOT AN OPEN OUTPUT 
          SX2    #NEW#
 SFEQ     BSS    0
          STORE  A0,ON=X2    ORG=OLD FILES NEED ON SET FOR SETFIT 
          RJ     =XC.SFEQ    SET FILE EQUIVALENCE 
          SB3    B0 
          RJ     =XC.SETKY   SET PRIME KEY TO KEY OF REF AND KEY FIELDS 
          RJ     =XC.IOSET   SET COLLATING SEQUENCE TABLE 
          SB3    #R#         SET FOR REWIND - ALWAYS REWIND AMM FILES 
          RJ     =XC.GETRT   RESET A0 AND B6 (C.SFEQ SAVED THEM)
          SX6    RTN
          SA6    =XC.AMFLG   SET RETURN FROM OPEN 
 OPNJMP   DATA   0           JUMP TO PROPER OPEN ROUTINE HERE 
 RTN      BSS    0           RETURNS HERE FROM OPEN 
          SB3    B0 
          RJ     =XC.SETKY   SET PRIME KEY AGAIN (SETFIT MAY CHANGE IT) 
          EQ     =XC.OPRTN   GO BACK AND FINISH AND TAKE NORMAL RTN 
          END 
