*DECK DB$RCLL 
          IDENT  DB$RCLL
*#
* *   DB$RCLL--PUT CONTROL POINT INTO RECALL     PAGE  1
* *   C O GIMBER                                 DATE  10/20/75 
* *   R L MCALLESTER - DB$IREC INTERFACE         DATE  01/23/80 
* 
* DC  PURPOSE 
* 
*     ACCEPT INPUT REQUESTS AND PUT THE CONTROL POINT IN RECALL 
* 
* DC  ENTRY CONDITIONS
* 
*     PARAMETER 
*         ZERO -- A SINGLE PERIODIC RECALL
*         NON-ZERO -- REPEAT RECALL UNTIL THE COMPLETION BIT IS SET 
*         AT THE ADDRESS SPECIFIED BY THE PARAMETER.
* 
* DC  DESCRIPTION 
* 
*     IF THE PARAMETER IS ZERO, DO A SINGLE PERIODIC RECALL,
*     CALL DB$IREC TO ACCEPT NEW INPUT AND THEN RETURN. 
* 
*     IF THE PARAMETER IS NON-ZERO, IT IS THE ADDRESS OF A COMPLETION 
*     BIT.
*     REPEAT THE RECALL AND DB$IREC UNTIL THE COMPLETION BIT IS SET.
*#
          ENTRY  DB$RCLL
DB$RCLL   EQ   *+1S17 
          SA1    X1 
          BX6    X1 
          SA6    PARAM
          RJ     =XDB$IREC   ACCEPT INPUT REQUESTS
  
RCLL      RECALL             PERIODIC RECALL
          RJ     =XDB$IREC   ACCEPT INPUT REQUESTS
          SA1    PARAM
          ZR   X1,DB$RCLL    EXIT IF NO PARAMETER 
          SA1    X1 
          LX1    59 
          PL   X1,RCLL       LOOP UNTIL THE COMPLETION BIT IS SET 
          EQ   DB$RCLL
  
PARAM     CON    0           COMPLETION BIT ADDRESS 
          EJECT 
*#
* *   DB$RCLL                                    PAGE  1
* *   DB$RCLM -- PUT CONTROL POINT INTO RECALL
* *   R L MCALLESTER                             DATE  01/23/80 
* 
* DC  PURPOSE 
* 
*     ISSUE RECALL MACRO WITHOUT CALLING DB$IREC. 
*#
          ENTRY  DB$RCLM
DB$RCLM   EQ   *+1S17 
          RECALL
          EQ     DB$RCLM
          END 
