*DECK DB$EXT
          IDENT  DB$EXT 
*#
* *   DB$EXT--EXTEND SEQUENTIAL FILE             PAGE  1
* *   W P CEAGLIO                                DATE  2/3/76 
* * 
* DC  PURPOSE 
* 
*     ISSUE "EXTEND" SYSTEM REQUEST 
* 
* DC  LANGUAGE
* 
*     COMPASS 
* 
* DC  ENTRY CONDITIONS
* 
*     LFN        LOCAL FILE TO BE EXTENDED
*     ERR        RETURN CODE
* 
* 
*                 0 = SUCCESSFUL
*                "0 = UNSUCCESSFUL
* 
* DC  EXIT CONDITIONS 
* 
*     NORMAL--"ERR" SET = 0 (NO ERROR OCCURRED IN EXTEND) 
*     ABNORMAL--"ERR" SET "0 (ERROR OCCURRED IN EXTEND) 
* 
* DC  CALLING ROUTINE 
* 
*     DB$CLOG    CLOSE LOG FILES
* 
* DC  CALLED ROUTINES 
* 
*     "EXTEND" SYSTEM MACRO 
* 
* DC  DESCRIPTION 
* 
*     1.  MASK RIGHT-MOST 18 BITS (ZEROES) OF LFN.
*     2.  ISSUE PERMANENT FILE EXTEND REQUEST.
*     3.  CHECK RETURN CODE IN FDB (LOCAL ITEM) AND SET ERROR CODE
*         FOR CALLER. 
*     4.  RETURN. 
* 
*#
  
          IPARAMS 
          LIST   F
  
          IFC    EQ,$"OS.NAME"$SCOPE $
 ERRCODE  BSSZ   1
FDB       VFD    60/1              PF FDB TABLE 
          VFD    60/0 
  
  
          ENDIF 
  
          ENTRY  DB$EXT 
 DB$EXT   JP     *+400000B
          IFC    EQ,$"OS.NAME"$SCOPE $
*#
*     ISSUE PF EXTEND.
*#
          SA2    A1+1 
          BX6    X2 
          SA6    ERRCODE
          SA1    X1 
          MX0    42D
          BX6    X0*X1
          SA6    FDB
          EXTEND  FDB,RC
*#
*     CHECK RETURN CODE FOR ERROR 
*       SET USER ERROR CELL ACCORDINGLY 
*#
RTNCODE   SA1    FDB
          MX0    51D
          AX1    9D 
          BX6    -X0*X1 
          SA3    ERRCODE
          SB1    X3 
          SA6    B1 
          ENDIF 
          EQ     DB$EXT 
          END 
