*COMDECK PBPSWITCH
******************************
*                            *
*         PBPSWITCH          *
*  PERFORM PAGE SWITCH       *
*                            *
******************************
*        NON-RECURSIVE
*        NON-INTERRUPTABLE
************************************************************
*                                                          *
**OVERVIEW- PBPSWITCH LOADS THE 4 DYNAMIC PAGE REGISTERS   *
*           (DYNAMICPAGE) GIVEN A SPECIFIC PAGE REGISTER   *
*           BASE VALUE.                                    *
*                                                          *
**INPUT- PAGE REGISTER BASE VALUE.                         *
*                                                          *
**OUTPUT- PAGE SWITCH PERFORMED.                           *
*                                                          *
**EXTERNAL SUBROUTINES- NONE                               *
*                                                          *
************************************************************
         NAM   PBPSWI 
         ENT   PBPSWI 
         EXT   QTOPSK 
* 
         EXT   DYNAMICPAG 
* 
PBPSWI   NOP   0
         IIN   0         INHIBIT INT
         LDA   =XDYNAMICPAG 
         ALS   11        DYNAMIC PAGE REGISTER
         LDQ*  (PBPSWI) 
         ADD+  0,Q       GET PAGE BASE ADDRESS
         AND   =N$FFFC   MASK OFF BITS 0, 1  OF PAGE CONTENTS 
         WPR   A         SET UP DYNAMIC PAGE 1
         ADD   =N$801    CALC DYNAMIC PAGE 2
         WPR   A         SET UP DYNAMIC PAGE 2
         ADD   =N$801    CALC DYNAMIC PAGE 3
         WPR   A         SET UP DYNAMIC PAGE 3
         ADD   =N$801    CALC DYNAMIC PAGE 4
         WPR   A         SET UP DYNAMIC PAGE 4
         RAO*  PBPSWI    BUMP PAST PARAMETER
         LDA   QTOPSK    CHECK INT COUNT
         SAN   1
         EIN   0         ENABLE INT 
         JMP*  (PBPSWI) 
         END
