*DECK DB$JLRP 
USETEXT JLPCMTX 
USETEXT CDCSCTX 
      PROC DB$JLRP(JBID,USID,RVPTEXT);
  BEGIN 
 #
* *   DB$JLRP                                    PAGE  1
* *   FORMAT "RECOVERY POINT" JOURNAL LOG RECORD
* *   W P CEAGLIO                                DATE  1/12/76
* *   A W LO (REVISION)                          DATE 10/ 1/76
* * 
* DC  PURPOSE 
*     FORMAT THE PERTINENT PORTION OF THE JOURNAL LOG RECORD
* 
* DC  ENTRY CONDITIONS
* 
*     PARAMETERS
# 
      ITEM JBID     C(07);         # JOB ID                            #
      ITEM USID     C(10);         # USER ID                           #
      ITEM RVPTEXT  C(30);         # RECOVERY POINT TEXT               #
# 
* 
*     SUMMARY OF SOURCE OF PARAMETERS 
* 
*           RECOVERY PT NBR  CDCS COMMON
*           RECOVERY PT TEXT PARAMETER PASSED FROM CALLING SEQUENCE 
*           JOB ID           PARAMETER PASSED FROM CALLING SEQUENCE 
*           USER ID          PARAMETER PASSED FROM CALLING SEQUENCE 
* 
* DC  EXIT CONDITIONS 
* 
*     NORMAL--A "RECOVERY POINT" RECORD HAS BEEN LOGGED 
* 
*     ABNORMAL--A CRM ERROR OCCURRED IN WRITING TO THE LOG FILE 
* 
* DC  CALLING ROUTINES
* 
*     DB$RUPD    RECOVERY RESTORE UPDATE ROUTINE
* 
* DC  CALLED ROUTINES 
* 
*     DB$JLOG    JOURNAL LOG I/O INTERFACE
* 
* DC  NON-LOCAL VARIABLES 
* 
*     CDCS COMMON (CDCSCOMMN) 
*     JOURNAL LOG PROCESSOR COMMON (JLPCMDCLS)
*     RUN-UNIT COMMAND BLOCK (RCB)
* 
* DC  DESCRIPTION 
* 
*     1. COMPLETE THE REQUEST TYPE AND DIRECTIVE CODE ENTRIES IN THE
*        HEADER. SET THE NUMBER OF CHARACTERS OF PADDING TO ZERO. 
*     2. STORE THE CONVERTED RECOVERY POINT NUMBER AND THE USER 
*        RECOVERY TEXT IN THE RECORD. 
*     3. SETUP THE SIZE OF THE "RECOVERY POINT" RECORD. 
*     4. CALL DB$JLOG TO COMPLETE AND OUTPUT THE RECORD.
*     5. RETURN.
* 
 #
  
#  LOCAL ITEMS                                                         #
  
      ITEM VERSION       C(07);    # VERSION NAME - ALWAYS BLANK       #
# EXTERNAL REFERENCES                                                  #
  
      XREF PROC DB$JLOG;                # OUTPUT JOURNAL LOG RECORD    #
      XREF FUNC DB$CDIS C(10);          # CONVERT BINARY TO DISPLAY    #
      CONTROL EJECT;
  
# START OF "DB$JLRP" EXECUTABLE CODE                                   #
  
      IF NOT SASCJAFG [SALX]  THEN      # RETURN IF NO JOURNAL LOGGING #
        BEGIN 
        RETURN; 
        END 
  
  
# FORMAT PERTINENT ENTRIES IN THE LOG RECORD HEADER                    #
  
      JLHDTYPE [0] = DFJLRQRP;          # REQUEST TYPE = "RECOVERY PT" #
      JLHDDIRC [0] = DFJLDCZ;           # DIRECTIVE CODE = OTHER       #
      JLHDPAD  [0] = DFJLPAD0;          # PADDING = "0"                #
  
# FORMAT LOG RECORD TRAILER                                            #
  
      JLRPNUMB [0] = DB$CDIS(RPNUM,10,10,"0");
                                        # CONVERTED RECOVERY PT NBR    #
      JLRPUTXT[0] = RVPTEXT;
  
# COMPLETE AND OUTPUT LOG RECORD                                       #
  
      TRLRLEN = 0;
      PARLEN = DFJLSZRP;                # SET SIZE OF "RECOVERY PT REC #
      VERSION = "       ";         # BLANK NAME USED FOR JLOG CALL     #
      DB$JLOG(0,JBID,USID,VERSION); 
  END 
      TERM
