*DECK DB$RDX1 
USETEXT   RQPARTX 
      PROC DB$RDX1(FIT,ARORD,PKAKORD);
      BEGIN 
 #
* *   DB$RDX1 - READ SEQUENTIAL ON INDEX FILE    PAGE  1
* *   READ SEQUENTIAL ON INDEX FILE OBJECT-TIME ROUTINE 
* *   E. P. JOHNSON                              DATE  10/25/79 
* * 
* 
* DC  PURPOSE 
* 
*     PARTIALLY FORMAT THE REQUEST PACKET 
*     FOR THE "READ SEQUENTIAL ON INDEX FILE" REQUEST.
* 
* 
* DC  ENTRY CONDITIONS
* 
*     PARAMETERS
# 
      ARRAY FIT;                       # FIT WITH REQUIRED PARAMETERS  #
*CALL FITDCLS 
      ITEM ARORD   I;                  # AREA ORDINAL                  #
      ITEM PKAKORD I;                  # ALTERNATE KEY ORDINAL         #
# 
* 
*     ASSUMPTIONS 
* 
*     NONE
* 
* DC  EXIT CONDITIONS 
* 
*     THE CALL IS MADE TO DB$RQST.
* 
*     IF CONTROL IS RETURNED FROM CDCS (WILL ALWAYS RETURN
*     FOR INTERACTIVE USER) THE FIT FIELDS FP,PTL AND KL
*     WILL BE RETURNED TO THE USER. 
* 
* DC  CALLING ROUTINES
* 
*     HOST LANGUAGE 
* 
* DC  CALLED ROUTINES 
# 
      XREF PROC DB$RQST;               # COMPLETE THE FORMATING OF THE #
                                       # REQUEST AND ISSUE "CALLSS"    #
                                       # TO CDCS.                      #
# 
* DC  NON-LOCAL VARIABLES MODIFIED
* 
*     REQUEST PACKET - ARRAY DB$RQBF
*     FIELDS FP,PTL AND KL OF THE USER FIT. 
* 
* DC  DESCRIPTION 
* 
*     - THE PARAMETERS FROM THE CALL (EXCEPT THE FIT) 
*       ARE STORED IN THE REQUEST PACKET. 
* 
*     - THE INDEX FILE PROCESSING FLAG IS SET IN THE REQUEST PACKET.
* 
*     - THE CALL IS MADE TO DB$RQST, TO COMPLETE
*       THE FORMATING OF THE REQUEST PACKET 
*       AND ISSUE "CALLSS" TO CDCS. 
* 
*     - THE FIT FIELDS FP,PTL AND KL ARE RETURNED TO USER.
* 
*     - TO AVOID HAVING THE INDEX FILE ONLY PROCESSING
*       FLAG (NDX) SET IN THE REQUEST PACKET WHEN AREA
*       FILE PROCESSING IS REQUESTED SET THE NDX FIELD TO FALSE.
* 
 #
  
# COMMON DECKS CDGDFDCLS AND RQPARDCLS ARE USED.                       #
  
  
      CONTROL EJECT;
  
# S T A R T   O F   D B $ R D X 1   E X E C U T A B L E   C O D E      #
  
  
# STORE THE CALL PARAMETERS AND THE INDEX FILE                         #
# PROCESSING FLAG IN THE REQUEST PACKET.                               #
  
      RQPARO   [0] = ARORD  ; 
      RQPPAKORD[0] = PKAKORD; 
      RQPFITNDX[0] = TRUE   ; 
  
# CALL DB$RQST.                                                        #
  
      DB$RQST(DFRX1,DFWCRDX1,FIT);
  
# RETURN THE FIT FIELDS FP, PTL AND KL TO THE USER.                    #
  
      FITFP [0] = RQPFITFP [0]; 
      FITPTL[0] = RQPFITPTL[0]; 
      FITKL [0] = RQPFITKL [0]; 
  
# TO AVOID HAVING THE INDEX FILE ONLY PROCESSING FLAG                  #
# (NDX) SET IN THE REQUEST PACKET WHEN AREA FILE PROCESSING            #
# IS REQUESTED SET THE NDX FIELD TO FALSE.                             #
  
      RQPFITNDX[0] = FALSE; 
      END 
      TERM
