*DECK DB$DRRD 
          IDENT  DB$DRRD
          SST 
          TITLE  DB$DRRD - SEQ READ FOR DB$AINT 
          COMMENT  SEQUENTIAL READ OF DIR FILE FOR DB$AINT
          DATA   10L  DB$DRRD 
*#
* *   DB$DRRD - READ SEQUENTIAL DIRECTIVE FILE   PAGE 1 
* *   M.L.BRANDENBURG                            DATE 05/05/81
* 
* DC  PURPOSE 
* 
*     READ THE SEQUENTIAL DIRECTIVE FILE DEFINED AS ONE 
*     OF THE PARAMETERS ON THE CDCS CONTROL CARD. 
* 
* DC  ENTRY CONDITION 
* 
*     ARRAY DB$DRFT CONTAINS THE NAME OF THE FILE.
* 
* DC  EXIT CONDITION
* 
*     ONE RECORD FROM THE FILE IS IN BUFFER DB$DRWB.
*     IF READ OK, THE FUNCTION RETURN IS ZERO.
*     FUNCTION RETURN IS LESS THAN ZERO AT END OF FILE. 
*     ERROR CONDITIONS ARE STORED IN FET. 
* 
* DC  CALLED ROUTINES 
* 
*     COMRDH
* 
* DC  CALLING ROUTINES
* 
*     DB$AINT 
* DC  NON LOCAL VARIABLES MODIFIED
* 
*     NONE
* 
* DC  DESCRIPTION 
* 
*     THE FIRST TIME THE PROCEDURE IS CALLED, THE FET 
*     IS READ.  THE ADDRESS OF THE FET AND THE ADDRESS
*     OF THE WORKING BUFFER ARE LOADED INTO REGISTERS 
*     AND COMRDH IS CALLED TO DO THE ACTUAL READ OF THE 
*     FILE AND MOVE OF ONE RECORD TO THE BUFFER.
* 
*#
          ENTRY  DB$DRRD
DB$DRRD   EQ     *+1S17 
          SA1    DB$DRWB     DIR FILE WORKING BUFFER
          NZ     X1,RDH01 
          READ   DB$DRFT,R   READ DIR FILE FET
  
RDH01     BSS    0
          SX2    DB$DRFT     GET FET
          SB6    DB$DRWB     GET WORKING BUFFER 
          SB7    8
          RJ     RDH=        GO GET A RECORD
          SX6    X1          SET UP THE RETURN
          EQ     DB$DRRD
  
          ENTRY  DB$DRFT
DB$DRFT   BSS    0
INPUT     FILEC  BUFFER,LENGTH
LENGTH    EQU    202B 
BUFFER    BSSZ   LENGTH 
  
          ENTRY  DB$DRWB
DB$DRWB   BSSZ   8
*CALL    COMCRDH
*CALL     COMCRDW 
          SPACE  3,10 
*CALL IOLIST
          END 
