*DECK C$ALPC1 
          IDENT  C$ALPC1
          TITLE  C.ALPC1 - IF ALPHABETIC FOR 1 CHAR FIELDS
  
          MACHINE   ANY,I 
  
          COMMENT   IF ALPHABETIC FOR 1 CHAR FLDS 
          SST 
  
 C.ALPC1  SPACE  4
**        C.ALPC1 - IF ALPHABETIC FOR 1 CHARACTER FIELDS
* 
*                SIMPLY CHECKS THE CHAR TO SEE IF IT IS A _ Z OR SPACE
* 
*         CALLING SEQ:  
*         SB5    BASE ADDRESS 
*         SB6    BYTE OFFSET
*         RJ     =XC.ALPC1
* 
*         RETURNS:  
*         B4 = 0 IF TRUE
*            = 1 IF FALSE 
* 
*         USES: 
*                X  - - - 3 4 - 6 - 
*                A  - - - 3 - - - - 
*                B  - - - - 4 5 6 - 
* 
*         ENTRY POINTS: 
          ENTRY  C.ALPC1
*         EXTERNALS REFERENCED: 
*         NONE
* 
          SPACE  4
 C.ALPC1  DATA   0
          SB7    10 
          SX4    B6+0 
          LT     B6,B7,ABCP  GOT A BCP, NOT AN INDEX
          SX3    52429
          IX6    X3*X4
          AX6    19 
          SB5    B5+X6       INCR ADDR
 IFA      IFEQ   OP.MODEL,OP.6400  UNIFIED CPU OR NO
          LX3    X6,B1       X6*2 
          LX6    3           X6*8 
          IX6    X6+X3       X6*10
 IFA      ELSE
          SX3    10 
          IX6    X3*X6
 IFA      ENDIF 
          IX4    X4-X6       COMPUTE THE BCP
  
 ABCP     SB6    1R0
          SB4    B0          SET TRUE 
          SA3    B5 
 IFB      IFEQ   OP.MODEL,OP.6400 
          LX6    X4,B1
          LX4    2
          IX4    X4+X6       X4*6 
 IFB      ELSE
          SX6    6
          IX4    X4*X6
 IFB      ENDIF 
          MX6    54 
          SB5    X4+6 
          LX3    X3,B5       LEFT JUST CHAR 
          BX4    -X6*X3 
          ZR     X4,NAY      COLON...NO GOOD
          SB5    X4+0 
          LT     B5,B6,C.ALPC1     XIT..HES OK
          SX4    X4-1R       MAYBE HES A BLANK
          ZR     X4,C.ALPC1 
 NAY      SB4    B1          SET -FALSE-
          EQ     C.ALPC1     RETURN 
          END 
