*COMDECK,MALETPC
          EJECT 
          QUAL   MALETPC
          IFNE   CMSE,0,1 
          USE    MODD 
          VFD    30/1,6/KEY32,6/KEY2,18/0 CW FOR MST PRODUCT OVERLAY
          USE    *
*         LENGTHS AND ADDRESSES OF PPU BUFFERS ARE DEFINED BELOW. THESE 
*         VALUES MUST BE KEPT IN PRODUCT OVERLAY ORDER AND MUST  ALWAYS 
*         AGREE  WITH  THE  ACTUAL  VALUES IN THE PPU PRODUCT OVERLAYS. 
* 
  
          IFNE   CMSE,0,1 
          USE    P0OB 
          DATA   220B        MAX VALUE FOR OB FOR (MST) 
          USE    *
          IFNE   CMSE,0,1 
          USE    P0OBFWA
          DATA   5650B       FWA OF OB FOR OVERLAY (MST)
          USE    *
          IFNE   CMSE,0,1 
          USE    P0IB 
          DATA   216B        MAX VALUE FOR IB FOR (MST) 
          USE    *
          IFNE   CMSE,0,1 
          USE    P0IBFWA
          DATA   5432B       FWA OF IB FOR OVERLAY (MST)
          USE    *
          IFNE   CMSE,0,1 
          USE    P0SB 
          DATA   100B        MAX VALUE FOR SB FOR (MST) 
          USE    *
          IFNE   CMSE,0,1 
          USE    P0SBFWA
          DATA   6070B       FWA OF SB FOR OVERLAY (MST)
          USE    *
          EJECT 
* 
*         MST (MSF/MST) PRODUCT OVERLAY ENTRY POINTS
* 
 RELMST   EQU    POVL 
 RESMST   EQU    RELMST+4 
 CMDZMST  EQU    RESMST+4 
 LOOPMST  EQU    CMDZMST+4
 READMST  EQU    LOOPMST+4
 RSETMST  EQU    READMST+4
 REWMST   EQU    RSETMST+4
 SEEKMST  EQU    REWMST+4 
 SNSMST   EQU    SEEKMST+4
 SKIPMST  EQU    SNSMST+4 
 STATMST  EQU    SKIPMST+4
 WRMST    EQU    STATMST+4
  
          IFNE   CMSE,0,1 
          USE    PKEY 
          VFD    24/0,18/LKEY32,18/TKEY32 
 KEY32    EQU    *-PKEY+PKEYOFF      LEGAL MST (MST) I/O COMMANDS 
          USE    *
* 
*         LEGAL HIGH-LEVEL I/O STATEMENTS FOR MSF TRANSPORT 
* 
 TKEY32   VFD    42/7LADVANCE,18/MSTADV 
          VFD    42/4LBKSP,18/MSTBKSP 
          VFD    42/3LDSE,18/MSTDSE 
          VFD    42/6LEXTEND,18/MSTEXT
          VFD    42/5LFORSP,18/MSTFSP 
          VFD    42/4LLOAD,18/MSTLOAD 
          VFD    42/6LLOOPBK,18/MSTLBK
          VFD    42/4LNOOP,18/MSTNOOP 
          VFD    42/4LREAD,18/MSTREAD 
          VFD    42/3LREL,18/MSTREL 
          VFD    42/3LRES,18/MSTRES 
          VFD    42/5LRESET,18/MSTRSET
          VFD    42/6LREWIND,18/MSTREW
          VFD    42/4LSEEK,18/MSTSEEK 
          VFD    42/5LSENSE,18/MSTSNS 
          VFD    42/3LSET,18/MSTSET 
          VFD    42/4LSKIP,18/MSTSKIP 
          VFD    42/6LSTATUS,18/MSTSTAT 
          VFD    42/6LUNLOAD,18/MSTUNL
          VFD    42/5LWRITE,18/MSTWR
 LKEY32   EQU    *-TKEY32 
  
*         CONSTANTS USED BY MST 
  
 DFWD     VFD    60/3LFWD 
 DREV     VFD    60/3LREV 
 DX       VFD    60/1LX 
 DY       VFD    60/1LY 
          EJECT 
**        COMMON CODE PROCESSING FOR OVERLAY MST
* 
*         CRACK ABT Z 
  
  
 PCC4     SA1    DABT 
          BX1    X3-X1
          NZ     X1,COM30    ERROR EXIT IF NEXT ITEM IS NOT ABT 
          SA3    A3+B1
          SX6    A3 
          SA6    PCRK        BUMP POINTER TO CRKBUF 
          ZR     X3,COM30    ERROR EXIT IF END OF STATEMENT 
          SA1    PCCC 
          RJ     FIND        GET Z
          NG     B2,COM31    ERROR EXIT IF NOT FOUND
          NZ     X3,COM30    ERROR EXIT IF NOT END OF STATEMENT 
          RJ     CPSN        PROCESS STATEMENT NUMBER 
          SA1    PCCD 
          SX2    B7          COMMAND ENTRY ADDRESS
          BX0    X1+X2       CODE = LDC 0  RJM ENTRY
          RJ     CABSPPU           ABSOLUTIZE PPU ADDRESSES 
          RJ     CSTOREB     SAVE GENERATED CODE
          EQ     COM10       EXIT TO COMPILER 
  
 PCCA     VFD    57/0,3/REG1           CONTROL WORD FOR V,W,X AND Y 
 PCCB     DATA   0                     BUFFER FOR ENTRY ADDRESS 
 PCCC     VFD    42/0,12/77B,6/0       CONTROL WORD FOR Z 
 PCCD     VFD    12/0,12/LDC,12/0,12/RJM,12/0 
 PCCE     VFD    60/3LCYL              KEYWORDS IN ORDER EXPECTED 
          VFD    60/3LTRK 
          VFD    60/3LSEC 
          EJECT 
 MSTADV   TITLE  PROCESS HIGH LEVEL MSF/MST COMMANDS. 
**        MSTADV  -  PROCESS  THE MST ADVANCE STATEMENT.
* 
*         J. E. SIPPER. 76/12/08. 
* 
*         MSTADV - PROCESS THE MSF ADVANCE STATEMENT. 
* 
*         ENTRY 
* 
*           CRKBUF = WORD STRING OF SOURCE STATEMENT. 
* 
*         EXIT
* 
*           . MODULE = BINARY PPU CODE GENERATED FOR THE SOURCE.
*           . FCERR COMPILER ERROR FLAG SET IF COMPILER ERROR CREATED.
* 
*         ROUTINES CALLED -  NONE.
* 
*         DATA AREAS USED -  CRKBUF - WORD STRING OF SOURCE STATEMENT.
*                            MODULE - BINARY CODE GENERATED.
* 
*         USES   A - NONE.
*                X - 0. 
*                B - NONE.
* 
 MSTADV   SX0    LDN
          EQ     MSTA        ENTER COMMON SEQUENCE
          EJECT 
 MSTBKSP  TITLE  MSTBKSP -  PROCESS THE MST BKSP STATEMENT. 
**        MSTBKSP -  PROCESS THE MST BKSP STATEMENT.
* 
*         J. E. SIPPER. 76/12/08. 
* 
*         MSTBKSP - PROCESS THE MSF BKSP STATEMENT. 
* 
*         ENTRY 
* 
*           CRKBUF = WORD STRING OF SOURCE STATEMENT. 
* 
*         EXIT
* 
*           . MODULE = BINARY PPU CODE GENERATED FOR THE SOURCE.
*           . FCERR COMPILER ERROR FLAG SET IF COMPILER ERROR CREATED.
* 
*         ROUTINES CALLED -  NONE.
* 
*         DATA AREAS USED -  NONE.
* 
*         USES   A - NONE.
*                X - 0. 
*                B - NONE.
* 
 MSTBKSP  SX0    LDN+1
          EQ     MSTA        ENTER COMMON SEQUENCE
          EJECT 
 MSTDSE   TITLE  MSTDSE -  PROCESS THE MST DATA SECURITY ERASE STATEMENT
**        MSTDSE -  PROCESS THE MST DATA SECURITY ERASE STATEMENT.
* 
*         E. L. HARMON. 78/05/31. 
* 
*         MSTDSE -  PROCESS THE MST DATA SECURITY ERASE STATEMENT.
* 
*         ENTRY 
* 
*           CRKBUF = WORD STRING OF SOURCE STATEMENT. 
* 
*         EXIT
* 
*           . MODULE = BINARY PPU CODE GENERATED FOR THE SOURCE.
*           . FCERR COMPILER ERROR FLAG SET IF COMPILER ERROR CREATED.
* 
*         ROUTINES CALLED -  NONE.
* 
*         DATA AREAS USED -  NONE.
* 
*         USES   A - NONE.
*                X - 0. 
*                B - NONE.
* 
 MSTDSE   SX0    LDN+8
          EQ     MSTA        ENTER COMMON SEQUENCE
          EJECT 
 MSTEXT   TITLE  MSTEXT -   PROCESS THE MST EXTEND IBG STATEMENT. 
**        MSTEXT -   PROCESS THE MST EXTEND IBG STATEMENT.
* 
*         J. E. SIPPER. 76/12/08. 
* 
*         MSTEXT - PROCESS THE MSF EXTEND STATEMENT.
* 
*         ENTRY 
* 
*           CRKBUF = WORD STRING OF SOURCE STATEMENT. 
* 
*         EXIT
* 
*           . MODULE = BINARY PPU CODE GENERATED FOR THE SOURCE.
*           . FCERR COMPILER ERROR FLAG SET IF COMPILER ERROR CREATED.
* 
*         ROUTINES CALLED -  NONE.
* 
*         DATA AREAS USED -  NONE.
* 
*         USES   A - 1, 6.
*                X - 0, 1, 6. 
*                B - NONE.
* 
 MSTEXT   SA1    MSTD1
          SX0    LDN+2
 MSTEX    BX1    X1-X3
          NZ     X1,COM30    IF NEXT ITEM IS NOT (X1) 
          SA3    A3+B1       NEXT ITEM FROM CRKBUF
          SX6    A3 
          SA6    PCRK        BUMP POINTER TO CRKBUF 
          EQ     MSTA        ENTER COMMON SEQUENCE
          EJECT 
 MSTFSP   TITLE  MSTFSP -   PROCESS THE MST FORSP STATEMENT.
**        MSTFSP -   PROCESS THE MST FORSP STATEMENT. 
* 
*         J. E. SIPPER. 76/12/08. 
* 
*         MSTFSP - PROCESS THE MST FORSP STATEMENT. 
* 
*         ENTRY 
* 
*           CRKBUF = WORD STRING OF SOURCE STATEMENT. 
* 
*         EXIT
* 
*           . MODULE = BINARY PPU CODE GENERATED FOR THE SOURCE.
*           . FCERR COMPILER ERROR FLAG SET IF COMPILER ERROR CREATED.
* 
*         ROUTINES CALLED -  NONE.
* 
*         DATA AREAS USED -  NONE.
* 
*         USES   A - NONE.
*                X - 0. 
*                B - NONE.
* 
 MSTFSP   SX0    LDN+3
          EQ     MSTA        ENTER COMMON SEQUENCE
          EJECT 
 MSTLOAD  TITLE  MSTLOAD -  PROCESS THE MST LOAD STATEMENT. 
**        MSTLOAD -  PROCESS THE MST LOAD STATEMENT.
* 
*         J. E. SIPPER. 76/12/08. 
* 
*         MSTLOAD - PROCESS THE MST LOAD STATEMENT. 
* 
*         ENTRY 
* 
*           CRKBUF = WORD STRING OF SOURCE STATEMENT. 
* 
*         EXIT
* 
*           . MODULE = BINARY PPU CODE GENERATED FOR THE SOURCE.
*           . FCERR COMPILER ERROR FLAG SET IF COMPILER ERROR CREATED.
* 
*         ROUTINES CALLED -  NONE.
* 
*         DATA AREAS USED -  NONE.
* 
*         USES   A - NONE.
*                X - 0. 
*                B - NONE.
  
 MSTLOAD  SX0    LDN+4
          EQ     MSTA        ENTER COMMON SEQUENCE
          EJECT 
 MSTLBK   TITLE  MSTLBK  -  PROCESS THE MST LOOPBK STATEMENT
**        MSTLBK  -  PROCESS THE MST LOOPBK STATEMENT 
* 
*         J. E. SIPPER. 76/12/08. 
* 
*         MSTFSP - PROCESS THE MST FORSP STATEMENT. 
* 
*         ENTRY 
* 
*           CRKBUF = WORD STRING OF SOURCE STATEMENT. 
* 
*         EXIT
* 
*           . MODULE = BINARY PPU CODE GENERATED FOR THE SOURCE.
*           . FCERR COMPILER ERROR FLAG SET IF COMPILER ERROR CREATED.
* 
*         ROUTINES CALLED -  FIND   - FIND THE NEXT ITEM FROM SOURCE. 
*                            CSTOREB- STORE GENERATED CODE. 
* 
*         DATA AREAS USED -  CRKBUF - WORD STRING OF SOURCE STATEMENT.
*                            MODULE - BINARY CODE GENERATED.
* 
*         USES   A - 1, 3, 6. 
*                X - 0, 1, 6. 
*                B - 2, 7.
  
 MSTLBK   SB7    LOOPMST     COMMAND ENTRY POINT
          SB2    B0          CLEAR INDEX
          SX0    LDN
          SB3    LMSTLB      LENGTH OF KEYWORDS 
 MSTLB1   SA1    MSTLB+B2    LOOP FOR KEYWORD 
          BX1    X1-X3
          ZR     X1,MSTLB2   ENTER COMMON SEQUENCE IF FOUND 
          SB2    B2+B1
          SX0    X0+B1
          NE     B2,B3,MSTLB1  IF ALL KEYWORDS NOT TESTED 
          EQ     COM30       ERROR EXIT IF KEYWORD NOT FOUND
  
 MSTLB2   SA3    A3+B1
          SX6    A3 
          SA6    PCRK         BUMP POINTER TO CRKBUF
          EQ     MSTB 
  
 MSTLB    VFD    60/3LMSA 
          VFD    60/3LCTL 
          VFD    60/3LDLI 
          VFD    60/7LCOUPLER 
 LMSTLB   EQU    *-MSTLB     LENGTH OF TABLE
          EJECT 
 MSTNOOP  TITLE  MSTNOOP -  PROCESS THE MST NOOP STATEMENT. 
**        MSTNOOP -  PROCESS THE MST NOOP STATEMENT.
* 
*         J. E. SIPPER. 76/12/08. 
* 
*         MSTNOOP - PROCESS THE MST NOOP STATEMENT. 
* 
*         ENTRY 
* 
*           CRKBUF = WORD STRING OF SOURCE STATEMENT. 
* 
*         EXIT
* 
*           . MODULE = BINARY PPU CODE GENERATED FOR THE SOURCE.
*           . FCERR COMPILER ERROR FLAG SET IF COMPILER ERROR CREATED.
* 
*         ROUTINES CALLED -  NONE.
* 
*         DATA AREAS USED -  NONE.
* 
*         USES   A - NONE.
*                X - 0. 
*                B - NONE.
* 
  
 MSTNOOP  SX0    LDN+5
          EQ     MSTA        ENTER COMMON SEQUENCE
          EJECT 
 MSTREAD  TITLE  MSTREAD -  PROCESS THE MST READ STATEMENT. 
**        MSTREAD -  PROCESS THE MST READ STATEMENT.
* 
*         J. E. SIPPER. 76/12/08. 
* 
*         MSTREAD - PROCESS THE MST READ STATEMENT. 
* 
*         ENTRY 
* 
*           CRKBUF = WORD STRING OF SOURCE STATEMENT. 
* 
*         EXIT
* 
*           . MODULE = BINARY PPU CODE GENERATED FOR THE SOURCE.
*           . FCERR COMPILER ERROR FLAG SET IF COMPILER ERROR CREATED.
* 
*         ROUTINES CALLED -  NONE.
* 
*         DATA AREAS USED -  NONE.
* 
*         USES   A - NONE.
*                X - NONE 
*                B - 7. 
* 
  
 MSTREAD  SB7    READMST     COMMAND ENTRY POINT
          EQ     PCC4         ENTER COMMON P4 SEQUENCE
          EJECT 
 MSTREL   TITLE  MSTREL -  PROCESS THE MST REL STATEMENT. 
**        MSTREL -  PROCESS THE MST REL STATEMENT.
* 
*         J. E. SIPPER. 76/12/08. 
* 
*         MSTREL - PROCESS THE MST REL STATEMENT. 
* 
*         ENTRY 
* 
*           CRKBUF = WORD STRING OF SOURCE STATEMENT. 
* 
*         EXIT
* 
*           . MODULE = BINARY PPU CODE GENERATED FOR THE SOURCE.
*           . FCERR COMPILER ERROR FLAG SET IF COMPILER ERROR CREATED.
* 
*         ROUTINES CALLED -  NONE.
* 
*         DATA AREAS USED -  NONE.
* 
*         USES   A - NONE.
*                X - NONE.
*                B - 7
* 
 MSTREL   SB7    RELMST      COMMAND ENTRY POINT
          EQ     PCC4        ENTER COMMON P4 SEQUENCE 
          EJECT 
 MSTRES   TITLE  MSTRES -  PROCESS THE MST RES STATEMENT. 
**        MSTRES -  PROCESS THE MST RES STATEMENT.
* 
*         J. E. SIPPER. 76/12/08. 
* 
*         MSTRES - PROCESS THE MST RES STATEMENT. 
* 
*         ENTRY 
* 
*           CRKBUF = WORD STRING OF SOURCE STATEMENT. 
* 
*         EXIT
* 
*           . MODULE = BINARY PPU CODE GENERATED FOR THE SOURCE.
*           . FCERR COMPILER ERROR FLAG SET IF COMPILER ERROR CREATED.
* 
*         ROUTINES CALLED -  NONE.
* 
*         DATA AREAS USED -  NONE.
* 
*         USES   A - NONE.
*                X - NONE.
*                B - 7. 
* 
 MSTRES   SB7    RESMST      COMMAND ENTRY POINT
          EQ     PCC4        ENTER COMMON P4 SEQUENCE 
          EJECT 
 MSTRSET  TITLE  MSTRSET - PROCESS THE MST *RESET* STATEMENT. 
**        MSTRSET - PROCESS THE MST *RESET* STATEMENT.
* 
*         J. E. SIPPER. 76/12/08. 
* 
*         MSTRSET - PROCESS THE MST RESET STATEMENT.
* 
*         ENTRY 
* 
*           CRKBUF = WORD STRING OF SOURCE STATEMENT. 
* 
*         EXIT
* 
*           . MODULE = BINARY PPU CODE GENERATED FOR THE SOURCE.
*           . FCERR COMPILER ERROR FLAG SET IF COMPILER ERROR CREATED.
* 
*         ROUTINES CALLED -  NONE.
* 
*         DATA AREAS USED -  NONE.
* 
*         USES   A - NONE.
*                X - NONE.
*                B - 7. 
* 
 MSTRSET  SB7    RSETMST     COMMAND ENTRY POINT
          EQ     PCC4        ENTER COMMON P4 SEQUENCE 
          EJECT 
 MSTREW   TITLE  MSTREW  -  PROCESS THE MST REWIND STATEMENT. 
**        MSTREW  -  PROCESS THE MST REWIND STATEMENT.
* 
*         J. E. SIPPER. 76/12/08. 
* 
*         MSTREW - PROCESS THE MST REW STATEMENT. 
* 
*         ENTRY 
* 
*           CRKBUF = WORD STRING OF SOURCE STATEMENT. 
* 
*         EXIT
* 
*           . MODULE = BINARY PPU CODE GENERATED FOR THE SOURCE.
*           . FCERR COMPILER ERROR FLAG SET IF COMPILER ERROR CREATED.
* 
*         ROUTINES CALLED -  NONE.
* 
*         DATA AREAS USED -  NONE.
* 
*         USES   A - NONE.
*                X - NONE.
*                B - 7. 
* 
 MSTREW   SB7    REWMST      COMMAND ENTRY POINT
          EQ     PCC4         ENTER COMMON P4 SEQUENCE
          EJECT 
 MSTSEEK  TITLE  MSTSEEK -  PROCESS THE MST SEEK STATEMENTS.
**        MSTSEEK -  PROCESS THE MST SEEK STATEMENTS. 
* 
*         J. E. SIPPER. 76/12/08. 
* 
*         MSTSEEK - PROCESS THE MST SEEK STATEMENT. 
* 
*         ENTRY 
* 
*           CRKBUF = WORD STRING OF SOURCE STATEMENT. 
* 
*         EXIT
* 
*           . MODULE = BINARY PPU CODE GENERATED FOR THE SOURCE.
*           . FCERR COMPILER ERROR FLAG SET IF COMPILER ERROR CREATED.
* 
*         ROUTINES CALLED -  NONE.
* 
*         DATA AREAS USED -  NONE.
* 
*         USES   A - 1, 3, 6. 
*                X - 0, 1, 3, 6.
*                B - 7. 
* 
 MSTSEEK  SA1    MSTD4
          BX1    X1-X3
          ZR     X1,MSTS1    IF SEEK STREAM STATEMEMT 
 MSTS0A   SA1    MSTD3                                                   MAL023G
          SX0    LDN+6
          EQ     MSTEX       TEST FOR LOADPOINT AND ENTER COMMON SEQUENC
 MSTS1    SA3    A3+B1       NEXT ITEM FROM CRKBUF
          SX6    A3 
          SA6    PCRK        BUMP POINTER TO CRKBUF 
          SA1    MSTS 
          RJ     FIND        GET X
          NG     B2,COM31    ERROR IF NOT FOUND 
          RJ     CLOAD       GENERATE LOAD X CODE 
          SB7    SEEKMST     COMMAND ENTRY POINT
          EQ     MSTB        ENTER COMMON SEQUENCE
  
 MSTS     VFD    42/0,12/17B,3/0,3/REG2  CW FOR X 
          EJECT 
 MSTSET   TITLE  MSTSET -  PROCESS THE MST *SET ERP* STATEMENT. 
**        MSTSET -  PROCESS THE MST *SET ERP* STATEMENT.
* 
*         J. E. SIPPER. 76/12/08. 
* 
*         MSTSET - PROCESS THE MST *SET ERP* STATEMENT. 
* 
*         ENTRY 
* 
*           CRKBUF = WORD STRING OF SOURCE STATEMENT. 
* 
*         EXIT
* 
*           . MODULE = BINARY PPU CODE GENERATED FOR THE SOURCE.
*           . FCERR COMPILER ERROR FLAG SET IF COMPILER ERROR CREATED.
* 
*         ROUTINES CALLED -  NONE.
* 
*         DATA AREAS USED -  NONE.
* 
*         USES   A - 1, 3.
*                X - 0, 1, 3, 6.
*                B - 7. 
* 
 MSTSET   SA1    MSTD7
          BX1    X1-X3
          NZ     X1,COM30    ERROR EXIT IF NEXT ITEM IS NOT *ERP* 
          SX0    LDN+1
          SA3    A3+B1
          SX6    PCRK 
          SB7    WRMST
          EQ     MSTB 
          EJECT 
 MSTSNS   TITLE  MSTSNS  -  PROCESS THE MST SENSE STATEMENT.
**        MSTSNS  -  PROCESS THE MST SENSE STATEMENT. 
* 
*         J. E. SIPPER. 76/12/08. 
* 
*         MSTSNS - PROCESS THE MST SENSE STATEMENT. 
* 
*         ENTRY 
* 
*           CRKBUF = WORD STRING OF SOURCE STATEMENT. 
* 
*         EXIT
* 
*           . MODULE = BINARY PPU CODE GENERATED FOR THE SOURCE.
*           . FCERR COMPILER ERROR FLAG SET IF COMPILER ERROR CREATED.
* 
*         ROUTINES CALLED -  NONE.
* 
*         DATA AREAS USED -  NONE.
* 
*         USES   A - 1, 3, 6. 
*                X - 1, 3, 6. 
*                B - 7. 
* 
 MSTSNS   SA1    MSTD2
          BX1    X1-X3
          NZ     X1,COM30    ERROR EXIT IF NEXT ITEM IS NOT MST 
          SA3    A3+B1       NEXT ITEM FROM CRKBUF
          SX6    A3 
          SA6    PCRK        BUMP POINTER TO CRKBUF 
          SB7    SNSMST      COMMAND ENTRY POINT
          EQ     PCC4         ENTER COMMON P4 SEQUENCE
          EJECT 
 MSTSKIP  TITLE  MSTSKIP -  PROCESS THE MST SKIP STATEMENT. 
**        MSTSKIP -  PROCESS THE MST SKIP STATEMENT.
* 
*         J. E. SIPPER. 76/12/08. 
* 
*         MSTSKIP - PROCESS THE MST *SKIP* STATEMENT. 
* 
*         ENTRY 
* 
*           CRKBUF = WORD STRING OF SOURCE STATEMENT. 
* 
*         EXIT
* 
*           . MODULE = BINARY PPU CODE GENERATED FOR THE SOURCE.
*           . FCERR COMPILER ERROR FLAG SET IF COMPILER ERROR CREATED.
* 
*         ROUTINES CALLED -  NONE.
* 
*         DATA AREAS USED -  NONE.
* 
*         USES   A - 1, 2, 3, 6.
*                X - 0, 1, 2, 3, 6. 
*                B - 7. 
* 
 MSTSKIP  SA1    MSTSK
          RJ     FIND        GET X
          NG     B2,COM31    ERROR EXIT IF NOT FOUND
          RJ     CLOAD       GENERATE LOAD X CODE 
          LX0    12 
          SX1    STD+PA+1 
          BX0    X0+X1
          SA1    MSTD6
          BX1    X1-X3
          NZ     X1,COM30    ERROR EXIT IF NEXT ITEM IS NOT BLOCKS
          SA2    DFWD 
          SA3    A3+B1       NEXT ITEM FROM CRKBUF
          SX1    LDN
          BX2    X2-X3
          ZR     X2,MSTSK1   IF NEXT ITEM IS FWD
          SA2    DREV 
          SX1    X1+B1
          BX2    X2-X3
          NZ     X2,COM30    ERROR EXIT IF NEXT ITEM IS NOT REV 
 MSTSK1   SA3    A3+B1       NEXT ITEM FROM CRKBUF
          SX6    A3 
          SA6    PCRK        BUMP POINTER TO CRKBUF 
          SB7    SKIPMST     COMMAND ENTRY POINT
          LX0    12 
          BX0    X0+X1
          EQ     MSTB        ENTER COMMON SEQUENCE
 MSTSK    VFD    42/0,12/232B,3/0,3/REG2  CW FOR X
          EJECT 
 MSTSTAT  TITLE  MSTSTAT -  PROCESS THE MST STATUS STATEMENT. 
**        MSTSTAT -  PROCESS THE MST STATUS STATEMENT.
* 
*         J. E. SIPPER. 76/12/08. 
* 
*         MSTSTAT - PROCESS THE MST *STATUS* STATEMENT. 
* 
*         ENTRY 
* 
*           CRKBUF = WORD STRING OF SOURCE STATEMENT. 
* 
*         EXIT
* 
*           . MODULE = BINARY PPU CODE GENERATED FOR THE SOURCE.
*           . FCERR COMPILER ERROR FLAG SET IF COMPILER ERROR CREATED.
* 
*         ROUTINES CALLED -  NONE.
* 
*         DATA AREAS USED -  NONE.
* 
*         USES   A - NONE.
*                X - NONE.
*                B - 7. 
* 
 MSTSTAT  SB7    STATMST     COMMAND ENTRY POINT
          EQ     PCC4        ENTER COMMON P4 SEQUENCE 
          EJECT 
 MSTUNL   TITLE  MSTUNL  -  PROCESS THE MST UNLOAD STATEMENT. 
**        MSTUNL  -  PROCESS THE MST UNLOAD STATEMENT.
* 
*         J. E. SIPPER. 76/12/08. 
* 
*         MSTUNL - PROCESS THE MST *UNLOAD* STATEMENT.
* 
*         ENTRY 
* 
*           CRKBUF = WORD STRING OF SOURCE STATEMENT. 
* 
*         EXIT
* 
*           . MODULE = BINARY PPU CODE GENERATED FOR THE SOURCE.
*           . FCERR COMPILER ERROR FLAG SET IF COMPILER ERROR CREATED.
* 
*         ROUTINES CALLED -  NONE.
* 
*         DATA AREAS USED -  NONE.
* 
*         USES   A - NONE.
*                X - NONE.
*                B - 7. 
* 
 MSTUNL   SX0    LDN+7
          EQ     MSTA        ENTER COMMON SEQUENCE
          EJECT 
 MSTWR    TITLE  MSTWR   -  PROCESS THE MST WRITE STATEMENTS. 
**        MSTWR   -  PROCESS THE MST WRITE STATEMENTS.
* 
*         J. E. SIPPER. 76/12/08. 
* 
*         MSTWR - PROCESS THE MST *WRITE* STATEMENT.
* 
*         ENTRY 
* 
*           CRKBUF = WORD STRING OF SOURCE STATEMENT. 
* 
*         EXIT
* 
*           . MODULE = BINARY PPU CODE GENERATED FOR THE SOURCE.
*           . FCERR COMPILER ERROR FLAG SET IF COMPILER ERROR CREATED.
* 
*         ROUTINES CALLED -  NONE.
* 
*         DATA AREAS USED -  NONE.
* 
*         USES   A - 1, 3, 6. 
*                X - 0, 1, 3, 6.
*                B - 7. 
* 
* 
 MSTWR    SX0    LDN+2
          SB7    WRMST
          SA1    MSTD5
          BX1    X1-X3
          NZ     X1,MSTB     IF NOT WRITE TM
          SX0    LDN+0
          SA3    A3+B1       NEXT ITEM FROM CRKBUF
          SX6    A3 
          SA6    PCRK        BUMP POINTER TO CRKBUF 
          EQ     MSTB        ENTER COMMON SEQUENCE
  
 MSTA     SB7    CMDZMST      COMMON COMMANDS ENTRY POINT 
 MSTB     SX1    STD+PA 
          LX0    12 
          BX0    X0+X1
          RJ     CSTOREB     SAVE GENERATED CODE
          EQ     PCC4        ENTER COMMON P4 SEQUENCE 
  
 MSTD1    VFD    60/3LIBG 
 MSTD2    VFD    60/3LMST 
 MSTD3    VFD    60/9LLOADPOINT 
 MSTD4    VFD    60/6LSTREAM
 MSTD5    VFD    60/2LTM
 MSTD6    VFD    60/6LBLOCKS
 MSTD7    VFD    60/3LERP 
 MSTD8    VFD    60/7LRESERVE                                            MAL023G
 MSTD9    VFD    60/7LRELEASE                                            MAL023G
