*DECK DB$GTID 
USETEXT,RQPARTX 
      PROC DB$GTID(RID,STAT); 
      BEGIN 
 #
* *   DB$GTID - GET THE RESTART ID               PAGE  1
* *   GET THE RESTART IDENTIFER OBJECT-TIME ROUTINE 
* *   W. P. CEAGLIO                              DATE  09/24/80 
* * 
* 
* DC  PURPOSE 
* 
*     PARTIALLY FORMAT THE REQUEST PACKET FOR THE 
*     *GET RESTART IDENTIFIER* REQUEST. 
* 
* DC  ENTRY CONDITIONS
* 
*     PARAMETERS
# 
      ITEM RID     C(10);    # OUTPUT - RESTART IDENTIFIER             #
      ITEM STAT        I;    # OUTPUT - ERROR STATUS                   #
# 
*     ASSUMPTIONS 
* 
*     NONE
* 
* DC  EXIT CONDITIONS 
* 
*     THE *CALLSS* SUBSYSTEM REQUEST TO CDCS IS MADE.  IF A NON-FATAL 
*     ERROR IS DIAGNOSED BY CDCS, CONTROL IS RETURNED WITH THE ERROR
*     NUMBER SET IN THE REQUEST PACKET--THIS IS SET IN THE *STAT* CELL. 
* 
* DC  CALLING ROUTINES
* 
*     HOST-LANGUAGE 
* 
* DC  CALLED ROUTINES 
* 
# 
      XREF PROC DB$RA0;      # PARAMETER LIST TERMINATOR               #
      XREF PROC DB$RQST;     # COMPLETE THE FORMATING OF THE           #
                             # REQUEST AND ISSUE THE CALLSS TO CDCS.   #
# 
* 
* DC  NON-LOCAL VARIABLES MODIFIED
* 
*     DB$RQBF - REQUEST PACKET BUFFER 
* 
* DC  DESCRIPTION 
* 
*     PARAMETERS THAT ARE SPECIFIC TO THE REQUEST ARE COMPLETED IN THE
*     REQUEST BUFFER.  THEN DB$RQST IS CALLED TO FORMAT THE COMMON
*     PARAMETERS AND TO ISSUE THE *CALLSS* FUNCTION.  UPON RETURN, THE
*     THE STATUS PARAMETER IS SET TO THE VALUE RETURNED IN THE REQUEST
*     PACKET HEADER.  CONTROL THEN IS RETURNED TO THE CALLER. 
* 
 #
  
#     COMMON DECKS CDGDFDCLS AND RQPARDCLS ARE USED.                   #
      CONTROL EJECT;
  
#     S T A R T  O F  D B $ G T I D  E X E C U T A B L E  C O D E      #
  
  
#     FORMAT SPECIFIC PARAMETERS IN REQUEST PACKET                     #
  
      RQPTRWRD1[0] = 0; 
      RQPRIDLOC[0] = LOC(RID);
  
#     COMPLETE REQUEST PACKET AND ISSUE *CALLSS* FUNCTION              #
  
      DB$RQST(DFGID,DFWCGID,DB$RA0);
  
#     SET STATUS PARAMETER FROM REQUEST PACKET AND RETURN TO CALLER    #
  
      STAT = RQPKERR[0];
      END 
      TERM
