*DECK,DB$IORE 
          IDENT  DB$IORE
          TITLE  DB$IORE  -  READ WITHOUT RECALL
          COMMENT  READ A FILE WITHOUT RECALL 
          DATA   10L  DB$IORD 
*#
* *   DB$IORE                                    PAGE  1
* *   DB$IOBR - BACK-SPACE RECORD 
* *   BOB MCALLESTER                             DATE  11/15/84 
* 
* DC   PURPOSE
* 
*     BACK SPACE ONE LOGICAL RECORD 
* 
* DC   ENTRY CONDITIONS 
* 
*     PARAMETERS
* 
*     LOC(FET)
* 
* DC  DESCRIPTION 
* 
*     ISSUE BKSP MACRO. 
*#
  
          ENTRY  DB$IOBR
DB$IOBR   EQ   *+1S17 
          SA1    X1          (X1) = ADDRESS FET 
          BKSP   X1 
          EQ   DB$IOBR
 DB$IORE  SPACE  3,10 
*#
* *   DB$IORE--READ FILE GIVEN FET               PAGE  1
* *   C O GIMBER                                 9/10/76
* 
* DC   PURPOSE
* 
*     READ A FILE VIA CIO WITHOUT RECALL. 
*     LEAVES FILE POSITIONED AT NEXT PRU. 
* 
* DC   ENTRY CONDITIONS 
* 
*     PARAMETERS
* 
*     LOC(FET)
*     LOC(WSA)
*     NUMBER OF WORDS TO READ 
* 
* DC  DESCRIPTION 
* 
*     SET FIRST, IN, OUT, LIMIT FIELDS IN FET.
*     ISSUE CIO READ MACRO WITHOUT RECALL.
*     RETURN. 
*#
          ENTRY  DB$IORE
DB$IORE   EQ   *+1S17 
          SB1    1
          SA2    A1+B1
          SA3    A2+B1
          MX0    42          (X0) = MASK
          SA1    X1          (X1) = ADDRESS FET 
          SA2    X2          (X2) = ADDRESS WSA 
          SA3    X3          (X3) = NUMBER WORDS TO READ
                             FIRST = WSA
          SA4    X1+B1       (X4) = FIRST WORD FROM FET 
          BX4    X0*X4
          IX6    X2+X4       ADD FIRST TO FIRST WORD
          SA6    A4          STORE FIRST WORD 
          BX7    X2 
          SA7    A6+B1       SET IN TO WSA
          BX6    X2 
          SA6    A7+B1       SET OUT TO WSA 
          IX4    X2+X3
          SX7    X4+B1       LIMIT = WSA+WORDS+1
          SA5    A6+B1       (X5) = LIMIT WORD FROM FET 
          BX5    X0*X5
          IX7    X7+X5       ADD LIMIT TO LIMIT WORD
          SA7    A5          STORE LIMIT WORD 
          READ  X1
          EQ   DB$IORE
          SPACE  3,10 
*CALL IOLIST
          END 
