*DECK C$BT2DS 
          IDENT  C$BT2DS
          TITLE  C$BT2DS - MOVE BOOLEAN BIT ITEM TO DISPLAY 
**        C.BT2BD - MOVE BOOLEAN BIT TO BOOLEAN DISPLAY 
* 
*         INPUT 
*                B3 - ADDRESS DESTINATION 
*                B4 - OFFSET DESTINATION
*                B5 - ADDRESS SOURCE
*                B6 - OFFSET SOURCE 
*                X0 - JUSTIFIED FLAG
*                X1 - BIT LENGTH SOURCE 
*                X2 - BYTE LENGTH DESTINATION 
          ENTRY  C.BT2BD
 C.BT2BD  DATA   0
          SA3    =XC.ZEROS
          BX6    X3 
          SA6    FILLCH 
          RJ     BT2DS
          EQ     C.BT2BD
 C$BT2AN  EJECT 
**        C.BT2AN - MOVE BOOLEAN BIT TO ALPHANUMERIC
* 
*         INPUT 
*                B3 - ADDRESS DESTINATION 
*                B4 - OFFSET DESTINATION
*                B5 - ADDRESS SOURCE
*                B6 - OFFSET SOURCE 
*                X0 - JUSTIFIED FLAG
*                X1 - BIT LENGTH SOURCE 
*                X2 - BYTE LENGTH DESTINATION 
          ENTRY  C.BT2AN
 C.BT2AN  DATA   0
          SA3    =XC.BLANK
          BX6    X3 
          SA6    FILLCH 
          RJ     BT2DS
          EQ     C.BT2AN
 BT2DS    EJECT 
**        BT2DS - MOVE BOOLEAN BIT ITEM TO DISPLAY
* 
*         INPUT 
*                SAME AS C.BT2BD, C.BT2AN 
*                FILLCH - FILL CHARACTER
* 
 BT2DS    DATA   0
          SX4    314632B
          SX3    B6 
          IX4    X4*X3
          AX4    20 
          SB5    B5+X4       NEW SOURCE ADDRESS 
          IX5    X4+X4
          LX4    3
          IX5    X4+X5
          IX6    X3-X5       SOURCE BCP 
          SX5    6
          IX6    X6*X5       SOURCE ECP 
          SA6    SRCOFFS
          SX7    B5 
          SA7    SRCADDR
          SX4    314632B
          SX3    B4 
          IX4    X4*X3
          AX4    20 
          SB3    B3+X4       NEW DESTINATION ADDRESS
          IX5    X4+X4
          LX4    3
          IX5    X5+X4
          IX6    X3-X5       BCP DESTINATION
          SA6    DSTOFFS
          SX7    B3 
          SA7    DSTADDR
          IX3    X2-X1
          BX7    X1 
          PL     X3,BT2DS1   DESTINATION LONGER 
          MX3    0
          BX7   X2
 BT2DS1   SA7    MOVECNT
          BX6    X3 
          SA6    FILLCNT
          IX3    X2-X1
          ZR     X3,BT2DS6   EQUAL LENGTHS
          ZR     X0,BT2DS4   NOT JUSTIFIED RIGHT
          PL     X3,BT2DS2   LEFT FILL
          SA1    SRCOFFS
          IX1    X1-X3       INCREMENT SOURCE OFFSET
          RJ     MOD60       CONVERT TO BBP 
          SA6    SRCOFFS
          SA2    SRCADDR
          IX6    X2+X0
          SA6    A2 
          EQ     BT2DS6 
          SPACE  3
*      RIGHT JUSTIFIED - LEFT FILL
 BT2DS2   SA1    DSTOFFS
          SA2    DSTADDR
          SB3    X2 
          SA3    FILLCNT
          SB4    X3 
 BT2DS3   SA2    FILLCH 
          BX6    X2 
          RJ     PUT10CH
          NZ     B4,BT2DS3
          SA1    DSTOFFS
          SA2    FILLCNT
          IX1    X1+X2
          SX4    314632B
          IX4    X4*X1
          AX4    20 
          SA3    DSTADDR
          IX6    X3+X4       NEW ADDRESS
          SA6    A3 
          IX5    X4+X4
          LX4    3
          IX5    X4+X5
          IX6    X1-X5       NEW BCP
          SA6    DSTOFFS
          EQ     BT2DS6 
*      LEFT JUSTIFIED - RIGHT FILL
 BT2DS4   SA2    FILLCNT
          ZR     X2,BT2DS6
          SA1    DSTOFFS
          SA2    MOVECNT
          IX1    X1+X2
          SX4    314632B
          IX4    X4*X1
          AX4    20 
          SA3    DSTADDR
          IX6    X4+X3
          SB3    X6 
          IX5    X4+X4
          LX4    3
          IX5    X4+X5
          IX1    X1-X5
          SA3    FILLCNT
          SB4    X3 
 BT2DS5   SA4    FILLCH 
          BX6    X4 
          RJ     PUT10CH
          NZ     B4,BT2DS5
          EQ     BT2DS6 
*      MOVE SOURCE TO DESTINATION 
 BT2DS6   SA1    SRCADDR
          SB3    X1 
          SA2    MOVECNT
          SB4    X2 
          SA1    SRCOFFS
          RJ     GETWORD
          SX7    B3 
          SA7    SRCADDR
          SA1    DSTOFFS
          SA2    DSTADDR
          SB3    X2 
          SA2    MOVECNT
          SB4    X2 
          RJ     PUT60
          ZR     B4,BT2DS 
          SX6    B3 
          SA6    DSTADDR
          SX7    B4 
          SA7    MOVECNT
          EQ     BT2DS6 
          SPACE  3
 DSTADDR  BSS    1
 DSTOFFS  BSS    1
 MOVECNT  BSS    1
 FILLCH   BSS    1
 FILLCNT  BSS    1
 SRCADDR  BSS    1
 SRCOFFS  BSS    1
*CALL CBPUT10C
*CALL CBMOD60 
*CALL CBPUT60 
*CALL CBGETWRD
          END 
