*DECK DB$DLAY 
          IDENT  DB$DLAY
          COMMENT WAIT FOR UP CDCS OR SCHEMA
          TITLE  DB$DLAY  --  DELAY UNTIL CDCS OR SCHEMA AVAILABLE
          IPARAMS 
*#
* *   DB$DLAY - DELAY UNTIL CDCS IS AVAILABLE    PAGE  1
* *   BOB MCALLESTER                             DATE  09/01/83 
* 
* DC  PURPOSE 
* 
*     THIS ROUTINE IS USED WHILE WAITING FOR CDCS OR A SCHEMA 
*     TO ENTER UP STATUS. 
* 
* DC  ENTRY CONDITIONS
* 
* D   PARAMETERS
* 
*     NONE
* 
* D   ASSUMPTIONS 
* 
*     DB$DLAC HAS BEEN INITIALLY SET TO ZERO. 
* 
* DC  EXIT CONDITIONS 
* 
*     THERE HAS BEEN A SIGNIFICANT TIME ELAPSED.
* 
* DC  CALLING ROUTINES
* 
*     DB$RQST    CDCS REQUEST PROCESSOR 
* 
* DC  CALLED ROUTINES 
* 
*     NONE
* 
* DC  NON-LOCAL VARIABLES MODIFIED
* 
*     NONE
* 
* DC  DESCRIPTION 
* 
*     NOS/BE -
*       ON THE FIRST CALL, ISSUE THE -WAITING- MESSAGE. 
*       ON EACH CALL, DELAY IN RECALL AND THEN RETURN.
* 
*     NOS - 
*       ON THE FIRST AND EVERY EIGHTH CALL, ISSUE THE -WAITING- MESSAGE.
*       ON EACH CALL, ROLL OUT FOR A WHILE, THEN DELAY IN RECALL
*       LONG ENOUGH FOR OPERATOR OBSERVATION OF THE MESSAGE.
*#
          LIST   F
  
          ENTRY  DB$DLAY
          ENTRY  DB$DLAC
          ENTRY  DB$DLAM
          SPACE  3,6
*         V A R I A B L E S   A N D    C O N S T A N T S .
  
  
 DB$DLAC  CON    0           DELAY COUNT
  
 RCLCOUNT SET    2500        RECALL COUNT FOR NOS/BE
  
.NOS.     IFC    EQ,$"OS.NAME"$KRONOS$
 RCLCOUNT SET    400         RECALL COUNT FOR NOS = 8 SECONDS 
  
 PERIOD   VFD    30/0,18/770000B
          VFD    12/52       ROLLOUT PERIOD = 52 SECONDS
  
 OPL      XTEXT  COMCMAC     OBTAIN DECK COMCMAC FROM FILE OPL
*                            COMCMAC CONTAINS THE ROLLOUT MACRO 
  
*         DB$RQST TRUNCATES THIS MESSAGE TO * WAITING FOR CDCS *
*         UNLESS THE ERROR CODE FROM CDCS IS -SCHEMA NOT AVAILABLE-.
  
 DB$DLAM  DATA   C*  WAITING FOR CDCS SCHEMA* 
.NOS.     ELSE
*                NOS/BE MESSAGE HAS A $ TO CREATE A FLASHING MESSAGE. 
 DB$DLAM  DATA   C*$ WAITING FOR CDCS SCHEMA* 
.NOS.     ENDIF 
          SPACE  3,6
*     B E G I N   D B $ D L A Y   E X E C U T A B L E   C O D E . 
  
  
 DB$DLAY  EQ     *+1S17 
          SA1    DB$DLAC
.NOS.     IFC    EQ,$"OS.NAME"$KRONOS$  IF NOS
          MX6    -1 
          MX0    -3 
          IX6    X1-X6
          BX1    -X0*X1 
.NOS.     ELSE                      ELSE NOS/BE 
          SX6    1
.NOS.     ENDIF 
          SA6    DB$DLAC
          NZ   X1,DLAY04
          MESSAGE  DB$DLAM,0,RECALL 
 DLAY04   BSS    0
.NOS.     IFC    EQ,$"OS.NAME"$KRONOS$
          ROLLOUT PERIOD
.NOS.     ENDIF 
  
          SB2    RCLCOUNT 
 DLAY08   BSS    0
          RECALL
          SB2    B2-1 
          LT   B0,B2,DLAY08 
          EQ   DB$DLAY       RETURN 
  
          END 
