*COMDECK,MALETPB
          EJECT 
          QUAL   MALETPB
          IFNE   CMSE,0,1 
          USE    MODD 
          VFD    30/1,6/KEY33,6/KEY2,18/0  CW FOR P11 PRODUCT OVERLAY.
          USE    *
*         LENGTHS AND ADDRESSES OF PPU BUFFERS ARE DEFINED BELOW. THESE 
*         VALUES MUST BE KEPT IN PRODUCT OVERLAY ORDER AND MUST  ALWAYS 
*         AGREE  WITH  THE  ACTUAL  VALUES IN THE PPU PRODUCT OVERLAYS. 
* 
  
          IFNE   CMSE,0,1 
          USE    P0OB 
          DATA   100B        MAX VALUE FOR OB FOR (CSU) 
          USE    *
          IFNE   CMSE,0,1 
          USE    P0OBFWA
          DATA   6476B       FWA OF OB FOR OVERLAY (CSU)
          USE    *
          IFNE   CMSE,0,1 
          USE    P0IB 
          DATA   100B        MAX VALUE FOR IB FOR (CSU) 
          USE    *
          IFNE   CMSE,0,1 
          USE    P0IBFWA
          DATA   6376B       FWA OF IB FOR OVERLAY (CSU)
          USE    *
          IFNE   CMSE,0,1 
          USE    P0SB 
          DATA   100B        MAX VALUE FOR SB FOR (CSU) 
          USE    *
          IFNE   CMSE,0,1 
          USE    P0SBFWA
          DATA   6576B       FWA OF SB FOR OVERLAY (CSU)
          USE    *
          EJECT 
*         P11 (CSU) PRODUCT OVERLAY ENTRY POINTS. 
  
 RELP11   EQU    POVL 
 RESP11   EQU    RELP11+4 
 ADVP11   EQU    RESP11+4 
 MNTP11   EQU    ADVP11+4 
 MVEP11   EQU    MNTP11+4 
 PREP11   EQU    MVEP11+4 
 RCLP11   EQU    PREP11+4 
 RSEP11   EQU    RCLP11+4 
 SEKP11   EQU    RSEP11+4 
 SNSP11   EQU    SEKP11+4 
 STAP11   EQU    SNSP11+4 
 SKRP11   EQU    STAP11+4                                                MAL023G
  
          IFNE   CMSE,0,1 
          USE    PKEY 
          VFD    24/0,18/LKEY33,18/TKEY33 
 KEY33    EQU    *-PKEY+PKEYOFF  LEGAL (CSU) I/O COMMANDS 
          USE    *
* 
*         LEGAL HIGH LEVEL COMMANDS FOR CSU.
* 
 TKEY33   VFD    42/7LADVANCE,18/P11ADV 
          VFD    42/5LMOUNT,18/P11MNT 
          VFD    42/4LMOVE,18/P11MVE
          VFD    42/7LPREPARE,18/P11PRE 
          VFD    42/5LRECAL,18/P11RCL 
          VFD    42/3LREL,18/P11REL 
          VFD    42/3LRES,18/P11RES 
          VFD    42/5LRESET,18/P11RSET
          VFD    42/4LSEEK,18/P11SEEK 
          VFD    42/5LSENSE,18/P11SNS 
          VFD    42/6LSTATUS,18/P11STAT 
 LKEY33   EQU    *-TKEY33 
  
*         CONSTANTS USED BY CSU 
  
 DX       VFD    60/1LX 
 DY       VFD    60/1LY 
          EJECT 
 P11ADV   TITLE  P11ADV - PROCESS THE CSU ADVANCE COMMAND.
**        P11ADV - PROCESS THE CSU ADVANCE COMMAND. 
* 
*         E. L. HARMON 77/10/19.
* 
*         ENTRY  - CRKBUF CONTAINS CRACKED COMMAND STRING.
*                  (A3) = ADDRESS OF CRKBUF+1.
*                  (X3) = CONTAINS OF CRKBUF+1. 
* 
*         EXIT   - MODULE UPDATED WITH BINARY OF COMMAND. 
* 
*         ROUTINES CALLED    - CSTOREB. 
* 
*         DATA AREAS USED    - CRKBUF  - CRACKED SOURCE OF COMMAND. 
*                              MODULE  - BINARY CODE GENERATED. 
*         USES   A - NONE.
*                X - 0, 1.
*                B - 7. 
* 
*         MESSAGES - NONE.
* 
 P11ADV   SB7    ADVP11 
          SX0    LDN+1       MST TYPE COMMAND 
          LX0    12 
          SX1    STD+PA 
          BX0    X0+X1
          RJ     CSTOREB     SAVE GENERATED CODE
  
**        COMMON CODE PROCESSING
* 
*         CRACK ABT Z 
  
 PBC4     SA1    DABT 
          BX1    X3-X1
          NZ     X1,COM30    ERROR EXIT IF NEXT ITEM IS NOT ABT 
          SA3    A3+B1
          SX6    A3 
          SA6    PCRK        BUMP POINTER TO CRKBUF 
          ZR     X3,COM30    ERROR EXIT IF END OF STATEMENT 
          SA1    PBCC 
          RJ     FIND        GET Z
          NG     B2,COM31    ERROR EXIT IF NOT FOUND
          NZ     X3,COM30    ERROR EXIT IF NOT END OF STATEMENT 
          RJ     CPSN        PROCESS STATEMENT NUMBER 
          SA1    PBCD 
          SX2    B7          COMMAND ENTRY ADDRESS
          BX0    X1+X2       CODE = LDC 0  RJM ENTRY
          RJ     CABSPPU           ABSOLUTIZE PPU ADDRESSES 
          RJ     CSTOREB     SAVE GENERATED CODE
          EQ     COM10       EXIT TO COMPILER 
  
 PBCA     VFD    57/0,3/REG1           CONTROL WORD FOR V,W,X AND Y 
 PBCB     DATA   0                     BUFFER FOR ENTRY ADDRESS 
 PBCC     VFD    42/0,12/77B,6/0       CONTROL WORD FOR Z 
 PBCD     VFD    12/0,12/LDC,12/0,12/RJM,12/0 
 PBCE     VFD    60/3LCYL              KEYWORDS IN ORDER EXPECTED 
          VFD    60/3LTRK 
          VFD    60/3LSEC 
          EJECT 
 P11LOOP  TITLE  P11LOOP - PROCESS THE CSU LOOPBK COMMAND.
**        P11LOOP - PROCESS THE CSU LOOPBK COMMAND. 
* 
*         G. L. GOLDEN 77/07/07.
* 
*         ENTRY  - CRKBUF CONTAINS CRACKED COMMAND STRING.
*                  (A3) = ADDRESS OF CRKBUF+1.
*                  (X3) = CONTAINS OF CRKBUF+1. 
* 
*         EXIT   - MODULE UPDATED WITH BINARY OF COMMAND. 
*                  (PCRK) UPDATED WITH POINTER TO NEXT SOURCE.
* 
*         ROUTINES CALLED    - CSTOREB - STORE GENERATED CODE.
* 
*         DATA AREAS USED    - CRKBUF  - CRACKED SOURCE OF COMMAND. 
*                              MODULE  - BINARY CODE GENERATED. 
*                              PCRK    - POINTER TO NEXT SOURCE CODE. 
*         USES   A - 1, 3, 6. 
*                X - 0, 1, 3, 6.
*                B - 2, 3, 7. 
* 
*         MESSAGES - NONE.
* 
*P11LOOP  SB7    LOOP11      COMMAND ENTRY POINT
          SB2    B0          CLEAR INDEX
          SX0    LDN
          SB3    LP11LB      LENGTH OF KEYNAMES 
 P11LB1   SA1    P11LB+B2 
          BX1    X1-X3
          ZR     X1,P11LB2   IF MATCH FOUND 
          SB2    B2+B1
          SX0    X0+B1
          NE     B2,B3,P11LB1  IF ALL KEY NAMES NOT PROCESSED 
          EQ     COM30       ERROR EXIT IF KEYWORD NOT FOUND
  
 P11LB2   SA3    A3+B1
          SX6    A3 
          SA6    PCRK        BUMP POINTER TO CRKBUF 
          SX1    STD+PA+1    FORM STD  PA+1  INSTRUCTION
          LX0    12 
          BX0    X0+X1
          RJ     CSTOREB     SAVE GENERATED CODE
          SX0    LDN
          SX1    STD+PA 
          LX0    12 
          BX0    X0+X1
          RJ     CSTOREB     SAVE GENERATED CODE
          EQ     PBC4 
  
 P11LB    VFD    60/3LMSA 
          VFD    60/3LCTL 
 LP11LB   EQU    *-P11LB
          EJECT 
 P11MAR   TITLE  P11MAR - PROCESS THE CSU MARGINS COMMAND.
**        P11MAR - PROCESS THE CSU MARGINS COMMAND. 
* 
*         G. L. GOLDEN 77/07/07.
* 
*         ENTRY  - CRKBUF CONTAINS CRACKED COMMAND STRING.
*                  (A3) = ADDRESS OF CRKBUF+1.
*                  (X3) = CONTAINS OF CRKBUF+1. 
* 
*         EXIT   - MODULE UPDATED WITH BINARY OF COMMAND. 
*                  (PCRK) UPDATED WITH POINTER TO NEXT SOURCE.
* 
*         ROUTINES CALLED    - CSTOREB - STORE GENERATED CODE.
*                            - CLOAD   - GENERATE LOAD INSTRUCTION. 
* 
*         DATA AREAS USED    - CRKBUF  - CRACKED SOURCE OF COMMAND. 
*                              MODULE  - BINARY CODE GENERATED. 
*                              PCRK    - POINTER TO NEXT SOURCE CODE. 
*         USES   A - 1, 3, 6. 
*                X - 0, 1, 3, 6.
*                B - 2, 7.
* 
*         MESSAGES - NONE.
* 
*P11MAR   SB7    MARP11 
          SX0    LDN
          SB2    B0 
          SB3    LP11MA      LENGTH OF KEYWORDS TABLE 
 P11MA1   SA1    P11CSU+B2
          BX1    X1-X3
          ZR     X1,P11MA2   IF KEYWORD  FOUND
          SB2    B2+B1
          SX0    X0+B1
          NE     B2,B3,P11MA1  IF NOT DONE WITH SCAN OF KEYWORDS
          EQ     COM30       ERROR EXIT IF NOT FOUND
  
 P11MA2   LX0    12 
          SX1    STD+PA 
          BX0    X0+X1
          RJ     CSTOREB     STORE GENERATED CODE 
          SX0    LDC
          LX0    12 
  
 P11MA3   SA1    PCRK 
          SA3    X1+B1
          ZR     X3,COM30    ERROR IF END OF PARAMETERS 
          SA1    DABT 
          BX1    X3-X1
          ZR     X1,COM30    IF ABT FOUND 
          SX6    A3 
          SA6    PCRK        BUMP POINT INTO CRKBUF 
          SB2    B0 
          SB3    LP11TA 
 P11MA4   SA1    P11TA+B2 
          BX1    X3-X1
          ZR     X1,P11MA5  IF MATCH FOUND
          SB2    B2+B1
          LT     B2,B3,P11MA4  IF NOT DONE WITH TABLE 
  
          SA1    P11MVA      CW FOR REG 
          RJ     FIND 
          NG     B2,COM30    IF PN NOT REG OR TABLE 
          MX0    0
          RJ     CLOAD       GENERATE LOAD INSTRUCTION
          EQ     P11MA6 
  
 P11MA5   SA1    P11TB+B2 
          BX0    X1+X0       COMBINE BITS SET 
          SA3    A3+B1
          SX6    A3 
          SA6    PCRK        BUMP POINTER INTO CRKBUF 
 P11MA6   LX0    12 
          SX1    STD+PA+1 
          BX0    X0+X1
          RJ     CSTOREB
          EQ     PBC4        ENTER COMMON SEQUENCE
  
 P11CSU   VFD    60/3LCSU 
 P11MST   VFD    60/3LMST 
 LP11MA   EQU    *-P11CSU    LENGTH OF TABLE
  
*         TABLE OF LEGAL PARAMETERS FOR MARGINS COMMAND.
  
 P11TA    VFD    60/2LLC
 LP11TA   EQU    *-P11TA     LENGTH OF TABLE
  
*         TABLE OF VALUES TO USE IF MATCH ON TABLE. 
  
 P11TB    VFD    48/0,12/4000B  ENTRY TO MATCH LC 
          EJECT 
 P11MNT   TITLE  P11MNT - PROCESS THE CSU MOUNT COMMAND.
**        P11MNT - PROCESS THE CSU MOUNT COMMAND. 
* 
*         G. L. GOLDEN 77/07/07.
* 
*         ENTRY  - CRKBUF CONTAINS CRACKED COMMAND STRING.
*                  (A3) = ADDRESS OF CRKBUF+1.
*                  (X3) = CONTAINS OF CRKBUF+1. 
* 
*         EXIT   - MODULE UPDATED WITH BINARY OF COMMAND. 
*                  (PCRK) UPDATED WITH POINTER TO NEXT SOURCE.
* 
*         ROUTINES CALLED    - CSTOREB - STORE GENERATED CODE.
* 
*         DATA AREAS USED    - CRKBUF  - CRACKED SOURCE OF COMMAND. 
*                              MODULE  - BINARY CODE GENERATED. 
*                              PCRK    - POINTER TO NEXT SOURCE CODE. 
*         USES   A - NONE.
*                X - 0, 1.
*                B - 7. 
* 
*         MESSAGES - NONE.
* 
 P11MNT   SB7    MNTP11 
          SX0    LDN
          SX1    STD+PA 
          LX0    12 
          BX0    X1+X0
          RJ     CSTOREB
          EQ     PBC4        ENTER COMMON SEQUENCE
          EJECT 
 P11MVE   TITLE  P11MVE - PROCESS THE CSU MOVE COMMAND. 
**        P11MVE - PROCESS THE CSU MOVE COMMAND.
* 
*         G. L. GOLDEN 77/07/07.
* 
*         ENTRY  - CRKBUF CONTAINS CRACKED COMMAND STRING.
*                  (A3) = ADDRESS OF CRKBUF+1.
*                  (X3) = CONTAINS OF CRKBUF+1. 
* 
*         EXIT   - MODULE UPDATED WITH BINARY OF COMMAND. 
*                  (PCRK) UPDATED WITH POINTER TO NEXT SOURCE.
* 
*         ROUTINES CALLED    - CSTOREB - STORE GENERATED CODE.
*                              CLOAD   - GENERATE LOAD INSTRUCTION. 
* 
*         DATA AREAS USED    - CRKBUF  - CRACKED SOURCE OF COMMAND. 
*                              MODULE  - BINARY CODE GENERATED. 
*                              PCRK    - POINTER TO NEXT SOURCE CODE. 
*         USES   A - 1, 3, 6. 
*                X - 0, 1, 3, 6.
*                B - 7. 
* 
*         MESSAGES - NONE.
* 
 P11MVE   SB7    MVEP11 
 P11MVE1  SX0    LDN
          SX1    STD+PA 
          LX0    12 
          BX0    X1+X0
          RJ     CSTOREB
          SA1    DX 
          BX1    X1-X3
          NZ     X1,COM30    ERROR EXIT IF NOT X
          SA1    PCRK 
          SA1    X1+B1
          SX1    X1-1R= 
          NZ     X1,COM30    ERROR EXIT IF NOT = SIGN 
          SX6    A1+B1
          SA6    PCRK        BUMP POINTER TO NEXT CRACKED VALUE 
          SA1    P11MVA 
          RJ     FIND 
          NG     B2,COM30    ERROR EXIT IF NOT FOUND
          RJ     CLOAD       GENERATE LOAD INSTRUCTION
          LX0    12 
          SX1    STD+PA+1 
          BX0    X0+X1
          RJ     CSTOREB     STORE GENERATED CODE 
          SA1    DY          GET DISPLAY CODE Y 
          BX1    X3-X1
          NZ     X1,COM30    ERROR EXIT IF NOT Y
          SA1    A3+B1
          SX1    X1-1R= 
          NZ     X1,COM30    ERROR EXIT IF NOT = SIGN 
          SX6    A1+B1
          SA6    PCRK 
          SA1    P11MVA 
          RJ     FIND 
          NG     B2,COM31    ERROR EXIT IF NOT FOUND
          RJ     CLOAD       GENERATE LOAD CONSTANT 
          LX0    12 
          SX1    STD+PA+2 
          BX0    X0+X1
          RJ     CSTOREB
          SX0    LDN
          SX1    STD+PA+3 
          LX0    12 
          BX0    X1+X0
          RJ     CSTOREB
          EQ     PBC4        ENTER COMMON SEQUENCE
  
 P11MVA   VFD    42/0,12/7777B,3/0,3/REG2   CW FOR X AND Y
          EJECT 
 P11PRE   TITLE  P11PRE - PROCESS THE CSU PREPARE COMMAND.
**        P11PRE - PROCESS THE CSU PREPARE COMMAND. 
* 
*         G. L. GOLDEN 77/07/07.
* 
*         ENTRY  - CRKBUF CONTAINS CRACKED COMMAND STRING.
*                  (A3) = ADDRESS OF CRKBUF+1.
*                  (X3) = CONTAINS OF CRKBUF+1. 
* 
*         EXIT   - MODULE UPDATED WITH BINARY OF COMMAND. 
*                  (PCRK) UPDATED WITH POINTER TO NEXT SOURCE.
* 
*         ROUTINES CALLED    - CSTOREB - STORE GENERATED CODE.
* 
*         DATA AREAS USED    - CRKBUF  - CRACKED SOURCE OF COMMAND. 
*                              MODULE  - BINARY CODE GENERATED. 
*                              PCRK    - POINTER TO NEXT SOURCE CODE. 
*         USES   A - 1, 3, 6. 
*                X - 0, 1, 3, 6.
*                B - 7. 
* 
*         MESSAGES - NONE.
* 
 P11PRE   SB7    PREP11 
          SX0    LDN
          SA1    P11CSU 
          BX1    X1-X3
          ZR     X1,P11P1    IF CSU 
          SA1    P11MST 
          BX1    X1-X3
          NZ     X1,COM30    ERROR EXIT IF NOT MST
          SX0    LDN+1
 P11P1    SA3    A3+B1
          SX6    A3 
          SA6    PCRK        BUMP POINTER INTO CRKBUF 
          SX1    STD+PA 
          LX0    12 
          BX0    X1+X0
          RJ     CSTOREB
          EQ     PBC4 
          EJECT 
 P11RCL   TITLE  P11RCL - PROCESS THE CSU RECAL COMMAND.
**        P11RCL - PROCESS THE CSU RECAL COMMAND. 
* 
*         G. L. GOLDEN 77/07/07.
* 
*         ENTRY  - CRKBUF CONTAINS CRACKED COMMAND STRING.
*                  (A3) = ADDRESS OF CRKBUF+1.
*                  (X3) = CONTAINS OF CRKBUF+1. 
* 
*         EXIT   - MODULE UPDATED WITH BINARY OF COMMAND. 
* 
*         ROUTINES CALLED    - NONE.
* 
*         DATA AREAS USED    - CRKBUF  - CRACKED SOURCE OF COMMAND. 
*                              MODULE  - BINARY CODE GENERATED. 
*         USES   A - NONE.
*                X - 0, 1.
*                B - 7. 
* 
*         MESSAGES - NONE.
* 
 P11RCL   SB7    RCLP11 
          SX0    LDN
          LX0    12 
          SX1    STD+PA 
          BX0    X0+X1
          RJ     CSTOREB     SAVE GENERATED CODE
          EQ     PBC4        ENTER COMMON SEQUENCE
          EJECT 
 P11REL   TITLE  P11REL - PROCESS THE CSU REL COMMAND.
**        P11REL - PROCESS THE CSU REL COMMAND. 
* 
*         G. L. GOLDEN 77/07/07.
* 
*         ENTRY  - CRKBUF CONTAINS CRACKED COMMAND STRING.
*                  (A3) = ADDRESS OF CRKBUF+1.
*                  (X3) = CONTAINS OF CRKBUF+1. 
* 
*         EXIT   - MODULE UPDATED WITH BINARY OF COMMAND. 
*                  (PCRK) UPDATED WITH POINTER TO NEXT SOURCE.
* 
*         ROUTINES CALLED    - NONE.
* 
*         DATA AREAS USED    - CRKBUF  - CRACKED SOURCE OF COMMAND. 
*                              MODULE  - BINARY CODE GENERATED. 
*                              PCRK    - POINTER TO NEXT SOURCE CODE. 
*         USES   A - NONE.
*                X - NONE.
*                B - 7. 
* 
*         MESSAGES - NONE.
* 
 P11REL   SB7    RELP11 
          EQ     PBC4        ENTER COMMON SEQUENCE
          EJECT 
 P11RES   TITLE  P11RES - PROCESS THE CSU RES COMMAND.
**        P11RES - PROCESS THE CSU RES COMMAND. 
* 
*         G. L. GOLDEN 77/07/07.
* 
*         ENTRY  - CRKBUF CONTAINS CRACKED COMMAND STRING.
*                  (A3) = ADDRESS OF CRKBUF+1.
*                  (X3) = CONTAINS OF CRKBUF+1. 
* 
*         EXIT   - MODULE UPDATED WITH BINARY OF COMMAND. 
*                  (PCRK) UPDATED WITH POINTER TO NEXT SOURCE.
* 
*         ROUTINES CALLED    - NONE.
* 
*         DATA AREAS USED    - CRKBUF  - CRACKED SOURCE OF COMMAND. 
*                              MODULE  - BINARY CODE GENERATED. 
*                              PCRK    - POINTER TO NEXT SOURCE CODE. 
*         USES   A - NONE.
*                X - NONE.
*                B - 7. 
* 
*         MESSAGES - NONE.
* 
 P11RES   SB7    RESP11 
          EQ     PBC4       ENTER COMMON SEQUENCE 
          EJECT 
 P11RSET  TITLE  P11RSET - PROCESS THE CSU RESET COMMAND. 
**        P11RSET - PROCESS THE CSU RESET COMMAND.
* 
*         E. L. HARMON 77/10/07.
* 
*         ENTRY  - CRKBUF CONTAINS CRACKED COMMAND STRING.
*                  (A3) = ADDRESS OF CRKBUF+1.
*                  (X3) = CONTENTS OF CRKBUF+1. 
* 
*         EXIT   - MODULE UPDATED WITH BINARY OF COMMAND. 
*                  (PCRK) UPDATED WITH POINTER TO NEXT SOURCE.
* 
*         ROUTINES CALLED    - CSTOREB - STORE GENERATED CODE.
* 
*         DATA AREAS USED    - CRKBUF  - CRACKED SOURCE OF COMMAND. 
*                              MODULE  - BINARY CODE GENERATED. 
*                              PCRK    - POINTER TO NEXT SOURCE CODE. 
*         USES   A - 1, 3, 6. 
*                X - 0, 1, 3, 6.
*                B - 7. 
* 
*         MESSAGES - NONE.
* 
 P11RSET  SB7    RSEP11 
          SX0    LDN
          SA1    P11CSU 
          BX1    X3-X1
          ZR     X1,P11R1    IF CSU 
          SA1    P11MST 
          BX1    X3-X1
          NZ     X1,COM30    ERROR EXIT IF NOT MST
          SX0    LDN+1
 P11R1    LX0    12 
          SX1    STD+PA 
          BX0    X0+X1
          RJ     CSTOREB     SAVE GENERATED CODE
          SA3    A3+B1
          SX6    A3 
          SA6    PCRK        BUMP POINTER INTO CRKBUF 
          EQ     PBC4        ENTER COMMON SEQUENCE
          EJECT 
 P11SEEK  TITLE  P11SEEK - PROCESS THE CSU SEEK COMMAND.
**        P11SEEK - PROCESS THE CSU SEEK COMMAND. 
* 
*         G. L. GOLDEN 77/07/07.
* 
*         ENTRY  - CRKBUF CONTAINS CRACKED COMMAND STRING.
*                  (A3) = ADDRESS OF CRKBUF+1.
*                  (X3) = CONTAINS OF CRKBUF+1. 
* 
*         EXIT   - MODULE UPDATED WITH BINARY OF COMMAND. 
*                  (PCRK) UPDATED WITH POINTER TO NEXT SOURCE.
* 
*         ROUTINES CALLED    - CSTOREB - STORE GENERATED CODE.
* 
*         DATA AREAS USED    - CRKBUF  - CRACKED SOURCE OF COMMAND. 
*                              MODULE  - BINARY CODE GENERATED. 
*                              PCRK    - POINTER TO NEXT SOURCE CODE. 
*         USES   A - 1, 3, 6. 
*                X - 0, 1, 3, 6.
*                B - 7. 
* 
*         MESSAGES - NONE.
* 
 P11SEEK  SB7    SEKP11 
          SA1    P11MST 
          BX1    X1-X3
          NZ     X1,P11MVE1  IF NOT MST ENTER COMMON SEQUENCE 
          SX0    LDN+1
          SX1    STD+PA+3 
          LX0    12 
          BX0    X1+X0
          RJ     CSTOREB
          SX0    LDN
          SX1    STD+PA 
          LX0    12 
          BX0    X1+X0
          RJ     CSTOREB
          SA3    A3+B1
          SX6    A3 
          SA6    PCRK        BUMP POINTER INTO CRKBUF 
          EQ     PBC4        ENTER COMMON SEQUENCE
 DRES     VFD    60/7LRESERVE                                            MAL023G
 DREL     VFD    60/7LRELEASE                                            MAL023G
          EJECT 
 P11SNS   TITLE  P11SNS - PROCESS THE CSU SENSE COMMAND.
**        P11SNS - PROCESS THE CSU SENSE COMMAND. 
* 
*         G. L. GOLDEN 77/07/07.
* 
*         ENTRY  - CRKBUF CONTAINS CRACKED COMMAND STRING.
*                  (A3) = ADDRESS OF CRKBUF+1.
*                  (X3) = CONTAINS OF CRKBUF+1. 
* 
*         EXIT   - MODULE UPDATED WITH BINARY OF COMMAND. 
*                  (PCRK) UPDATED WITH POINTER TO NEXT SOURCE.
* 
*         ROUTINES CALLED    - CSTOREB - STORE GENERATED CODE.
* 
*         DATA AREAS USED    - CRKBUF  - CRACKED SOURCE OF COMMAND. 
*                              MODULE  - BINARY CODE GENERATED. 
*                              PCRK    - POINTER TO NEXT SOURCE CODE. 
*         USES   A - 1, 3, 6. 
*                X - 0, 1, 3, 6.
*                B - 7. 
* 
*         MESSAGES - NONE.
* 
 P11SNS   SB7    SNSP11 
          SX0    LDN
          SA1    P11CSU 
          BX1    X3-X1
          ZR     X1,P11S1    IF CSU 
          SA1    P11MST 
          BX1    X3-X1
          NZ     X1,COM30    ERROR EXIT IF NOT MST
          SX0    LDN+1
 P11S1    LX0    12 
          SX1    STD+PA 
          BX0    X0+X1
          RJ     CSTOREB     SAVE GENERATED CODE
          SA3    A3+B1
          SX6    A3 
          SA6    PCRK        BUMP POINTER INTO CRKBUF 
          EQ     PBC4        ENTER COMMON SEQUENCE
          EJECT 
 P11STAT  TITLE  P11STAT - PROCESS THE CSU STATUS COMMAND.
**        P11STAT - PROCESS THE CSU STATUS COMMAND. 
* 
*         G. L. GOLDEN 77/07/07.
* 
*         ENTRY  - CRKBUF CONTAINS CRACKED COMMAND STRING.
*                  (A3) = ADDRESS OF CRKBUF+1.
*                  (X3) = CONTAINS OF CRKBUF+1. 
* 
*         EXIT   - MODULE UPDATED WITH BINARY OF COMMAND. 
*                  (PCRK) UPDATED WITH POINTER TO NEXT SOURCE.
* 
*         ROUTINES CALLED    - NONE.
* 
*         DATA AREAS USED    - CRKBUF  - CRACKED SOURCE OF COMMAND. 
*                              MODULE  - BINARY CODE GENERATED. 
*                              PCRK    - POINTER TO NEXT SOURCE CODE. 
*         USES   A - NONE.
*                X - NONE.
*                B - 7. 
* 
*         MESSAGES - NONE.
* 
 P11STAT  SB7    STAP11 
          EQ     PBC4        ENTER COMMON SEQUENCE
          EJECT 
