*DECK DB$STA
USETEXT RVRSCTX 
      PROC DB$STA;
      BEGIN 
 #
* *   DB$STA                                     PAGE 1 
* *   C O GIMBER                                 2-24-75
* 
* DC  PURPOSE 
* 
*     OUTPUT STATISTICS FOR THE AREA JUST RECOVERED OR RESTORED.
* 
* DC  ENTRY CONDITIONS
* 
*     AREA HAS JUST BEEN COMPLETELY PROCESSED.
* 
* DC  DESCRIPTION 
* 
 #
      CONTROL EJECT;
  
# EXTERNAL REFERENCES#
  
      XREF FUNC DB$CDIS C(10);         #CONVERT TO DISP CODE BLANK FILL#
      XREF PROC DB$EPRT;                #PRINT LINE TO OUTPUT FILE# 
  
# MESSAGES TO BE PRINTED# 
  
      ITEM WRTMSG C(36)="0       WRITES PROCESSED =          "; 
      ITEM DELMSG C(36)="        DELETES PROCESSED =         "; 
      ITEM REWMSG C(36)="        REWRITES PROCESSED =        "; 
      CONTROL EJECT;
 #
*     PRINT WRITES PROCESSED AND UPDATE TOTAL WRITES COUNT
 #
      C<28,8>WRTMSG = DB$CDIS(CNTWRITES,8,10," ");
      DB$EPRT(WRTMSG,36); 
      TOTLWRITES = TOTLWRITES+CNTWRITES;
      CNTWRITES = 0;
 #
*     PRINT DELETES PROCESSED AND UPDATE TOTAL DELTES COUNT 
 #
      C<28,8>DELMSG = DB$CDIS(CNTDELETES,8,10," "); 
      DB$EPRT(DELMSG,36); 
      TOTLDELETES = TOTLDELETES+CNTDELETES; 
      CNTDELETES = 0; 
 #
*     PRINT REWRITES PROCESSED AND UPDATE TOTAL REWRITES COUNT
 #
      C<28,8>REWMSG = DB$CDIS(CNTREWRITES,8,10," ");
      DB$EPRT(REWMSG,36); 
      TOTLREWRITES = TOTLREWRITES+CNTREWRITES;
      CNTREWRITES = 0;
      RETURN; 
      END 
      TERM; 
