*COMDECK PTTPINF
          NAM    PTTPINF
*                                                                      *
*                                                                      *
************************************************************************
*                                                                      *
*                            P T T P I N F                             *
*              TEXT PROCESSOR FIRMWARE INTERFACE ROUTINE               *
*                                                                      *
*                                                                      *
**OVERVIEW-                                                            *
*     PTTPINF ESCAPES TO FIRMWARE TO TRANSFER THE LOWER 16 WORDS OF    *
*     THE TEXT PROCESSING MUX LCB TO FILE 1 REGISTERS.ON RETURN        *
*     PTTPINF ESCAPES TO FIRMWARE TO DO TEXT PROCESSING.ON RETURN      *
*     ONE OF THREE ACTIONS IS TAKEN DEPENDING ON THE Q REGISTER:       *
*                                                                      *
*      1)   Q=0     TRANSFER FILE 1 REGISTERS TO LOWER 16 WORDS        *
*                   OF TEXT PROCESSING LCB AND EXIT TEXT PROCESSING.   *
*                                                                      *
*      2)   Q"0                                                        *
*           A=0     ALLOW INTERRUPTS AND RE-ENTER FIRMWARE TO          *
*                   CONTINUE TEXT PROCESSING.                          *
*                                                                      *
*      3)   Q"0                                                        *
*           A"0     RELEASE CHAIN OF DESTINATION BUFFERS USED          *
*                   DURING A TEXT PROCESSING SAVE CONDITIONS           *
*                   SEQUENCE WHERE THE A REGISTER CONTAINS THE         *
*                   ADDRESS OF THE FIRST BUFFER TO RELEASE.            *
*                                                                      *
**INPUT-                                                               *
*     INPUT IS A PASSED PARAMETER WITH THE TEXT PROCESSING LCB ADDRESS.*
*                                                                      *
**OUTPUT-                                                              *
*     OUTPUT IS A CHAIN OF TEXT PROCESSED DESTINATION BUFFERS.         *
*     THE ADDRESS OF THE FIRST BUFFER IS IN THE TEXT PROCESSING LCB.   *
*                                                                      *
**EXTERNAL SUBROUTINES USED-                                           *
*     PBRELCHN - TO RELEASE UNUSED DESTINATION BUFFERS.                *
*                                                                      *
*                                                                      *
************************************************************************
          SPC    2
          ENT    PTTPINF
          EXT    PBRELCHN 
          EXT    BEDBSIZE 
          SPC    2
*        FIRMWARE ENTRY POINTS
          SPC    2
          EQU    TMEMF1($603) TRANSFER MEMORY(LCB) TO FILE 1 REGS 
          EQU    TF1MEM($604) TRANSFER FILE 1 REGS. TO MEMORY(LCB)
          EQU    TXPENT($60F) TEXT PROCESSING ENTRY POINT 
          EQU    TXRENT($610) TEXT PROCESSING RE-ENTRY POINT
          SPC    2
PTTPIN    NOP    0            ENTRY 
          SR3*   PR3SAV       PRESERVE CONTENTS OF R3 
          LDA*   (PTTPIN)     GET PARAMETER 
          STA*   PLCBAD       SAVE LCB ADDRESS(TOP) 
          INA    $10          DISPL. TO LCB FIRST WORD TO MOVE TO F1
          STA*   PLCBF1       SAVE LCB ADDRESS(FIRST WORD TO MOVE)* 
          RAO*   PTTPIN       BUMP RETURN ADDRESS 
          LDQ    =N$10CF      FIRMWARE MOVE MEM. TO FILE 1 PARAMETER
          LR3    =XTMEMF1     FIRMWARE ENTRY POINT
          EMS    3            ESCAPE TO MOVE MEM. TO FILE 1 REGS. 
          LDQ    =XTXPENT     FIRMWARE ENTRY TO DO TEXT PROCESSING
PTRENT    LDA*   PLCBAD       LCB ADDRESS 
          EMS    Q            ESCAPE FOR TEXT PROCESSING
*                        TEXT PROCESSING RETURN POINT 
         SQZ     PTEXIT       Q=0 - TRANSFER F1 TO MEM AND EXIT TP
          SAZ    PTAIR        A=0 - ALLOW INTS., REENTER FIRMWARE TP
*                             A"0 - RELEASE BUFFERS,RE-ENTER FIRM. TP 
          STA*   PDBADD       (A) HAS FIRST BUFFER ADDRESS
          RTJ+   PBRELCHN     RELEASE DEST. BUFFER CHAIN
          ADC    PDBADD       PARAMETER 1 - LOC. OF FIRST BUFFER ADDR.
          ADC    BEDBSIZE     PARAMETER 2 - BUFFER CNTRL. BLK. PTR. 
PTAIR     LDQ    =XTXRENT     FIRMWARE TP RE-ENTRY POINT
          JMP*   PTRENT       RE-ENTER FIRMWARE TP
PTEXIT    LDA*   PLCBF1       LCB ADDRESS TO TRANSFER F1 REGS. TO MEM.
          LDQ    =N$10D0      FIRMWARE MOVE F1 TO MEM. PARAMETER
          LR3    =XTF1MEM     FIRMWARE ENTRY POINT
          EMS    3            ESCAPE TO MOVE F1 REGS. TO MEM.(LCB)
          LR3*   PR3SAV       RESTORE R3
          JMP*   (PTTPIN)     RETURN
          SPC    2
PR3SAV    NUM    0            R3 SAVE LOCATION
PLCBAD    NUM    0            PARAMETER SAVED(LCB ADDRESS)
PLCBF1    NUM    0            LCB ADDRESS FOR F1-MEM AND MEM-F1 MOVE
PDBADD    ADC    0            ADDRESS OF BUFFER CHAIN TO RELEASE
          END 
