*DECK,SBP                                                                MLD
          IDENT  SBP,SBP                                                 MLD
          PERIPH                                                         MLD
          SST                                                            MLD
          TITLE   STAND BY PPU FOR MALET IAM/OAM CHANNEL PROTECTION.     MLD
*CALL,CPYCOM                                                             MLD
          EJECT                                                          MLD
**        MAINTENANCE LANGUAGE STAND BY PPU PROGRAM.                     MLD
*                                                                        MLD
*         DESCRIPTION-  THE SBP PPU IS A SLAVE TO *MALET*, THE CDC       MLD
*                       CONCURRENT MAINTENANCE EXECUTIVE.                MLD
*                                                                        MLD
*         CALLING SEQUENCE-                                              MLD
*                                                                        MLD
*         AUTO-RECALL IS USED BY THE CPU TO CALL SBP WITH A DUMMY FET.   MLD
*                                                                        MLD
*                       ----------------------------                     MLD
*                RA+1   I XXXX XXY0 0000 0000 ZZZZ I                     MLD
*                       ----------------------------                     MLD
*                                                                        MLD
*                          XXXXXX = SBP IN DISPLAY CODE.                 MLD
*                          Y = AUTO RECALL BIT.                          MLD
*                          ZZZZ = DUMMY FET ADDRESS.                     MLD
*                                                                        MLD
*                       ----------------------------                     MLD
*                   Z   I 0000 0000 AAAA 0000 BBBB I                     MLD
*                       ----------------------------                     MLD
*                                                                        MLD
*                       AAAA = FWA OF THE COMMUNICATIONS BLOCK           MLD
*                              IN CM (POINTS TO SECURE).                 MLD
*                       BBBB = 0002 (BIT 0 IS THE COMPLETE BIT).         MLD
*                                                                        MLD
*         THE PPU WILL READ THE DUMMY FET WORD (ZZZZ) AND  VERIFY  THAT  MLD
*         BYTE  BBBB  IS  EQUAL  TO  0002.   IF NOT, AN ABORT SEQUENCE,  MLD
*         DESCRIBED LATER, IS ENTERED. THE PPU SAVES AAAA AND READS THE  MLD
*         FIRST CM WORD AT THAT ADDRESS. (SECURE)                        MLD
*                                                                        MLD
*                                                                        MLD
*                       ----------------------------                     MLD
*                SECURE I NNNN NNNN NNNN NNNN NNNN I                     MLD
*                       ----------------------------                     MLD
*                                                                        MLD
*                       NN-NN = XXXXXXXXXX IN DISPLAY CODE.              MLD
*                                                                        MLD
*         IF THE FORMAT OF THE SECURITY WORD IS NOT  CORRECT,  THE  PPU  MLD
*         ENTERS THE ABORT SEQUENCE.                                     MLD
*                                                                        MLD
*         THE  PPU  THEN READS THE INPUT REGISTER IN THE COMMUNICATIONS  MLD
*         BLOCK AND GOES INTO A LOOP TESTING THE CHANNEL FOR A CONSTANT  MLD
*         STATE  OF  ACTIVE AND FULL OR ACTIVE AND EMPTY FOR 5 SECONDS.  MLD
*         IF THIS EVER HAPPENDS SBP DISCONNECTS  THE  CHANNEL,  LOGS  A  MLD
*         DAFILE  MESSAGE  AND  STAYS IN THE CHANNEL TESTING LOOP UNTIL  MLD
*         THE INPUT REGISTER BYTE 0 GOES NON ZERO.                       MLD
*                                                                        MLD
          EJECT                                                          MLD
**                                                                       MLD
*         COMMUNICATIONS-                                                MLD
*                                                        NUMBER          MLD
*                      *COMMUNICATION BLOCK*               OF            MLD
*                                                         WORDS          MLD
*                -----------------------------------------------         MLD
*                I                                       I     I         MLD
*                I    SECURITY WORD                      I   1 I         MLD
*                I---------------------------------------------I         MLD
*                I                                       I     I         MLD
*                I    INPUT REGISTER                     I   1 I         MLD
*                I---------------------------------------------I         MLD
*                I                                       I     I         MLD
*                I    OUTPUT REGISTER                    I   1 I         MLD
*                I---------------------------------------------I         MLD
*                I                                       I     I         MLD
*                I    MESSAGE BUFFER                     I   5 I         MLD
*                I---------------------------------------------I         MLD
*                I                                       I     I         MLD
*                I    PPU DISPLAY BUFFER                 I 164 I
*                I---------------------------------------------I         MLD
*                I                                       I     I         MLD
*                I    PPU PLOT BUFFER                    I  40 I         MLD
*                I---------------------------------------------I         MLD
*                I                                       I     I         MLD
*                I    PPU CHECKPOINT BUFFER              I 975 I
*                I---------------------------------------------I         MLD
*                I                                       I     I         MLD
*                I    SCRATCH FILE WORKING BUFFER        I  70 I
*                I---------------------------------------------I         MLD
*                I                                       I     I         MLD
*                I    MODULE BUFFER                      I1453 I
*                I---------------------------------------------I         MLD
*                I                                       I     I         MLD
*                I    STANDBY PPU COMMUNICATIONS         I 120 I
*                I---------------------------------------------I         MLD
*                I                                       I     I         MLD
*                I    STANDBY PPU COMMUNICATIONS         I   2 I         MLD
*                -----------------------------------------------         MLD
*                                                                        MLD
*                                                                        MLD
                                                                         MLD
 L.SEC    EQU    1                                                       MLD
 L.IR     EQU    1                                                       MLD
 L.OR     EQU    1                                                       MLD
 L.MB     EQU    5                                                       MLD
 L.DB     EQU    164         L.DB = DB + WDB
 L.PB     EQU    40                                                      MLD
 L.CB     EQU    975         L.CB INCREASED FOR 16-BIT MALET
 L.SFB    EQU    70 
 L.MOD    EQU    1453        L.MOD INCREASED FOR 16-BIT MALET 
 L.POMB   EQU    120                                                     MLD
 L.SBPIR  EQU    1                                                       MLD
 L.SBP0R  EQU    1                                                       MLD
          EJECT                                                          MLD
**        ENTRY- SBP IS CALLED BY THE EXEC PROGRAM WHENEVER THE PPU 
*                DRIVERS MLD OR WLD ARE CALLED.   SBP EXAMINES THE
*                INPUT REGISTER IN THE COMMUNICATION BLOCK TO DETERMINE  MLD
*                IF THE MALET DRIVER IS DUING AN IAM/OAM INSTRUCTION.    MLD
*                                                                        MLD
*                                                                        MLD
*                                                                        MLD
*                THE INPUT REGISTER WILL CONTAIN THE FOLLOWING_          MLD
*                                                                        MLD
*                        ----------------------------                    MLD
*                 SBIR   I 0000 0000 0000 0000 SSSS I                    MLD
*                        ----------------------------                    MLD
*                                                                        MLD
*                IF THE VALUE FOR SSSS EVER GOES NON ZERO SBP DROPS      MLD
*                THE PPU.                                                MLD
*                                                                        MLD
*                                                                        MLD
*                                                                        MLD
 SEF      EQU    1           STOP-ON-ERROR FLAG                          MLD
 RMF      EQU    2           REPEAT-MODULE FLAG                          MLD
 RCF      EQU    4           REPEAT-CONDITION FLAG                       MLD
 RTF      EQU    10B         REPEAT TEST FLAG                            MLD
 DF       EQU    20B         DROP FLAG                                   MLD
 CF       EQU    40B         CHECKPOINT FLAG                             MLD
 PLF      EQU    100B        PRINT LOG ACTIVE FLAG                       MLD
 DFF      EQU    200B        DAYFILE LOG ACTIVE FLAG                     MLD
 KLF      EQU    400B        SYSTEM K/L DISPLAY ACTIVE FLAG              MLD
 SBF      EQU    1000B       STANDBY PPU OPTION ACTIVE FLAG              MLD
                                                                         MLD
          EJECT                                                          MLD
*CALL,ASSYTAG                                                            MLD
          IFEQ   NOS,1                                                   MLD
 P.ZERO   EQU    ZERL                                                    MLD
 D.Z0     EQU    0                                                       MLD
 D.Z1     EQU    1                                                       MLD
 D.Z2     EQU    2                                                       MLD
 D.Z3     EQU    3                                                       MLD
 D.Z4     EQU    4                                                       MLD
 D.Z5     EQU    5                                                       MLD
 D.Z6     EQU    6                                                       MLD
 D.Z7     EQU    7                                                       MLD
 D.T0     EQU    10B                                                     MLD
 D.T1     EQU    11B                                                     MLD
 D.T2     EQU    12B                                                     MLD
 D.T3     EQU    13B                                                     MLD
 D.T4     EQU    14B                                                     MLD
 D.T5     EQU    15B                                                     MLD
 D.T6     EQU    16B                                                     MLD
 D.T7     EQU    17B                                                     MLD
                                                                         MLD
 D.RA     EQU    RA                                                      MLD
 D.FL     EQU    FL                                                      MLD
 D.CPAD   EQU    CP                                                      MLD
 D.PPIR   EQU    IA                                                      MLD
 D.PPOR   EQU    OA                                                      MLD
 D.PPMSG  EQU    MA                                                      MLD
 D.PPIRB  EQU    IR                                                      MLD
 D.PPONE  EQU    ON                                                      MLD
 M.DPP    EQU    DPPM                                                    MLD
 M.ABORT  EQU    ABTM        ABORT CONTROL POINT
 M.RCL    EQU    RCLM                                                    MLD
 M.DCP    EQU    DCPM                                                    MLD
 C.PPFWA  EQU    PPFW                                                    MLD
 M.RCP    EQU    RCPM                                                    MLD
 L.CPNUM  EQU    37B                                                     MLD
 W.CPSTAT EQU    STSW                                                    MLD
*                                                                        MLD
 R.IDLE   EQU    PPR                                                     MLD
 R.DFM    EQU    DFM                                                     MLD
          XTEXT  COMPMAC
 R.OVL    EQU    EXR                                                     MLD
 R.MTR    EQU    FTN                                                     MLD
 R.MTR    EQU    FTN                                                     MLD
          ENDIF                                                          MLD
          EJECT                                                          MLD
*                                                                        MLD
*         OPERATING REGISTERS                                            MLD
*                                                                        MLD
*                                                                        MLD
 B0       EQU    20B                                                     MLD
 B1       EQU    21B                                                     MLD
 B2       EQU    22B                                                     MLD
 B3       EQU    23B                                                     MLD
 B4       EQU    24B                                                     MLD
 B5       EQU    25B                                                     MLD
 B6       EQU    26B                                                     MLD
 B7       EQU    27B                                                     MLD
 WC       EQU    30B                                                     MLD
 BA       EQU    31B                                                     MLD
 P0       EQU    32B                                                     MLD
 P1       EQU    33B                                                     MLD
 P2       EQU    34B                                                     MLD
 P3       EQU    35B                                                     MLD
 P4       EQU    36B                                                     MLD
 P5       EQU    37B                                                     MLD
 P6       EQU    40B                                                     MLD
 P7       EQU    41B                                                     MLD
 P8       EQU    42B                                                     MLD
 P9       EQU    43B                                                     MLD
 WT       EQU    44B                                                     MLD
 LF       EQU    45B                                                     MLD
 P        EQU    46B                                                     MLD
 EC       EQU    47B                                                     MLD
 EA       EQU    50B                                                     MLD
 EM       EQU    51B                                                     MLD
 DC       EQU    52B                                                     MLD
*         EQU    53B         RESERVED                                    MLD
 RT       EQU    54B                                                     MLD
*   D.RA  EQU    55B                                                     MLD
*   D.FL  EQU    56B                                                     MLD
 ES       EQU    57B                                                     MLD
 DCNCNT   EQU    60B
                                                                         MLD
 F.ABT    EQU    1                                                       MLD
 F.BLANK  EQU    2                                                       MLD
 F.DROP   EQU    3           PPU  FUNCTION CODES TO EXEC                 MLD
 F.END    EQU    4                                                       MLD
 F.ERR    EQU    5                                                       MLD
 F.HALT   EQU    6                                                       MLD
 F.LOAD   EQU    7                                                       MLD
 F.PIC    EQU    10B                                                     MLD
 F.SYS    EQU    11B                                                     MLD
 F.TERM   EQU    12B                                                     MLD
                                                                         MLD
 F.EOF    EQU    0           SYS SUBFUNCTIONS                            MLD
 F.POS    EQU    1                                                       MLD
 F.READ   EQU    2                                                       MLD
 F.REW    EQU    3                                                       MLD
 F.WRITE  EQU    4                                                       MLD
                                                                         MLD
 F.START  EQU    1           CPU EXEC FUNCTION CODES TO PPU              MLD
 F.RESUME EQU    2                                                       MLD
          EJECT                                                          MLD
                                                                         MLD
*         MACROS FOR BASIC DRIVER AND ALL PRODUCT OVERLAYS               MLD
*                                                                        MLD
          PURGMAC ACN                                                    MLD
 ACN      MACRO  X                                                       MLD
          CHOP                                                           MLD
          VFD    12/7400B+X                                              MLD
          ENDM                                                           MLD
          PURGMAC AJM                                                    MLD
                                                                         MLD
 AJM      MACRO  X                                                       MLD
          CHOP                                                           MLD
          VFD    12/6400B                                                MLD
          VFD    12/X                                                    MLD
          ENDM                                                           MLD
                                                                         MLD
          PURGMAC CHOP                                                   MLD
 CHOP     MACRO                                                          MLD
          LOCAL  A                                                       MLD
 A        SET    *L                                                      MLD
          RMT                                                            MLD
          VFD    12/A                                                    MLD
          RMT                                                            MLD
          ENDM                                                           MLD
                                                                         MLD
          PURGMAC DCN                                                    MLD
 DCN      MACRO  X                                                       MLD
          CHOP                                                           MLD
          VFD    12/7500B+X                                              MLD
          ENDM                                                           MLD
                                                                         MLD
          PURGMAC EJM                                                    MLD
 EJM      MACRO  X                                                       MLD
          CHOP                                                           MLD
          VFD    12/6700B                                                MLD
          VFD    12/X                                                    MLD
          ENDM                                                           MLD
                                                                         MLD
          PURGMAC FAN                                                    MLD
 FAN      MACRO  X                                                       MLD
          CHOP                                                           MLD
          VFD    12/7600B+X                                              MLD
          ENDM                                                           MLD
                                                                         MLD
          PURGMAC FJM                                                    MLD
 FJM      MACRO  X                                                       MLD
          CHOP                                                           MLD
          VFD    12/6600B                                                MLD
          VFD    12/X                                                    MLD
          ENDM                                                           MLD
                                                                         MLD
          PURGMAC FNC                                                    MLD
 FNC      MACRO  X                                                       MLD
          CHOP                                                           MLD
          VFD    12/7700B                                                MLD
          VFD    12/X                                                    MLD
          ENDM                                                           MLD
                                                                         MLD
          PURGMAC IAM                                                    MLD
 IAM      MACRO  X                                                       MLD
          CHOP                                                           MLD
          VFD    12/7100B                                                MLD
          VFD    12/X                                                    MLD
          ENDM                                                           MLD
                                                                         MLD
          PURGMAC IAN                                                    MLD
 IAN      MACRO  X                                                       MLD
          CHOP                                                           MLD
          VFD    12/7000B+X                                              MLD
          ENDM                                                           MLD
                                                                         MLD
 IANN     MACRO  X                                                       MLD
          VFD    12/7000B+X                                              MLD
          ENDM                                                           MLD
                                                                         MLD
          PURGMAC IJM                                                    MLD
 IJM      MACRO  X                                                       MLD
          CHOP                                                           MLD
          VFD    12/6500B                                                MLD
          VFD    12/X                                                    MLD
          ENDM                                                           MLD
                                                                         MLD
          PURGMAC OAM                                                    MLD
 OAM      MACRO  X                                                       MLD
          CHOP                                                           MLD
          VFD    12/7300B                                                MLD
          VFD    12/X                                                    MLD
          ENDM                                                           MLD
                                                                         MLD
          PURGMAC OAN                                                    MLD
 OAN      MACRO  X                                                       MLD
          CHOP                                                           MLD
          VFD    12/7200B+X                                              MLD
          ENDM                                                           MLD
          EJECT                                                          MLD
          ORG    C.PPFWA                                                 MLD
                                                                         MLD
**     STEP -01- SET CONTROL POINT ADDRESS AND D.PPONE.                  MLD
*                                                                        MLD
 SBP      BSS    0                                                       MLD
 SBP1     LDD    D.PPIR      READ SYSTEM IR                              MLD
          CRD    D.PPIRB                                                 MLD
          LDD    D.PPIRB+1   ISOLATE CONTROL POINT NUMBER                MLD
          LPN    L.CPNUM                                                 MLD
          SHN    7           FORM CONTROL POINT ADDRESS                  MLD
          STD    D.CPAD                                                  MLD
          LDN    0
          STD    DCNCNT      INITIALIZE DCN COUNTER 
          LDN    1                                                       MLD
          STD    D.PPONE                                                 MLD
                                                                         MLD
**     STEP -02- PAUSE TO SET D.RA AND D.FL.  ABORT IF ERROR FLAGS SET.  MLD
*                                                                        MLD
          IFEQ   NOS,1,1
          PAUSE 
  
          IFEQ   NOSBE,1,1
          RJM    R.RAFL 
          LDD    D.T1        TEST ERROR FLAGS                            MLD
          NJN    SBP2A
          RJM    CUA
          LDD    D.T0 
          ZJN    SBP1A       IF LEGAL USER ACCESS 
          LDC    IUERR
          LJM    ABORT       ILLEGAL USER ACCESS
                                                                         MLD
 SBP2A    UJN    SBP2 
  
**     STEP -03- READ  THE  DUMMY FET POINTED TO BY BYTE 4 OF THE INPUT  MLD
*                REGISTER AND ABORT IF BYTE 4 IS NOT 0002.               MLD
*                                                                        MLD
 SBP1A    BSSZ   0
          IFEQ   NOS+NOS4+NOS5,2
          LDN    CPUL 
          CRD    D.T0 
          LDD    D.T3 
          SHN    11B
          PJN    SBP1B       IF NOT CME MACHINE 
          ENDIF 
          IFEQ   NOS+NOS4+NOS5,1
          LDC    MABL 
          CRD    D.T0 
          LDD    D.T1 
          SHN    6
          MJN    SBP1B       IF NOT CME MACHINE 
          ENDIF 
          IFEQ   NOS+NOS4+NOS5,2
          LDC    2400B+D.T2 
          STM    RAC1C       BUILD LRD INST 
          LDC    4000B
          STD    D.RA        SET RA SIGN BIT
          ENDIF 
          IFEQ   NOS+NOS4+NOS5,1
          LDC    1600B+FLSW+1   BUILD ADDRESS FOR CME MACHINE 
          STM    RAC1D1 
          ENDIF 
          IFEQ   NOS+NOS4+NOS5,2
          LDC    3000B+D.T7 
          STM    TFL1A
          SBN    6
          STM    RAC1EA 
          STM    RAC1F       BUILD INSTRUCTION FOR CME MACHINE
          ENDIF 
 SBP1B    LDD    D.PPIRB+4
          STM    FET         SAVE DUMMY FET ADDRESS                      MLD
          RJM    TFL         FIND OUT IF IN RANGE                        MLD
          CRD    D.T0        READ THE FET                                MLD
          LDD    D.T0+4      CHECK FOR BYTE 4 = 0002                     MLD
          SBN    2                                                       MLD
          ZJN    SBP3        OK                                          MLD
 SBP2     LDC    PCERR       INITIALIZATION ERROR EXIT                   MLD
          LJM    ABORT                                                   MLD
                                                                         MLD
**     STEP -04- USE BYTE 2 OF THE FET TO  GENERATE  ALL  COMMUNICATION  MLD
*                ADDRESSES  BETWEEN THE DRIVER AND THE EXECUTIVE. ABORT  MLD
*                IF THE LAST ADDRESS IS NOT IN FL OR IS GREATER THAN 12  MLD
*                BITS.                                                   MLD
*                                                                        MLD
 SBP3     LDD    D.T0+2      GET ADDRESS OF COMM BLOCK                   MLD
          STM    P.SECURE    POINTER TO SECURITY WORD                    MLD
          ADN    L.SEC                                                   MLD
          ADN    L.IR                                                    MLD
          ADN    L.OR                                                    MLD
          STM    P.MB        POINTER TO MESSAGE BUFFER                   MLD
          ADN    L.MB                                                    MLD
          ADC    L.DB                                                    MLD
          ADN    L.PB                                                    MLD
          ADC    L.CB                                                    MLD
          ADC    L.SFB                                                   MLD
          STM    P.MOD       POINTER TO MODULE BUFFER                    MLD
          ADC    L.MOD                                                   MLD
          ADC    L.POMB                                                  MLD
          STM    P.SBPIR     POINTER TO SBP INPUT REGISTER               MLD
          ADN    L.SBPIR                                                 MLD
          STM    P.SBPOR     POINTER TO SBP OUTPUT REGISTER              MLD
          SHN    -12D                                                    MLD
          ZJN    SBP5        IF LAST ADDRESS IN 12 BIT FIELD             MLD
          LDC    PCERR                                                   MLD
          LJM    ABORT                                                   MLD
                                                                         MLD
 SBP4     LDC    SERR                                                    MLD
          LJM    ABORT       ABORT IF SECURITY/ ERROR                    MLD
                                                                         MLD
 SBP5     LDC    **                                                      MLD
 P.SBPOR  EQU    *-1                                                     MLD
          RJM    TFL         VERIFY THAT LAST ADDRESS IS IN FL           MLD
                                                                         MLD
**     STEP -05- ABORT IF THE SECURITY WORD AND VERSION NUMBER FROM THE  MLD
*                EXECUTIVE DOES NOT MATCH THE PPU DRIVER.                MLD
*                                                                        MLD
 SBP6     LDC    **                                                      MLD
 P.SECURE EQU    *-1                                                     MLD
          RJM    TFL                                                     MLD
          CRD    D.T0                                                    MLD
          LDN    D.T0        NOW TEST FOR A SECURITY WORD MATCH          MLD
          STD    D.T5                                                    MLD
 SBP7     LDM    SECURE-D.T0,D.T5                                        MLD
          LMI    D.T5        COMPARE WORDS                               MLD
          NJN    SBP4        NO, ABORT                                   MLD
          AOD    D.T5                                                    MLD
          SBN    D.T0+5                                                  MLD
          NJN    SBP7        NOT FINISHED                                MLD
                                                                         MLD
**     STEP -06- GET CHANNEL NUMBER, MODIFY CHANNEL  INSTRUCTIONS  THEN  MLD
*                STEP 7.                                                 MLD
*                                                                        MLD
          LDC    0                                                       MLD
 P.MB     EQU    *-1                                                     MLD
          RJM    TFL                                                     MLD
          CRD    D.T0        GET MESSAGE BUFFER WORD                     MLD
          LDD    D.T3                                                    MLD
          SHN    -6                                                      MLD
          LPN    40B
          STM    FLCIO       SAVE CIO PP FLAG 
          LDD    D.T3 
          SHN    -6 
          LPN    37B
          STD    D.T2        (D.T2) = I/O CHANNEL                        MLD
          ADN    40B                                                     MLD
          STM    CHAN        (CHAN) = I/O CHANNEL                        MLD
          LDC    TCHAN                                                   MLD
          STD    D.T0        (D.T0) = INDEX INTO CHANNEL TABLE           MLD
 SBP8     LDI    D.T0                                                    MLD
          ZJN    SBP8A       IF END OF CHANNEL TABLE                     MLD
          STD    D.T1                                                    MLD
          LDI    D.T1                                                    MLD
          LPC    7740B                                                   MLD
          ADD    D.T2        ADD CHANNEL NUMBER                          MLD
          STI    D.T1        STORE UPDATED CHANNEL CODE                  MLD
          AOD    D.T0        ADVANCE INDEX INTO CHANNEL TABLE            MLD
          UJN    SBP8                                                    MLD
                                                                         MLD
**     STEP -07- ABORT IF THE VERISON NUMBER OF THE MODULE  IN  WORD  3  MLD
*                BYTE  0  DOES  NOT  AGREE  WITH THE VERSION OF THE PPU  MLD
*                DRIVER AND PRODUCT OVERLAY.  SET THE STARTING LINE AND  MLD
*                STACK  ADDRESS  FROM  WORD  5 OF THE MODULE BUFFER AND  MLD
*                ABORT IF THEY ARE OUT OF LEGAL RANGE.                   MLD
*                                                                        MLD
 SBP8A    LDC    0                                                       MLD
 P.MOD    EQU    *-1                                                     MLD
          ADN    3                                                       MLD
          RJM    TFL                                                     MLD
          CRD    D.Z6        READ VERSION NUMBER OF THIS MODULE COMPILER MLD
          ADN    2                                                       MLD
          CRD    D.T3        READ LINE/ADDRESS DATA                      MLD
          LDD    D.Z6                                                    MLD
          LPC    3777B       MASK OFF LOCK BIT                           MLD
          STD    D.Z6                                                    MLD
          SBM    VERSION                                                 MLD
          ZJN    SBP9        IF MODULE/SBP VERSION MATCH                 MLD
          LDC    SERR                                                    MLD
          LJM    ABORT       IF NO MATCH                                 MLD
                                                                         MLD
**     STEP -08- SET  COMPLETE  BIT AND RECALL THE CPU EXECUTIVE.  THEN  MLD
*                FIND THE PPU SPEED AND MODIFY  TM  ACCOURDING  TO  THE  MLD
*                SPEED THEN STEP 9.                                      MLD
*                                                                        MLD
 SBP9     LDM    FET                                                     MLD
          RJM    TFL                                                     MLD
          CRD    D.T0        READ DUMMY FET                              MLD
          LDN    3                                                       MLD
          STD    D.T4                                                    MLD
          LDM    FET                                                     MLD
          RJM    TFL                                                     MLD
          CWD    D.T0        SEND COMPLETE BIT TO EXECUTIVE              MLD
                                                                         MLD
          IFEQ   NOS,1                                                   MLD
          LDN    RCPM                                                    MLD
          RJM    R.MTR       RECALL CPU                                  MLD
          ENDIF                                                          MLD
                                                                         MLD
          IFEQ   NOSBE,1,1                                               MLD
          RJM    R.TAFL      RETURN ACCESS TO FL                         MLD
                                                                         MLD
 SBP9A    IANN   14B                                                     MLD
          STD    D.T0                                                    MLD
          IANN   14B                                                     MLD
          SBD    D.T0                                                    MLD
          MJN    SBP9A                                                   MLD
          SBN    4                                                       MLD
          PJN    SBP10                                                   MLD
          LDC    60B                                                     MLD
          STM    TM          MODIFY FOR 2X PPU                           MLD
                                                                         MLD
**        STEP -09- PAUSE, GET SBP INPUT REGISTER, GOTO DROP IF IR       MLD
*                   BYTE 0 NON ZERO, ELSE STEP 10.                       MLD
*                                                                        MLD
 SBP10    LDC    ** 
 P.SBPIR  EQU    *-1                                                     MLD
          RJM    RACM        REQUEST ACCESS TO CENTRAL MEMORY 
          CRM    SBPREG,D.PPONE                                          MLD
          CRM    SBPREG+5,D.PPONE                                        MLD
          LDD    B0 
          NJN    SBP12       SKIP CHECKS IF STORAGE MOVE IN PROGRESS
          LDM    SBPREG                                                  MLD
          ZJN    SBP11       IF DROP FLAG NOT UP
          LJM    DROPP       IF DROP FLAG IS UP                          MLD
                                                                         MLD
**        STEP -10- IF CHANNEL ASSIGNED TO MLD GO TO STEP 11, ELSE STEP  MLD
*                   09.                                                  MLD
*                                                                        MLD
 SBP11    LDM    SBPREG+9 
          NJN    *+3         IF CHANNEL ASSIGNED TO MLD DRIVER
          LJM    SBP10       CHANNEL NOT ASSIGNED 
                                                                         MLD
**        STEP -11- IF  MB  CHANNEL  COMPARES  WITH DRIVER CHANNEL THEN  MLD
*                   STEP  12,  ELSE  ABORT  WITH  MSG (SBP MALET/DRIVER  MLD
*                   CHANNEL MIS-MATCH.).                                 MLD
*                                                                        MLD
          SBM    CHAN                                                    MLD
          ZJN    SBP12       IF CHANNEL COMPARES                         MLD
          LDC    MMERR       CHANNEL MLD/MALET NO COMPARE                MLD
          LJM    ABORT                                                   MLD
                                                                         MLD
**        STEP -12- IF CHANNEL IS INACTIVE THEN STEP 9, ELSE IF CHANNEL  MLD
*                   EMPTY THEN STEP 13 ELSE CHECK CHANNEL CONDITION FOR  MLD
*                   5 SEC.  IF NO CHANGE FROM ACTIVE AND FULL THEN STEP  MLD
*                   14, ELSE STEP 9.                                     MLD
*                                                                        MLD
SBP12     IJM    SBP10,** 
          LDN    0
          STD    D.T0                                                    MLD
          STD    D.T1                                                    MLD
          EJM    SBP15,**    IF CHANNEL EMPTY GOTO TEST FOR CHANGE       MLD
                                                                         MLD
 SBP13    EJM    SBP12,**    IF CHANNEL CHANGES STATE IT IS NOT HUNG
          EJM    SBP12,**    IF CHANNEL CHANGES STATE IT IS NOT HUNG
          EJM    SBP12,**    IF CHANNEL CHANGES STATE IT IS NOT HUNG
          EJM    SBP12,**    IF CHANNEL CHANGES STATE IT IS NOT HUNG
          EJM    SBP12,**    IF CHANNEL CHANGES STATE IT IS NOT HUNG
          AOD    D.T0 
          EJM    SBP12,**    IF CHANNEL CHANGES STATE IT IS NOT HUNG
          EJM    SBP12,**    IF CHANNEL CHANGES STATE IT IS NOT HUNG
          EJM    SBP12,**    IF CHANNEL CHANGES STATE IT IS NOT HUNG
          SHN    -12
          EJM    SBP12,**    IF CHANNEL CHANGES STATE IT IS NOT HUNG
          EJM    SBP12,**    IF CHANNEL CHANGES STATE IT IS NOT HUNG
          EJM    SBP12,**    IF CHANNEL CHANGES STATE IT IS NOT HUNG
          EJM    SBP12,**    IF CHANNEL CHANGES STATE IT IS NOT HUNG
          EJM    SBP12,**    IF CHANNEL CHANGES STATE IT IS NOT HUNG
          EJM    SBP12,**    IF CHANNEL CHANGES STATE IT IS NOT HUNG
          RAD    D.T1 
          EJM    SBP12,**    IF CHANNEL CHANGES STATE IT IS NOT HUNG
          EJM    SBP12,**    IF CHANNEL CHANGES STATE IT IS NOT HUNG
          SBM    TM 
          EJM    SBP12,**    IF CHANNEL CHANGES STATE IT IS NOT HUNG
          EJM    SBP12,**    IF CHANNEL CHANGES STATE IT IS NOT HUNG
          EJM    SBP12,**    IF CHANNEL CHANGES STATE IT IS NOT HUNG
          EJM    SBP12,**    IF CHANNEL CHANGES STATE IT IS NOT HUNG
          ZJN    SBP14       IF TIME EXPIRED                             MLD
          LJM    SBP13                                                   MLD
 SBP14    LJM    SBP16                                                   MLD
                                                                         MLD
**        STEP -13- TEST  CHANNEL FULL/INACTIVE FOR 5 SEC. IF NO CHANGE  MLD
*                   FROM EMPTY AND ACTIVE THEN STEP 14, ELSE STEP 9.     MLD
*                                                                        MLD
 SBP15    FJM    SBP12,**    IF CHANNEL CHANGES STATE IT IS NOT HUNG
          FJM    SBP12,**    IF CHANNEL CHANGES STATE IT IS NOT HUNG
          FJM    SBP12,**    IF CHANNEL CHANGES STATE IT IS NOT HUNG
          FJM    SBP12,**    IF CHANNEL CHANGES STATE IT IS NOT HUNG
          AOD    D.T0 
          IJM    SBP10,**    IF CHANNEL CHANGES STATE 
          FJM    SBP12,**    IF CHANNEL CHANGES STATE IT IS NOT HUNG
          FJM    SBP12,**    IF CHANNEL CHANGES STATE IT IS NOT HUNG
          SHN    -12D 
          IJM    SBP10,**    IF CHANNEL CHANGES STATE 
          FJM    SBP12,**    IF CHANNEL CHANGES STATE IT IS NOT HUNG
          FJM    SBP12,**    IF CHANNEL CHANGES STATE IT IS NOT HUNG
          IJM    SBP10,**    IF CHANNEL CHANGES STATE 
          FJM    SBP12,**    IF CHANNEL CHANGES STATE IT IS NOT HUNG
          FJM    SBP12,**    IF CHANNEL CHANGES STATE IT IS NOT HUNG
          FJM    SBP12,**    IF CHANNEL CHANGES STATE IT IS NOT HUNG
          RAD    D.T1 
          IJM    SBP10,**    IF CHANNEL CHANGES STATE 
          FJM    SBP12,**    IF CHANNEL CHANGES STATE IT IS NOT HUNG
          FJM    SBP12,**    IF CHANNEL CHANGES STATE IT IS NOT HUNG
          FJM    SBP12,**    IF CHANNEL CHANGES STATE IT IS NOT HUNG
          SBM    TM 
          IJM    SBP10,**    IF CHANNEL CHANGES STATE 
          ZJN    SBP16       IF TIME EXPIRED                             MLD
          LJM    SBP15                                                   MLD
                                                                         MLD
**        STEP -14- CHECK IF CHANNEL STILL ASSIGNED TO MLD IF  NO  THEN  MLD
*                   STEP  9,  ELSE  CHECK IF CORRECT CHANNEL IF NO THEN  MLD
*                   DROP,  ELSE  IF  CHANNEL  ACTIVE  THEN   DISCONNECT  MLD
*                   CHANNEL THEN STEP 9,  ELSE STEP 9.                   MLD
*                                                                        MLD
 SBP16    LDM    P.SBPOR
          RJM    RACM        REQUEST ACCESS TO CENTRAL MEMORY 
          CRM    SBPREG+5,D.PPONE                                        MLD
          LDM    SBPREG+9                                                MLD
          ZJN    SBP19       IF CHANNEL NOT ASSIGNED TO MLD DRIVER
          SBM    CHAN                                                    MLD
          ZJN    SBP17       IF CHANNEL STILL COMPARES                   MLD
          LDD    B0 
          NJN    SBP19       RETRY IF STORAGE MOVE IS IN PROGRESS 
          LDC    MMERR                                                   MLD
          LJM    ABORT                                                   MLD
                                                                         MLD
 SBP17    IJM    SBP10,00                                                MLD
 SBP18    DCN    40B         DISCONNECT CHANNEL                          MLD
          AOD    DCNCNT      INCREMENT NUMBER OF DCN-S PERFORMED
 SBP19    LJM    SBP10
          SPACE  4,15 
**        CD2 - CONVERT 2 OCTAL DIGITS TO DISPLAY CODE. 
* 
*         ENTRY -(A) = DIGITS TO BE CONVERTED 
* 
*         EXIT - (A) = CONVERSION 
* 
*         USES - T0.
* 
*         CALLS  NONE.
  
  
 C2DX     LJM    ** 
 C2D      EQU    *-1
          LPN    77B         UNPACK 
          STD    D.T0 
          SHN    3
          LMD    D.T0 
          SCN    70B
          ADC    2R00        CONVERT
          UJN    C2DX        RETURN 
          EJECT                                                          MLD
**        RACM - REQUEST ACCESS TO CENTRAL MEMORY 
* 
*         PERFORM THE NECESSARY STEPS TO INSURE THAT D.RA AND D.FL
*         ARE SET TO POINT TO OUR CURRENT AREA OF CENTRAL MEMORY. 
*         IF A STORAGE MOVE IS CURRENTLY IN PROGRESS, SET A FLAG TO 
*         INDICATE THAT MEMORY READS MAY NOT REFERENCE THE CORRECT
*         AREA OF MEMORY (NOTE THAT SBP, ONCE IN FULL EXECUTION 
*         ONLY WRITES TO CM USER AREA ON A DROP OR ABORT).
* 
*         ENTRY- (A) = RELATIVE ADDRESS IN CENTRAL MEMORY.
* 
*         EXIT - (A) = ABSOLUTE ADDRESS IN CENTRAL MEMORY 
*                (D.RA) = CURRENT REFERENCE ADDRESS 
*                (D.FL) = CURRENT FIELD LENGTH
*                (B0)   = STORAGE MOVE FLAG (NON-ZERO IF MOVING)
* 
*         USES - D.Z0,D.Z1,D.T0-D.T4,D.T7,D.RA,D.FL,B0
* 
*         CALLS- TFL
  
 RACMX    LJM    ** 
 RACM     EQU    *-1
          STD    D.T7        SAVE CM ADDRESS
          LDN    0
          STD    B0          CLEAR STORAGE MOVE IN PROGRESS FLAG
  
          IFEQ   NOS,1
          LDM    FLCIO
          ZJN    RACMAA      IF NOT CIO PP
          LDN    PPRL        SET MONITOR REQUEST FLAG 
          CRD    D.T0 
          LDD    D.PPOR 
          STD    D.T0 
          LDN    PPRL 
          CWD    D.T0 
 RACMAA   LDN    PRLM 
          STD    D.Z1 
          LDD    D.PPOR 
          CWD    D.Z1        SEND PAUSE FUNCTION TO MONITOR 
          LDC    CMCL 
          CRD    D.T0 
          LDD    D.T0 
          SBD    D.CPAD 
          NJN    RAC1        IF WE ARE NOT INVOLVED IN A STORAGE MOVE 
          ENDIF 
  
          IFEQ   NOSBE,1
          LDD    D.CPAD 
          ADN    W.CPLINK 
          CRD    D.T0 
          LDD    D.T0 
          LPN    1
          ZJN    RAC1        IF WE ARE NOT INVOLVED IN A STORAGE MOVE 
          ENDIF 
  
          AOD    B0          SET STORAGE MOVE FLAG
 RAC1     BSSZ   0
          IFEQ   NOS+NOS4+NOS5,1
          UJN    RAC1D
          ENDIF 
          IFEQ   NOS+NOS4+NOS5,2
          LDN    W.CPSTAT 
          SBN    26B
          ZJN    RAC1A       IF NOS R5
          ENDIF 
          LDD    D.CPAD 
          ADN    W.CPSTAT 
          CRD    D.T0        GET ERROR FLAGS, RA AND FL 
          LDD    D.T3 
          STD    D.RA        STORE CURRENT RA 
          LDD    D.T4 
          STD    D.FL        STORE CURRENT FL 
          UJN    RAC1E
          IFEQ   NOS,1
 RAC1A    LDD    D.CPAD 
          ADN    20B
 RAC1B    CRD    D.T0        GET RA AND FL
          ENDIF 
          IFEQ   NOS+NOS4+NOS5,2
          LDD    D.T3 
 RAC1C    STD    RA          STORE CURRENT RA 
*         LRD    D.T2        MODIFIED FOR CME MACHINE 
          ENDIF 
          IFEQ   NOS+NOS4+NOS5,1
 RAC1C    DATA   2411B       LRD INSTRUCTION FOR CME MACHINE
          LDD    D.T3 
          STD    D.RA        STORE CURRENT RA 
          ENDIF 
          IFEQ   NOS,1
          LDD    D.T4 
          STD    D.FL        STORE FL 
          LDD    D.CPAD 
          ADN    STSW 
          CRD    D.T0        GET ERROR FLAGS
          UJN    RAC1E
          ENDIF 
          IFEQ   NOS+NOS4+NOS5,1
 RAC1D    LDD    D.CPAD 
 RAC1D1   ADN    FLSW 
*         ADN    FLSW+1      MODIFIED FOR CME MACHINE 
          UJN    RAC1B
          ENDIF 
 RAC1E    LDD    D.T1 
          NJN    RAC1DA      ERROR FLAG SET 
          IFEQ   NOS+NOS4+NOS5,1
          LDD    D.T2 
          SHN    17 
          PJN    RAC1E1      NO ROLLOUT SET 
          LJM    DROPP1 
          ENDIF 
          UJN    RAC1E1 
  
 RAC1DA   LJM    RAC1H       ERROR FLAG SET 
 RAC1E1   BSSZ   0
          IFEQ   NOS,1
          LDM    ADRF 
          ZJN    RAC1FA 
          LJM    RAC2        EXIT 
 RAC1FA   LDC    RTCL 
          CRD    D.T0 
          LDD    D.T1 
          STM    ITIM 
 RAC1FA1  DATA   2510B
 RAC1F    LDD    D.RA 
*         LDD    D.T1        MODIFIED FOR CME MACHINE 
          SHN    6
          ADN    1
          CRD    D.T0        READ RA+1
          LDM    FLCIO
          ZJN    RAC1FA2     IF NOT CIO PP
          LDD    D.T1 
          SHN    -6 
          STD    D.T1 
          LDD    D.T0 
          SHN    6
          ADD    D.T1 
          LMC    032015B
          ZJN    RAC1FB      IF MLD CPM CALL
          UJN    RAC1FA3     EXIT 
 RAC1FA2  LDD    D.T1 
          SHN    -6 
          STD    D.T1 
          LDD    D.T0 
          SHN    6
          ADD    D.T1 
          LMC    151404B
          ZJN    RAC1FB      IF MLD CALL
 RAC1FA3  LJM    RAC2        EXIT 
 RAC1FB   LDD    D.CPAD 
          IFEQ   NOS+NOS4+NOS5,2,1
          ADN    JCIW 
          IFEQ   NOS+NOS4+NOS5,1,1
          ADN    STSW 
          CRD    D.T0        READ ROLLOUT INFO
          LDD    D.T2 
          SHN    17 
          MJN    RAC1EA1     ROLLOUT SET
          DATA   2510B
 RAC1EA   LDD    D.RA 
*         LDD    D.T1 
          SHN    6
          ADM    P.SBPIR
          ADN    3
          CRD    D.T0 
          LDD    D.T4 
 RAC1EA1  NJN    RAC1EB      TERMINAL INTERRUPT SET 
          LDC    RTCL 
          CRD    D.T0 
          LDD    D.T1 
          STM    STIM 
          SBM    ITIM 
          PJN    RAC1EA2     NOT CLOCK OVERFLOW 
          LJM    RAC1FA 
 RAC1EA2  SBN    2
          PJN    RAC1EB      2 SEC UP 
          LJM    RAC1FA1
 RAC1EB   LCN    0
          LJM    DROPPA      TELL MALET SBP ROLLED OUT
          ENDIF 
 RAC1G    PJN    RAC2        EXIT 
 RAC1H    LDM    ADRF 
          ZJN    RAC4        NOT CALLED BY ABORT OR DROPP 
          SBN    1
          ZJN    RAC3        CALLED BY ABORT
          LJM    DROPP1      CALLED BY DROPP
 RAC3     LJM    ABT2 
 RAC4     LJM    DROPP
  
 RAC2     LDD    D.T7 
          RJM    TFL         VERIFY CM ADDRESS IS WITHIN RANGE
          LJM    RACMX       EXIT 
**        TFL - TEST IF (A) WITHIN FL.                                   MLD
*                                                                        MLD
*         TEST ADDRESS IN THE A REGSITER FOR BEING WITHIN                MLD
*         FIELD LENGTH.                                                  MLD
*                                                                        MLD
*         ENTRY- (A) = RELATIVE ADDRESS IN CENTRAL MEMORY.               MLD
*                                                                        MLD
*         EXIT - (A) = (A) + D.RA IF IN RANGE.                           MLD
*                POST A DAYFILE MESSAGE AND DROP  PPU IF NOT IN RANGE.   MLD
*                                                                        MLD
*         USES - D.Z0.                                                   MLD
*                                                                        MLD
*         CALLS- END, R.DFM.                                             MLD
                                                                         MLD
 TFL1     DATA   2516B       SRD FOR CME MACHINE
 TFL1A    LDD    D.RA 
*         LDD    D.T7        MODIFIED FOR CME MACHINE 
          SHN    6                                                       MLD
          ADD    D.Z0                                                    MLD
                                                                         MLD
 TFLX     LJM    **                                                      MLD
 TFL      EQU    *-1                                                     MLD
          STD    D.Z0                                                    MLD
          SHN    -6                                                      MLD
          SBD    D.FL                                                    MLD
          MJN    TFL1        IF IN RANGE OF FL                           MLD
          LDN    3
          STM    ADRF        FLAG FOR FL ERROR
          LDC    FLERR                                                   MLD
 ABORT    STD    D.Z0 
          RJM    CKOR        CHECK OUTPUT REG BUSY
          LDD    D.Z0 
          RJM    R.DFM       SEND DAYFILE MESSAGE 
          LDN    0
          STM    SBPREG      TELL MALET SBP HAS DROPPED 
          LDM    ADRF 
          SBN    3
          ZJN    ABT2        FL ERROR GO TO IDLE
          LDN    1
          STM    ADRF        STORE ABORT FLAG 
          LDM    P.SBPIR
          RJM    RACM        REQUEST ACCESS TO CM 
          CWM    SBPREG,D.PPONE 
 ABT2     RJM    CKOR        CHECK OUTPUT REG BUSY
          LDN    M.ABORT
          RJM    R.MTR       SEND ABORT CONTROL POINT FUNCTION
          LJM    R.IDLE      GOTO IDLE PP 
  
          IFEQ   NOS,1,1
 DROPP    LDD    D.PPOR 
          IFEQ   NOSBE,1,2
 DROPP    LDD    D.PPIR 
          ADN    W.PPOR-W.PPIR
          CRD    D.T0 
          LDD    D.T0 
          NJN    DROPP       LOOP UNTIL PP OUTPUT REGISTER IS CLEAR 
          LDN    0
 DROPPA   STM    SBPREG      TELL MALET SBP HAS DROPPED 
          LDN    2
          STM    ADRF        DROPP FLAG 
          LDM    P.SBPIR
          RJM    RACM        REQUEST ACCESS TO CM 
          CWM    SBPREG,D.PPONE 
 DROPP1   LDD    DCNCNT 
          ZJN    DROPP2      NO DCN-S PERFORMED 
          RJM    C2D         CONVERT LOWER 2 DIGITS OF DCN COUNT
          STM    DCCNT+1
          LDD    DCNCNT 
          SHN    -6 
          RJM    C2D         CONVERT UPPER 2 DIGITS 
          STM    DCCNT
          LDM    SBP18
          LPN    37B
          RJM    C2D         CONVERT CHANNEL NUMBER 
          STM    DCCH 
          RJM    CKOR        CHECK OUTPUT REG BUSY
          LDC    DCERR
          RJM    R.DFM       ISSUE DAYFILE MESSAGE OF DCN-S 
 DROPP2   RJM    CKOR        CHECK OUTPUT REG BUSY
          LDN    M.DPP
          RJM    R.MTR                                                   MLD
          LJM    R.IDLE      GO TO IDLE                                  MLD
* 
 CKORX    LJM    ** 
 CKOR     EQU    *-1         CHECK PP OUTPUT REG BUSY 
          IFEQ   NOS,1,1
 CKOR1    LDD    D.PPOR 
          IFEQ   NOSBE,1,2
 CKOR1    LDD    D.PPIR 
          ADN    W.PPOR-W.PPIR
          CRD    D.T0 
          LDD    D.T0 
          NJN    CKOR1       IF OUTPUT REG BUSY 
          UJN    CKORX
                                                                         MLD
 ADRF     DATA   0           ABORT/DROP FLAG FOR RACM 
 ITIM     DATA   0           INITIAL TIME 
 STIM     DATA   0           RUNNING TIME 
 SBPREG   BSSZ   12B         STAND BY PPU INPUT/OUTPUT REGISTER WORDS    MLD
 SECURE   DATA   8HMALET     SECURITY TEST MATCHES SECURE AND VERSION    MLD
 VERSION  DATA   2           VERSION NUMBER CML LEVEL 142 
 FET      DATA   0                                                       MLD
 TM       DATA   30B         TIME WORD FOR 1X PPU                        MLD
*TM       DATA   60B         TIME WORD FOR 2X PPU                        MLD
 FLCIO    DATA   0           CIO PP FLAG
 CHAN     DATA   0           CHANNEL                                     MLD
 TCHAN    EQU    *           CHANNEL TABLE                               MLD
          HERE                                                           MLD
          DATA   0                                                       MLD
                                                                         MLD
 FLERR    DIS    ,*SBP ADDRESS NOT IN PROGRAM FL.*                       MLD
 PCERR    DIS    ,*SBP INITIALIZATION ERROR.*                            MLD
 DCERR    DIS    ,*AUTO DCN CH=00  0000 TIMES.* 
 DCCH     EQU    *-11B
 DCCNT    EQU    *-7
 SERR     DIS    ,*SBP MODULE VERSION ERROR.*                            MLD
 MPERR    DIS    ,*SBP MODULE HEADER ERROR.*                             MLD
 MMERR    DIS    ,*SBP MALET/DRIVER CHANNEL MIS-MATCH.*                  MLD
 IUERR    DIS    ,*SBP ILLEGAL USER ACCESS.*
  
          IFEQ   NOS,1,6
          BASE   O
 SSJ$     EQU    1
          XTEXT  COMSSSJ
          XTEXT  COMPCUA
          BASE   *
  
          IFEQ   NOSBE+NOSBE6,1,1 
 OPL1B    XTEXT  COMPCUA
*IF DEF,NOSBE6,1
*CALL COMPCUA 
  
          END                                                            MLD
