*DECK DB$SRRI 
USETEXT MD10CTX 
USETEXT CUGBATX 
USETEXT MDBCMTX 
USETEXT UTMPTTX 
      PROC DB$SRRI; 
      BEGIN 
 #
  *   DB$SRRI - REINITIALIZE TEMPORARY CELLS     PAGE  1
  *   M D SAXE                                   DATE  03/15/76 
  
  DC  PURPOSE 
  
      REINITIALIZE TEMPORARY CELLS PERTAINING TO AREA, SUBSCHEMA AND
      VERSIONS. 
  
  DC  CALLED ROUTINES 
  
      DB$NO - SYNTAX TABLE DRIVER -NO- RETURN 
  
  DC  CALLING ROUTINES
  
      DB$STD - SYNTAX TABLE DRIVER. 
  
  DC  NON-LOCAL VARIABLES 
  
      COMMON DECK - MD10CDCLS 
 #
      XDEF PROC DB$SR61;
      XDEF PROC DB$SR62;
      XDEF PROC DB$SR82;
  
      XREF PROC DB$NO;
  
  
      CONTROL EJECT;
      PROC DB$SR61; 
      BEGIN 
  
  
      ITEM I;                #SCRATCH CELL                             #
  
  
      AREANAM = " ";
  
#     ZERO OUT THE AREA PERMANENT FILE INFORMATION WITHIN MDPFINFO     #
  
      P<PUTENTRY> = LOC(MDPFWORD[FILETYPE"AREA"]);  # POSITION         #
      FOR I = 0 STEP 1
        UNTIL DFPFENTLEN - 1
      DO
        BEGIN 
        PUTINT[I] = 0;
        END 
      AREAFLAGS[0] = 0; 
      CHANGFLAGS[0] = 0;
      AREACHGF = FALSE; 
      VERSORD = 1;                 # DEFAULT VERSION IS MASTER         #
      ARNMLNW = 0;
      ARNMLEN = 0;
  
#     ZERO OUT THE INDEX PERMANENT FILE INFORMATION WITHIN MDPFINFO    #
  
      P<PUTENTRY> = LOC(MDPFWORD[FILETYPE"INDEX"]);  # POSITION        #
      FOR I = 0 STEP 1
        UNTIL DFPFENTLEN - 1
      DO
        BEGIN 
        PUTINT[I] = 0;
        END 
      DB$NO;
      END 
  
  
      PROC DB$SR62; 
      BEGIN 
      FILENAM = 0;
      SUBNAME = " ";
      DB$NO;
      END 
      CONTROL EJECT;
  
      PROC DB$SR82; 
      BEGIN 
 #
* *   DB$SRRI                                    PAGE  1
* *   DB$SR82 - REINITIALIZE CELLS FOR VERSION PROCESSING 
* *   R. M. PAPPE                                DATE  07/25/80 
* *   J. G. SERPA                                DATE  12/18/80 
* 
* DC  PURPOSE 
* 
*     INITIALIZE CELLS USED IN VERSION PROCESSING, AND ADD ENOUGH 
*     SPACE TO THE VERSION INFORMATION TABLE TO ACCOMODATE THE CURRENT
*     VERSION.
* 
* DC  ENTRY CONDITIONS
* 
*     AREACNT  - NUMBER OF ENTRIES IN THE AREA DIRECTORY TABLE
*     VERINFBP - ADDRESS OF THE BLOCK FOR THE VERSION INFORMATION TABLE 
* 
* DC  EXIT CONDITIONS 
* 
*     VERSNAM HAS BEEN RESET
*     ENOUGH SPACE HAS BEEN ADDED TO THE VERSION INFORMATION TABLE TO 
*     ACCOMMODATE THE CURRENT VERSION 
* 
* DC  CALLING ROUTINES
* 
*     DB$SNTX - SYNTAX CRACKER (SYNGEN) 
* 
* DC  CALLED ROUTINES 
# 
      XREF PROC DB$NO;             # SYNTAX TABLE DRIVER -NO- RETURN   #
      XREF PROC DB$UAWS;           # ADJUST WORK SPACE - CMM INTERFACE #
# 
* DC  NON-LOCAL VARIABLES MODIFIED
* 
*     VERSNAM IN THE (1,0) COMMON 
* 
* DC  DESCRIPTION 
* 
*     VERSNAM IS SET TO ALL BLANKS. THEN, DB$UAWS IS CALLED TO ADD
*     ENOUGH SPACE TO THE VERSION INFORMATION TABLE TO ACCOMODATE THE 
*     CURRENT VERSION.
*     EXIT IS TO DB$NO. 
* 
 #
  
      VERSNAM = " ";               # CLEAR VERSION NAME                #
      DB$UAWS(LOC(VERINFBP),AREACNT*DFMDVIEN);  # ADJUST SIZE OF VIT   #
      DB$NO;                       # EXIT                              #
  
      END 
      END 
      TERM; 
