*DECK DB$SSIN 
          IDENT  DB$SSIN
          SST 
          IPARAMS 
*#
* *   DB$SSIN                                    PAGE  1
* *   C O GIMBER                                 DATE  10/16/75 
* *   R L MCALLESTER         REMOVE SETMFL       DATE  01/23/80 
* 
* DC  PURPOSE 
* 
*     PUT A PROGRAM INTO SCP STATUS.
* 
* DC  ENTRY CONDITIONS
* 
*     PARAMETERS
* 
*         AREA TO RECEIVE INPUT REQUEST 
*         AREA SIZE 
* 
* DC  EXIT CONDITIONS 
* 
*     RA.SSC AND RA.SSID HAVE BEEN INITIALIZED. 
*     THE CALLSS MACRO HAS INITIATED SYSTEM CONTROL POINT STATUS. 
* 
* DC  CALLED ROUTINES 
* 
*     CALLSS MACRO
* 
* DC  CALLING ROUTINES
* 
*     DB$INT
* 
*#
          EJECT 
          LIST   F
          ENTRY  DB$SSIN
DB$SSIN   EQ   *+1S17 
          SA2    A1+1 
          SA1    X1          (X1) = INPUT REQUEST BUFFER ADDRESS
          SA2    X2          (X2) = SS READ COUNT 
          MX3    1
          LX3    35-59       SET THE VARIABLE FIELD BIT  (BIT 35) 
          BX1    X1+X3
          LX2    18D
          IX6    X1+X2
          SA6    RA.SSC      STORE RA.SSC--COUNT+INPUT REQUEST ADDRESS
          SA1    SSID 
          BX6    X1 
          SA6    RA.SSID     STORE RA.SSID--SUBSYSTEM PROG NAME AND ID
  
          CALLSS SS.SYS,SCPSTAT,R 
          EQ   DB$SSIN
  
SCPSTAT   CON    0
*#
* DC  EXTERNAL CONDITIONS 
* 
*     CDCS SYSTEM CONTROL POINT NAME IS CDCS2.
*     CDCS SYSTEM CONTROL POINT CODE IS 1.
* 
*     THESE CAN BE CHANGED BY SPECIFYING THE PC PARAMETER ON
*     THE COMPASS CONTROL CARD. 
*     I.E.  COMPASS,PC=$XXXX NNN$.
*       XXXX WILL BE THE SYSTEM CONTROL POINT NAME. 
*       NNN WILL BE THE SYSTEM CONTROL POINT CODE.
*     ONE AND ONLY ONE BLANK MUST SEPARATE NAME AND CODE. 
*     TO SPECIFY CODE IN OCTAL, TERMINATE NNN WITH A B. 
*     I.E. COMPASS,PC=$CDCSX 11B$.
* 
*     ON NOS, THE CODE VALUE MUST BE THE CDCS SUBSYSTEM QUEUE PRIORITY. 
*     I.E. COMPASS,PC=$CDCS 7766B$. 
* 
*#
*CALL SSIDDCLS
SSID      VFD    42/"LEN"_L"SS$NAME",18/"SS$CODE" 
          END 
