*DECK C$ACCTM 
          IDENT  C$ACCTM
          TITLE  CBACCTM - ACCEPT FROM TIME 
          MACHINE  ANY,I
          COMMENT  ACCEPT FROM TIME 
          SST 
          B1=1
          SPACE  4
**        C.ACCTM - ACCEPT FROM TIME
* 
*         CALLING SEQUENCE- 
*                RJ   C.ACCTM 
* 
*         INPUT-
*                NONE 
* 
*         OUTPUT- 
*                TIME IN FORMAT HHMMSSNN IN X1 RIGHT-JUSTIFIED AND
*                DISPLAY CODE ZERO FILLED   (NN= HUNDREDTHS OF A SEC) 
* 
*         DOES- 
*                GETS TIME USING SYSTEM MACRO CLOCK.  FORMATS HHMMSS
*                AS SPECIFIED ABOVE.  SETS NN=0 SINCE THERE IS NO 
*                MEANINGFUL WAY TO GET HUNDREDTHS OF A SECOND.
* 
*         USES- 
*                A2,X2,X0,B3,X1,X5
*                C.TEMP,C.ZERO
* 
          SPACE  4
          ENTRY  C.ACCTM
 C.ACCTM  DATA   0
          CLOCK  =XC.TEMP    GET TIME FROM SYSTEM 
          SA2    =XC.TEMP    HH.MM.SS.
          MX0    48 
          SB3    B1+B1       LOOP INDEX 
          SX1    B0 
 LOOP     BSS    0
          LX2    18          RIGHT-JUSTIFY HH THEN MM THEN SS 
          BX5    -X0*X2      HH OR MM OR SS 
          LX1    12 
          SB3    B3-B1       DECREMENT LOOP INDEX 
          BX1    X1+X5       INSERT HH OR MM OR SS
          GE     B3,LOOP     IF MORE CHARS TO COLLECT- LOOP 
          LX1    12          MAKE ROOM FOR NN 
          SA2    =XC.ZERO    WORD OF ZEROS
          MX0    36          MASK FOR HHMMSS
          LX0    48 
          BX2    -X0*X2      MAKE HOLE FOR HHMMSS 
          BX1    X1+X2
          EQ     C.ACCTM
          END 
