*DECK C$AOPTN 
          IDENT  C$AOPTN
          TITLE  C.AOPTN -  CONVERT BLANKS TO NUMERIC ZEROS 
  
          MACHINE  ANY,I
          COMMENT  CONVERT BLANKS TO NUMERIC ZEROS
          SPACE  4
**        C.AOPTN -  CONVERT BLANKS TO NUMERIC ZEROS
* 
*         X1 = 10 CHARACTERS
*         RJ     C.AOPTN
* 
*         CONVERTS BLANKS (55B) TO NUMERIC ZEROS (33B)
*           AND LEAVES THE RESULT IN X1.
* 
*         CODING PRIORITIES-
*                1)  USE FEW X-REGISTERS. 
*                2)  BE FAST. 
*                3)  BE SMALL IN SIZE.  (LEAST IMPORTANT
* 
*         USES-  X  0 * - - - - - -    *X1 = INPUT/OUTPUT 
*                A  - - - - - - - - 
*                B    - - - - - 6 7 
  
  
          ENTRY  C.AOPTN
 C.AOPTN  DATA    0 
          SB7    -1R
          SB6    1R0&1R 
1         DUP    10 
+         LX1    6           SHIFT FOR NEXT CHARACTER 
          MX0    -6 
          BX0    -X0*X1      EXTRACT CHARACTER
          SX0    X0+B7 (-1R ) 
+         NZ     X0,*+1      IF NON-BLANK, SKIP 
          SX0    B6 (1R0&1R ) 
          BX1    X1-X0       CONVERT BLANK TO ZERO
1         ENDD
          EQ     C.AOPTN     EXIT 
  
          END 
