*DECK DB$DBPL 
          IDENT  DB$DBPL
          TITLE  DB$DBPL
DB$DBPL   TITLE  DB$DBPL - LOAD A DATABASE PROCEDURE
          ENTRY  DB$DBPL     LOAD A DATA BASE PROCEDURE 
*#
* *   DB$DBPL - LOAD A DATABASE PROC WITH FDL    PAGE  1
* *   J E ESLER                                  DATE  05/03/76 
* 
* DC  ENTRY CONDITIONS
* 
*     PARAMETERS
* 
*         LIBRARY NAME (=FDL GROUP NAME)
*         ACTIVE PROCEDURE LIST (APL) ENTRY ADDRESS 
* 
* DC  EXIT CONDITIONS 
* 
*     ENTRY ADDRESS OR FDL ERROR CODE SET IN APEPADD IN APL ENTRY.
* 
* DC  CALLING ROUTINES
* 
*     DB$ADDP   FIND DBP ADDRESS FOR SYSTEM RECOVERY
*     DB$DPIF   DATABASE PROCEDURE INTERFACE ROUTINE
* 
* DC  CALLED ROUTINES 
          EXT    FDL.LDC     FAST DYNAMIC LOADER - LOAD 
* 
*#
 DB$DBPL  EQ   *+1S17 
          SA2    A1+1        SECOND PARAMETER - APL ENTRY ADDR
          SA1    X1          FIRST PARAMETER - LIBRARY,, SET NAME 
          BX6    X1 
          SA6    LIBRARY
          SA2    X2          APL ENTRY ADDRESS
          BX6    X2 
          SA6    APLENTRY 
          SA2    X2          CAPLULE (DB PROC)NAME
          BX6    X2 
          SA6    PASSLOC+1   SET UP PASSLOC TABLE 
          MX7    0
          SA7    PASSLOC+2
          SX3    LIBRARY     LIBRARY LIST POINTER 
          SX4    PSLIST      LIST OF PASSLOC TABLES 
          RJ   FDL.LDC       LOAD CAPSULE 
          SA1    APLENTRY 
          SA6    X1+1        STORE ERROR CODE IN ENTRY ADDRESS
          NZ   X6,DB$DBPL    ..EXIT - FDL ERROR 
  
          SA1    PASSLOC+2   PUT ENTRY ADDRESS IN APL ENTRY 
          BX6    X1 
          SA6    A6 
          EQ   DB$DBPL       ..EXIT 
 LIBRARY  BSSZ   2
 PASSLOC  LDREQ PASSLOC,((DUMMY,0,,,))
 PSLIST   VFD    60/PASSLOC,60/0
 APLENTRY BSS    1
DB$DBPU   TITLE  DB$DBPU - UNLOAD A DATABASE PROCEDURE
          ENTRY  DB$DBPU     UNLOAD A DATBASE PROCEDURE 
*#
* *   DB$DBPU - UNLOAD A DATABASE PROC WITH FDL  PAGE  1
* *   J E ESLER                                  DATE  05/03/76 
* 
* DC  ENTRY CONDITIONS
* 
*     PARAMETERS
* 
*         LIBRARY NAME (=FDL GROUP NAME)
*         ACTIVE PROCEDURE LIST (APL) ENTRY ADDRESS 
* 
* DC  EXIT CONDITIONS 
* 
*     FDL ERROR CODE OR ZERO SET IN APEPADD IN APL ENTRY. 
* 
* DC  CALLING ROUTINES
* 
*     DB$CLSA                CLOSE AREA 
*     DB$CMOH                CENTRAL MEMORY OVERFLOW HANDLER
*     DB$RLSP                RELEASE DATABASE PROCEDURES
* 
* DC  CALLED ROUTINES 
* 
          EXT    FDL.ULC     FAST DYNAMIC LOADER - UNLOAD 
* 
*#
 DB$DBPU  EQ   *+1S17 
          SA2    A1+1        SECOND PARAMETER - APL ENTRY ADDRESS 
          SA1    X1          FIRST PARAMETER - SET NAME 
          SA2    X2          APL ENTRY ADDRESS
          SA2    X2          CAPSULE NAME 
          SX6    A2 
          SA6    ULENTRY     ADDRESS OF APL ENTRY 
          MX4    0           LIST OF PASSLOC TABLES 
          RJ   FDL.ULC       UNLOAD DB PROC 
          SA1    ULENTRY     SAVE RETURN CODE IN APL ENTRY
          SA6    X1+1 
          EQ   DB$DBPU       ..EXIT 
 ULENTRY  BSS    1
DB$DBPX   TITLE  DB$DBPX - UNLOAD FDL GROUP DIRECTORY 
          ENTRY  DB$DBPX
*#
* *   DB$DBPX - UNLOAD FDL GROUP DIRECTORY       PAGE  1
* *   BOB MCALLESTER                             DATE  08/09/82 
* 
* DC  ENTRY CONDITIONS
* 
*     PARAMETERS
* 
*     LIBRARY NAME (=FDL GROUP NAME)
* 
* DC  EXIT CONDITIONS 
* 
*     NORMAL - THE GROUP DIRECTORY IS UNLOADED. 
*     ABNORMAL - FDL ERROR CODE IS RETURNED IN X6.
* 
* DC  CALLING ROUTINES
* 
*     DB$RLSP                RELEASE DATABASE PROCEDURES
* 
* DC  CALLED ROUTINES 
* 
*     FDL.UGD                UNLOAD GROUP DIRECTORY 
* 
*#
 DB$DBPX  EQ   *+1S17 
          SA1    X1          (X1) = GROUP NAME
          RJ   =XFDL.UGD
          EQ   DB$DBPX       (X6) = ERROR STATUS
*                                  00B - NO ERROR 
*                                  02B - UNKNOWN GROUP NAME 
*                                  10B - GROUP HAS CAPSULES 
          END 
