*DECK DB$ASK
USETEXT,RQPARTX 
      PROC DB$ASK(RID,TID,STAT);
      BEGIN 
 #
* *   DB$ASK - INQUIRE TRANSACTION               PAGE  1
* *   INQUIRE TRANSACTION OBJECT-TIME ROUTINE 
* *   W. P. CEAGLIO                              DATE  09/24/80 
* * 
* 
* DC  PURPOSE 
* 
*     PARTIALLY FORMAT THE REQUEST PACKET FOR THE 
*     *INQUIRE TRANSACTION* REQUEST.
* 
* DC  ENTRY CONDITIONS
* 
*     PARAMETERS
# 
      ITEM RID     C(10);    # INPUT - RESTART IDENTIFIER              #
      ITEM TID     C(10);    # OUTPUT - TRANSACTION IDENTIFIER         #
      ITEM STAT        I;    # OUTPUT - ERROR STATUS                   #
# 
*     ASSUMPTIONS 
* 
*     NONE
* 
* DC  EXIT CONDITIONS 
* 
*     THE *CALLSS* SUBSYSTEM REQUEST TO CDCS IS MADE.  IF A NON-FATAL 
*     ERROR IS DIAGNOSED BY CDCS, CONTROL IS RETURNED WITH THE ERROR
*     NUMBER SET IN THE REQUEST PACKET--THIS IS SET IN THE *STAT* CELL. 
* 
* DC  CALLING ROUTINES
* 
*     HOST LANGUAGE 
* 
* DC  CALLED ROUTINES 
* 
# 
      XREF PROC DB$RA0;      # PARAMETER LIST TERMINATOR               #
      XREF PROC DB$RQST;     # COMPLETE THE FORMATING OF THE           #
                             # REQUEST AND ISSUE THE CALLSS TO CDCS.   #
# 
* 
* DC  NON-LOCAL VARIABLES MODIFIED
* 
*     DB$RQBF - REQUEST PACKET BUFFER 
* 
* DC  DESCRIPTION 
* 
*     PARAMETERS THAT ARE SPECIFIC TO THE REQUEST ARE COMPLETED IN THE
*     REQUEST BUFFER.  THEN DB$RQST IS CALLED TO FORMAT THE COMMON
*     PARAMETERS AND TO ISSUE THE *CALLSS* FUNCTION.  UPON RETURN, THE
*     THE STATUS PARAMETER IS SET TO THE VALUE RETURNED IN THE REQUEST
*     PACKET HEADER.  CONTROL THEN IS RETURNED TO THE CALLER. 
* 
 #
  
#     COMMON DECKS CDGDFDCLS AND RQPARDCLS ARE USED.                   #
      CONTROL EJECT;
  
#     S T A R T  O F  D B $ A S K  E X E C U T A B L E  C O D E        #
  
  
#     FORMAT SPECIFIC PARAMETERS IN REQUEST PACKET                     #
  
      RQPTRWRD1[0] = 0; 
      RQPTRWRD2[0] = 0; 
      RQPRID[0] = RID;
      RQPTIDLOC[0] = LOC(TID);
  
#     COMPLETE REQUEST PACKET AND ISSUE *CALLSS* FUNCTION              #
  
      DB$RQST(DFASK,DFWCASK,DB$RA0);
  
#     SET STATUS PARAMETER FROM REQUEST PACKET AND RETURN TO CALLER    #
  
      STAT = RQPKERR[0];
  
      END 
      TERM
