*DECK DB$MLDO 
          IDENT  DB$MLDO
DB$MLDO   TITLE  DB$MLDO - OVCAP LINKAGE TABLES FOR DBMSTRD 
          COMMENT OVCAP LINKAGE TABLES
          DATA   10L  DB$MLDO 
*#
* *   DB$MLDO - LOAD OVERLAY CAPSULE             PAGE  1
* *   BOB MCALLESTER                             DATE  07/30/84 
* 
* DC  PURPOSE 
* 
*     DB$MLDO PROVIDES THE LINK BETWEEN AN OVCAP ENTRY POINT AND ITS
*     CALLER. EVERY CALL TO AN OVCAP ENTRY POINT PASSES THROUGH THIS
*     ROUTINE. THIS ROUTINE IS RESPONSIBLE FOR THE LOADING OF THE 
*     OVCAP.
* 
* DC  ENTRY CONDITIONS
* 
* D   PARAMETERS
* 
*     NONE. 
* 
* D   ASSUMPTIONS 
* 
*     THIS ROUTINE WAS CALLED BY ONE OF THE ENTRY POINT DUMMY ROUTINES. 
*     THE RETURN LINKAGE TO THE ENTRY POINT CALLER IS IN THE WORD 
*     PRECEDING THE CALL TO THIS ROUTINE. 
*     THE WORD CONTAINING THE CALL TO THIS ROUTINE IS OF THE FORMAT:  
* 
*         VFD    30/RJ DB$MLDO,12/CAPORD,18/EPADDR
* 
*         CAPORD = ORDINAL OF OVCAP IN WHICH CALLED ENTRY POINT EXISTS. 
*         EPADDR = ADDRESS OF THE *ENTRY* TABLE ENTRY WHICH CONTAINS
*                  THE ADDRESS OF THE CALLED ENTRY POINT. 
* 
* DC  EXIT CONDITIONS 
* 
*     THE REQUIRED OVCAP IS IN CENTRAL MEMORY, AND THE OVCAP ENTRY
*     LOADED BIT IS SET.
* 
*     THE RETURN LINKAGE FROM THE DUMMY ROUTINE ENTRY POINT IS PLACED 
*     IN THE OVCAP ENTRY POINT AS ITS RETURN LINK.
* 
*     CONTROL IS TRANSFERRED TO THE OVCAP ENTRY POINT (+1). 
* 
* DC  CALLING ROUTINES
* 
*     EACH DUMMY ROUTINE (CREATED BY AN INCAP MACRO OCCURRENCE).
* 
* DC  CALLED ROUTINES 
* 
*     LOADOVC - LOAD AN OVCAP 
* 
* DC  CONTAINED ROUTINES
* 
          ENTRY  DB$MLDO     SUPERVISOR TO LOAD OVCAP FOR CALLED EP 
          ENTRY  DB$MULO     UNLOAD ALL OVCAPS
*                ERRABT      ISSUE DAYFILE MESSAGE AND ABORT FOR FDL ERR
*                LOADOVC     LOAD OVCAP 
* 
*     ALSO, EVERY OVCAP ENTRY POINT NAME - E.G., DB$XXXX - WILL HAVE
*     AN ENTRY POINT ROUTINE WITH A NAME SUCH AS DB.XXXX. 
* 
* DC  DESCRIPTION 
* 
* D   LOADING OVCAPS AND LINKAGE TO OVCAP ENTRY POINTS
* 
*     FOR EACH OVCAP ENTRY POINT DEFINED, A SMALL ROUTINE IS CREATED IN 
*     THIS MODULE. WHEN CALLED, THIS SMALL ROUTINE PASSES CONTROL TO
*     DB$MLDO, IDENTIFYING BOTH THE CALLED ENTRY POINT AND THE OVCAP
*     IN WHICH IT IS CONTAINED.  DB$MLDO WILL TRANSFER CONTROL TO THE 
*     OVCAP ENTRY POINT AFTER FIRST LOADING THE OVCAP, IF NECESSARY.
*     A PARAMETER LIST FOR THE OVCAP ROUTINE WILL BE PRESERVED
*     ACROSS THE CALL TO DB$MLDO. 
* 
*     THE RETURN LINKAGE FOR THE OVCAP ENTRY POINT IS GIVEN THE 
*     RETURN LINKAGE FROM ITS ASSOCIATED SMALL ROUTINE IN DB$MLDO.
*     THE OVCAP ENTRY POINT THEREFORE LOOKS AS IF IT WERE CALLED
*     DIRECTLY, AND NOT THROUGH THE SMALL ROUTINE AND DB$MLDO.
* 
*     THE OBJECTIVE OF THIS SCHEME IS TO FREE BOTH THE CALLER AND THE 
*     CALLEE FROM THE NEED TO KNOW ABOUT OVCAPS.
* 
* 
* D   INTERNAL TABLES - 
* 
*     INTERNAL TABLES ARE GENERATED BY THREE MACROS: OVCAP, INCAP,
*     AND PASSLOC. THESE MUST OCCUR IN THE FOLLOWING ORDER. 
*     AN OVCAP MACRO DECLARES THE NAME AND MAXIMUM AGE OF AN OVCAP. 
*     AN INCAP MACRO DECLARES AN ENTRY POINT TO BE IN A PARTICULAR
*     OVCAP.
*     THE PASSLOC MACRO TRIGGERS THE INSERTION OF AN ENTRY POINT LIST 
*     (LOADER ENTRY TABLE) WHICH WAS BUILT BY THE INCAP MACRO 
*     OCCURRENCES.
*     THE ENTRY POINT LIST IS GIVEN TO FDL SO WE CAN FIND THE LOCATION
*     OF A LOADED ENTRY POINT.  THERE IS ONE ENTRY IN THIS LIST FOR 
*     EACH INCAP MACRO OCCURRENCE.
* 
*     THE OVCAP LIST HOLDS THE NAME OF EACH OVCAP, AND OTHER BITS AND 
*     FIELDS CONCERNED WITH WHETHER OR NOT IT IS LOADED OR CAN BE 
*     UNLOADED.  THERE IS ONE ENTRY IN THIS LIST FOR EACH OVCAP 
*     MACRO OCCURRENCE. 
* 
*     THE SMALL DUMMY ROUTINE FOR EACH OVCAP ENTRY POINT IS GENERATED 
*     BY THE INCAP MACRO, AND FORMS A LINK BETWEEN THE ENTRY POINT
*     LIST AND THE OVCAP LIST.  EACH DUMMY ROUTINE HAS AN ENTRY POINT 
*     WHOSE NAME IS RELATED TO THE OVCAP ENTRY POINT NAME (DB$XXXX
*     BECOMES DB.XXXX).  EACH ROUTINE IDENTIFIES THE ASSOCIATED ENTRY 
*     POINT LIST ENTRY, THE ORDINAL OF THE OVCAP CONTAINING THE ENTRY 
*     POINT, AND WHETHER THIS ENTRY POINT ROUTINE IS INTERRUPTIBLE. 
*     EACH ROUTINE CONTAINS A CALL TO THE OVCAP SUPERVISOR, DB$MLDO,
*     WHICH WILL LOAD THE OVCAP, IF NECESSARY, AND THEN TRANSFER
*     CONTROL TO THE OVCAP ENTRY POINT WHOSE ADDRESS FDL PLACED 
*     IN THE ENTRY POINT LIST.
* 
* D   PROCEDURAL DESCRIPTION
* 
*     LOCATE THE OVCAP ENTRY INDICATED BY THE OVCAP ORDINAL.
*     LOCATE ENTRY POINT ADDRESS. 
*     GET SUBROUTINE RETURN LINKAGE FROM DUMMY ROUTINE ENTRY POINT. 
*     PUT RETURN LINKAGE IN OVCAP ENTRY POINT (CODE MODIFICATION).
*     VOID INSTRUCTION STACK. 
*     TRANSFER CONTROL TO OVCAP ENTRY POINT (+1). 
*#
  
 DB$MLDO  JP   *+1S17        ENTRY/EXIT 
          SA2    DB$MLDO
          SB1    1
          LX2    30D
          SA5    X2-1        (X5) = +1 WORD OF DUMMY ROUTINE
          SB3    X5          (B3) = ADDRESS OF ENTRY POINT LIST ENTRY 
          SA0    A5          (A0) = ADDRESS OF +1 WORD OF DUMMY ROUTINE 
          MX0    -6 
          LX5    0-18        POSITION BIT 18 IN BIT 0 
          BX3    -X0*X5      (X3) = OVCAP ORDINAL   = OFFSET IN LIST
          SB2    OVCAP00+X3  (B2) = ADDRESS OF OVCAP ENTRY
          SA2    B2          (X2) = OVCAP ENTRY 
          SX3    X2 
          MI   X3,MLD2       IF OVCAP ALREADY LOADED
  
          RJ     LOADOVC     LOAD THE OVCAP 
          SA2    B2          (X2) = +0 WORD OF OVCAP ENTRY
          MX6    1
          LX6    18 
          BX6    X2+X6       MERGE IN LOADED FLAG 
          SA6    A2          REPLACE +0 WORD OF OVCAP ENTRY 
  
 MLD2     SA2    B3          (X2) = ENTRY POINT LIST ENTRY
          SB7    X2+B1       (B7) = OVCAP ENTRY POINT ADDRESS (+1)
          SA5    A0-B1       (X5) = DUMMY ROUTINE RETURN LINKAGE
          BX6    X5 
          SA6    B7-B1       PLACE RETURN LINKAGE IN OVCAP ENTRY POINT
          RJ     VOIDSTK     VOID INSTRUCTION STACK (CAUSED BY AN RJ) 
 VOIDSTK  BSS    1
          JP     B7          TRANSFER CONTROL TO OVCAP ENTRY POINT (+1) 
 DB$MULO  SPACE  4,10 
*#
* *   DB$MLDO                                    PAGE  1
* *   DB$MULO - UNLOAD OVCAPS 
* *   BOB MCALLESTER                             DATE  07/30/84 
* 
* DC  PURPOSE 
* 
*     DB$MULO PERFORMS THE UNLOAD OF ALL OVCAPS.
* 
* DC  ENTRY CONDITIONS
* 
* D   PARAMETERS
* 
*     NONE
* 
* D   ASSUMPTIONS 
* 
*     OVCAP LIST TERMINATED BY A ZERO WORD. 
* 
* DC  EXIT CONDITIONS 
* 
*     ALL OVCAPS HAV BEEN UNLOADED. 
* 
* DC  CALLING ROUTINES
* 
*     DBMSTRD - MAIN PROCEDURE
* 
* DC  CALLED ROUTINES 
* 
*     FDL.UOC - UNLOAD OVCAP
* 
* DC  NON-LOCAL VARIABLES MODIFIED
* 
*     NONE. 
* 
* DC  DESCRIPTION 
* 
*     SCAN THE OVCAP LIST SEARCHING FOR OVCAPS THAT ARE LOADED. 
*     UNLOAD EACH LOADED OVCAP. 
*     RETURN TO CALLER WHEN A ZERO WORD IS FOUND TO SIGNIFY THE END 
*     OF THE OVCAP LIST.
*#
  
 DB$MULO  JP   *+1S17D       ENTRY/EXIT 
          SB3    OVCAP00     (B3) = FWA OF FIRST OVCAP LIST ENTRY 
 OUOC2    SA3    B3          (X3) = OVCAP LIST ENTRY
          SB3    B3+1        (B3) = ADDRESS OF NEXT OVCAP ENTRY 
          SX4    X3          SIGN EXTEND THE LOADED BIT 
          ZR   X3,DB$MULO    IF NO MORE OVCAPS IN LIST
          PL   X4,OUOC2      IF THIS OVCAP IS NOT LOADED
          MX2    42D
          BX2    X2*X3       (X2) = OVCAP NAME
          SX4    PASSLIST    (X4) = FWA OF LIST OF PASSLOC TABLES 
          BX6    X2 
          SA6    A3          REPLACE +0 WORD OF OVCAP ENTRY 
          SA1    GROUP       (X1) = GROUP NAME (FOR FDL TRACE INFO) 
          RJ     =XFDL.UOC   UNLOAD OVCAP 
          EQ   OUOC2
 ERRABT   SPACE  4,10 
*#
* *   DB$MLDO                                    PAGE  1
* *   ERRABT - MESSAGE AND ABORT ON FDL ERROR 
* *   C. F. RICHARDS                             DATE  10/16/80 
* 
* DC  PURPOSE 
* 
*     DIAGNOSE FDL ERRORS ENCOUNTERED TRYING TO LOAD AN OVCAP, THEN 
*     ABORT.
* 
* DC  ENTRY CONDITIONS
* 
* D   PARAMETERS
* 
*     (X6) = FDL ERROR CODE 
* 
* D   ASSUMPTIONS 
* 
*     (ERRMSG+3) = OVCAP NAME LEFT-JUSTIFIED WITH ZERO-FILL 
* 
* DC  EXIT CONDITIONS 
* 
*     CDCS EXECUTION TERMINATED BY ABORT MACRO. 
* 
* DC  CALLING ROUTINES
* 
*     LOADOVC 
* 
* DC  CALLED ROUTINES 
* 
*     ABORT MACRO 
*     MESSAGE MACRO 
* 
* DC  NON-LOCAL VARIABLES MODIFIED
* 
*     NONE. 
* 
* DC  DESCRIPTION 
* 
*     CONVERT THE ERROR CODE TO DISPLAY CODE AND INSERT IT INTO THE 
*     ERROR MESSAGE. ISSUE THE ERROR MESSAGE TO THE DAYFILE.
*     ABORT CDCS SINCE ALL FDL ERRORS ARE EVIDENCE OF INSTALLATION
*     OR BUILD PROBLEMS.
*#
  
 ERRABT   BSS    0
          MX0    -3 
          BX7    -X0*X6      (X7) = 57/0,3/DIGIT2 
          LX0    3
          BX6    -X0*X6      (X6) = 54/0,3/DIGIT1,3/0 
          LX6    3
          BX6    X6+X7       (X6) = 48/0,6/DIGIT1,6/DIGIT2
          LX6    6
          MX0    -18
          SX6    X6+3R00B    CONVERT TO OCTAL D.C. (BEWARE OF SIGN EXT.)
          BX6    -X0*X6      (X6) = 42/0,18/*77B* 
          SA1    ERRMSG+1 
          BX1    X0*X1       (X1) = 42/*R CODE *,18/0 
          BX6    X6+X1       (X6) = 60/*R CODE 77B* 
          SA6    A1          PLACE ERROR CODE WORD IN MESSAGE TEXT
          MESSAGE ERRMSG     ISSUE DAYFILE MESSAGE
          ABORT              ABORT CDCS 
 LOADOVC  SPACE  4,10 
*#
* *   DB$MLDO                                    PAGE  1
* *   LOADOVC - LOAD OVCAP
* *   C. F. RICHARDS                             DATE  10/16/80 
* 
* DC  PURPOSE 
* 
*     LOADOVC ATTEMPTS TO LOAD A SPECIFIED CDCS OVCAP.
* 
* DC  ENTRY CONDITIONS
* 
* D   PARAMETERS
* 
*     (X2) = OVCAP NAME, LEFT-JUSTIFIED 
* 
* D   ASSUMPTIONS 
* 
*     THE OVCAP IS NOT ALREADY LOADED.
* 
* DC  EXIT CONDITIONS 
* 
* D   NORMAL
* 
*     THE OVCAP HAS BEEN LOADED INTO CENTRAL MEMORY 
* 
*     REGISTERS PRESERVED - A0, A1, X0, X5, B2, B3. 
*     (B1) = 1. 
* 
* D   ABNORMAL
* 
*     EXIT TO ERRABT IF AN FDL ERROR CODE WAS RECEIVED. 
* 
* DC  CALLING ROUTINES
* 
*     DB$OLLO - LOAD AND LOCK AN OVCAP. 
*     DB$MLDO - SUPERVISOR LOAD OF A CALLED OVCAP.
* 
* DC  CALLED ROUTINES 
* 
*     ERRABT - DIAGNOSE FDL ERROR AND ABORT.
*     FDL.LOC - FDL ROUTINE TO LOAD AN OVCAP. 
* 
* DC  NON-LOCAL VARIABLES MODIFIED
* 
*     NONE. 
* 
* DC  DESCRIPTION 
* 
*     SAVE PARAMETER LIST POINTER.
*     SETUP REGISTERS AS PARAMETERS FOR FDL.LOC.
*     STORE OVCAP NAME IN ERROR MESSAGE TEXT. 
*     CALL FDL.LOC TO LOAD THE OVCAP. 
*     RESTORE PARAMETER LIST POINTER. 
*     IF AN FDL ERROR CODE WAS RECEIVED, EXIT TO ERRABT.
*     RETURN. 
*#
  
 LOADOVC  JP     *+1S17D     ENTRY/EXIT 
          SX6    A1 
          SA6    LOADOVCA    SAVE PARAMETER LIST POINTER
          MX6    -18
          BX2    X6*X2       (X2) = 42/OVCAP NAME,18/0
          BX7    X2 
          SA7    ERRMSG+3    SAVE OVCAP NAME IN ERROR MESSAGE TEXT
          SA1    GROUP       (X1) = 42/OVCAP GROUP NAME, 18/0 
          SX3    LIBLIST     (X3) = ADDRESS OF LIST OF LIBRARIES
          SX4    PASSLIST    (X4) = FWA OF LIST OF PASSLOC TABLES.
          RJ     =XFDL.LOC
          SA1    LOADOVCA 
          SA1    X1          RESTORE PARAMETER LIST POINTER 
          NZ     X6,ERRABT   IF AN FDL ERROR CODE RECEIVED
          EQ     LOADOVC     RETURN 
  
 LOADOVCA BSS    1           CONTAINS PARAMETER LIST POINTER
 INCAP    SPACE  4,10 
***       INCAP - MACRO FOR DEFINING ENTRY POINTS IN OVCAPS.
* 
* ENTRY   INCAP  CAP
* 
*         ENTRY   = ENTRY POINT NAME WHICH OCCURS IN OVCAP. 
*         CAP     = OVCAP NAME AND ENTRY IN OVCAP LIST. 
* 
*              THIS MACRO IS USED TO DEFINE ENTRY POINTS WHICH WILL CALL
*         THE SUPERVISOR TO LOAD THE OVCAP IF NOT ALREADY LOADED AND
*         TO JUMP TO THE INDICATED ENTRY POINT.  THE ENTRY POINT NAMES
*         MUST BE IN ALPHANUMERIC ORDER BECAUSE A PASSLOC TABLE BODY
*         IS GENERATED IN THE REMOTE TABLE *PASSLOC* AND THE FDL
*         RESIDENT REQUIRES PASSLOCS TO BE IN INCREASING ORDER.  THE
*         OVCAP ENTRY POINT NAME CANNOT BE USED, OTHERWISE LOADER 
*         WOULD GENERATE DUPLICATE ENTRY POINT DIAGNOSTICS SO THE 
*         ENTRY POINT NAME"S THIRD CHARACTER IS A PERIOD INSTEAD OF A 
*         DOLLAR.   A SUBST *DB$ENTRY BECOMES DB.ENTRY*  MUST BE
*         USED IN THE (0,0) OVERLAY (SEE SKELGEN).  THE ENTRY POINT MUST
*         ALSO BE REINSTATED IN THE OVCAP BY USING *ENTRY BECOMES 
*         ENTRY* WITHIN THE OVCAP DEFINITION. 
*         THE OVCAP ORDINAL IS CALCULATED FROM THE LOCATION OF THE
*         OVCAP ENTRY. THE SET OF CAPORD BELOW INDICATES THE ASSUMED
*         SYMBOL OF THE OVCAP LIST FWA AS WELL AS THE SIZE OF EACH
*         ENTRY.
  
          PURGMAC INCAP 
  
          MACRO  INCAP,ENT,CAP,NONINT 
          NOREF  CAPORD 
          NOREF  NI 
 '?PRFX   MICRO  1,3, ENT 
 '?SUFX   MICRO  4,4, ENT 
* 
          IFC    NE, "'?PRFX" DB$ ,1
          ERR    "'?PRFX"_"'?SUFX" - ENTRY POINT MUST BEGIN WITH DB$
* 
 CAPORD   SET    ._CAP-OVCAP00
* 
          ENTRY  DB._"'?SUFX" 
 DB._"'?SUFX" JP  *+1S17D 
          RJ     =XDB$MLDO
 -        VFD    12/CAPORD,18/#_ENT 
* 
 #_ENT    PASS   "ENTPRFX"_"'?SUFX" 
          ENDM
 OVCAP    SPACE  4,10 
***       OVCAP - MACRO FOR DEFINING AN OVCAP ENTRY.
* 
*         OVCAP  NAME 
* 
*         NAME = NAME OF AN OVCAP TO BE INSERTED IN AN OVCAP LIST.
* 
*             THIS MACRO DEFINES THE ENTRIES IN THE OVCAP LIST FOR
*         DBMSTRD.
* 
*         42/0LCAPNAME,1/LOADED,17/UNUSED 
* 
*         THE ENTRY WILL BE USED BY THE *INCAP* MACRO.
  
          PURGMAC OVCAP 
  
 OVCAP    MACRO  NAME,MAXAGE
 ._NAME   VFD    42/0L_NAME,18/0
          ENDM
 PASS     SPACE  4,10 
***       PASS - MACRO FOR DEFINING PASSLOC ENTRY POINT ENTRIES.
* 
* SYM     PASS   ENTRY,X
* 
*         SYM      = OPTIONAL SYMBOL DEFINING THE LOCATION OF THIS
*                    PASSLOC TABLE. 
*         ENTRY    = ENTRY POINT/EXTERNAL NAME TO BE ADDED TO A PASSLOC 
*                    LIST.
*         X        = IF PRESENT INDICATES THE NAME IS AN EXTERNAL 
*                    RATHER THAN AN ENTRY POINT PASSLOC TABLE ENTRY.
* 
*         ENTRY POINTS AND EXTERNALS CAN BE ADDED TO A PASSLOC
*         TABLE BY USING THIS MACRO.  THE PASSLOC HEADER MUST BE
*         DEFINED BY USING THE *PASSLOC* MACRO. 
  
          PURGMAC PASS
  
          MACRO  PASS,SYM,ENT,X 
          IFC    LE, ENT "PLOCNAM" ,1 
          ERR    ENT - OUT OF ORDER IN PASSLOC TABLE. 
 PLOCNAM  MICRO  1,, ENT
 PLOCWC   SET    PLOCWC+1 
 NOX      IFC    EQ, X
 PASSLOC  RMT 
 SYM      VFD    42/0L_ENT,18/**
          RMT 
 NOX      ELSE
 PASSLOC  RMT 
 SYM      VFD    42/0L_ENT,18/=X_ENT
          RMT 
 NOX      ENDIF 
          ENDM
 PASSLOC  SPACE  4,10 
***       PASSLOC - MACRO FOR DEFINING A PASSLOC TABLE. 
* 
*         PASSLOC 
* 
*              THIS MACRO FLUSHES ALL THE PREVIOUSLY DEFINED PASSLOC
*         TABLE ENTRIES (SEE *PASS* MACRO). 
  
          PURGMAC PASSLOC 
  
 PASSLOC  MACRO 
          IFEQ   PLOCWC,0,1 
          ERR    EMPTY PASSLOC TABLE. 
          VFD    12/0021B,12/PLOCWC,36/0  *ENTRY* TABLE HEADER
 PASSLOC  HERE
 PLOCWC   SET    0
 PLOCNAM  MICRO  1,,
          ENDM
OVCAPS    SPACE  4,10 
**        OVCAP LOADING GLOBAL DEFINITIONS. 
  
  
 ERRMSG   DATA   C*  FDL ERROR CODE 77B LOADING -.......* 
 GROUP    DATA   C*DBMSTRD*  GROUP NAME OF OVCAPS 
 LIBLIST  VFD    60/0LDMSLIB OVCAP LIBRARY IF DBMSTRD LOADED FROM SYSTEM
          CON    0                 END OF LIST
 PASSLIST CON    ENTPL00     ENTRY POINT PASSLOC LIST 
          CON    0           END OF LIST
  
 PLOCNAM  MICRO  1,,         LAST PASSLOC NAME USED 
 PLOCWC   SET    0           PASSLOC TABLE WORD COUNT 
  
*         FOR CDCS THE OVCAP ENTRY POINT PREFIXES ARE DB$ 
  
 ENTPRFX  MICRO  1,3, DB$ 
          SPACE  4,10 
**        OVCAP00 - OVERLAY CAPSULES FOR DBMSTRD
* 
*         THE FOLLOWING IS A LIST OF THE OVCAPS DEFINED FOR DBMSTRD 
*         THE SYMBOL *OVCAP00* REPRESENTS THE FWA OF THE LIST OF OVCAP
*         MACRO OCCURRENCES. A ZERO WORD TERMINATES THE LIST. 
  
 OVCAP00  BSS    0
          OVCAP  DB$DIAG           DIAGNOSTIC MESSAGES (OVERLAY 1,0)
  
          CON    0           END OF OVCAP LIST
          SPACE  4,10 
**        OVCAP ENTRY POINTS. 
* 
*              THESE ENTRIES MUST BE IN ALPHANUMERIC ORDER FOR FDL. 
  
  
 DB$DIAG  INCAP  DB$DIAG
          SPACE  4,10 
**        ENTRY POINT PASSLOC LIST
  
  
 ENTPL00  PASSLOC            BUILD PASSLOC TABLES 
  
          END 
