*DECK DB$MF 
          IDENT  DB$MF
*#
* *   DB$MF--CMM FIXED POS INTERFACE ROUTINES    PAGE  1
* *   C O GIMBER                                 DATE 10/6/75 
* 
* DC  PURPOSE 
* 
*     TO INTERFACE WITH CMM FIXED POSITION ROUTINES.
* 
* DC  ENTRY CONDITIONS, EXIT CONDITIONS, AND CALLED ROUTINES. 
*#
  
*#
* 
* D   DB$MFA(SIZE,FWA) -- ALLOCATE FIXED POSITION FIXED SIZE BLOCK= 
* 
*         SIZE = SIZE OF BLOCK. 
*         FWA = RETURNED FWA OF BLOCK.
*         CALLS CMM.ALF.
*#
          ENTRY  DB$MFA 
DB$MFA    EQ   *+1S17 
          SA3    A1+1        (X3) = ADDRESS OF FWA WORD 
          SA2    X1          (X2) = BLOCK SIZE
          BX6    X3 
          SA6    FWACFA      SAVE FWA ADDRESS 
          MX3    0           (X3) = SIZE CODE 
          RJ   =XCMM.ALF
          SA2    FWACFA 
          BX6    X1 
          SA6    X2          RETURN FWA OF BLOCK
          EQ   DB$MFA 
  
FWACFA    CON    0           SAVED FWA ADDRESS
  
*#
* 
* D   DB$MFF(FWA) -- FREE FIXED POSITION FIXED SIZE BLOCK.
* 
*         FWA = FWA BLOCK TO BE FREED 
*         CALLS CMM.FRF 
*#
DB$MFF    EQ   *+1S17 
          ENTRY  DB$MFF 
          SB2    X1          (B2) = SAVE ADDRESS OF BLOCK POINTER 
          SA1    X1          (X1) = FWA BLOCK TO BE FREED 
          RJ   =XCMM.FRF
          SX6    -65535      NULL POINTER (600000 OCTAL)
          SA6    B2          NULL VALUE TO THE OLD POINTER. 
          EQ   DB$MFF 
          END 
